static.asm

windows汇编语言程序设计 吴中平著 一书所附所有源代码。 该书重点讲解了Windows环境下汇编语言程序设计的基本原理及其实现过程

include .\head.inc
WinMain proto :DWORD,:DWORD,:DWORD,:DWORD
.data
ClassName                       db "StaticClass",0
TitleName                        db "静态控制子窗口",0
ButtonClassName             db "BUTTON",0
StaticClassName               db "STATIC",0
PushButtonText                db "确定",0
StaticBitmap                     db "flower",0
StaticText                        db "远上寒山石径斜，白云生处有人家，停车坐爱枫林晚，霜叶红于二月花",0
.data?
hInstance                  HINSTANCE ?
hwndButtonPush       HWND ?
hwndStatic                HWND ?
Buffer                       db 100 dup(?)
.const
ID_BUTTON_PUSH     equ 1
ID_STATIC                 equ 2
.code
start:
   invoke GetModuleHandle, NULL
   mov    hInstance,eax
   invoke WinMain, NULL,NULL,NULL, SW_SHOWDEFAULT
   invoke ExitProcess,eax

WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,CmdShow:DWORD
   LOCAL wc:WNDCLASSEX
   LOCAL msg:MSG
   LOCAL hwnd:HWND
   mov   wc.cbSize,SIZEOF WNDCLASSEX
   mov   wc.style, CS_HREDRAW or CS_VREDRAW or CS_DBLCLKS
   mov   wc.lpfnWndProc, OFFSET WndProc
   mov   wc.cbClsExtra,NULL
   mov   wc.cbWndExtra,NULL
   mov   eax, hInstance
   mov   wc.hInstance,eax
   invoke GetStockObject,WHITE_BRUSH 
   mov   wc.hbrBackground,eax
   mov   wc.lpszMenuName,NULL
   mov   wc.lpszClassName,OFFSET ClassName
   invoke LoadIcon,NULL,IDI_ASTERISK
   mov   wc.hIcon,eax
   mov   wc.hIconSm,0
   invoke LoadCursor,NULL,IDC_HAND
   mov   wc.hCursor,eax
   invoke RegisterClassEx, addr wc
   invoke CreateWindowEx,WS_EX_CLIENTEDGE+WS_EX_APPWINDOW,addr ClassName,\
      addr TitleName,WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,CW_USEDEFAULT,400,300,\
      NULL,NULL,hInst,NULL
   mov   hwnd,eax
   invoke ShowWindow,hwnd,CmdShow
   invoke UpdateWindow,hwnd
   .while TRUE
      invoke GetMessage, addr msg,NULL,0,0
      .BREAK .if (!eax)
      invoke TranslateMessage,addr msg
      invoke DispatchMessage, addr msg
   .endw
   mov eax,msg.wParam
   ret
WinMain endp
WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
   .if uMsg==WM_DESTROY
      invoke PostQuitMessage,NULL
   .elseif uMsg==WM_CREATE 
      invoke CreateWindowEx,WS_EX_CLIENTEDGE, ADDR StaticClassName,addr StaticBitmap,\
         WS_VISIBLE or WS_CHILD  or  SS_BITMAP ,30,40,100,100,hWnd,NULL,hInstance,NULL
      invoke CreateWindowEx,WS_EX_CLIENTEDGE, ADDR StaticClassName,addr StaticText,\
         WS_VISIBLE  or WS_CHILD or SS_NOTIFY or SS_LEFT or SS_SUNKEN,180,40,100,100,hWnd,ID_STATIC,hInstance,NULL  
      mov hwndStatic,eax
      invoke CreateWindowEx,NULL, ADDR ButtonClassName,addr PushButtonText,\
         WS_VISIBLE or WS_CHILD  or  BS_DEFPUSHBUTTON or BS_VCENTER, 120,190,80,20,hWnd,ID_BUTTON_PUSH,hInstance,NULL
      mov hwndButtonPush,eax              
   .elseif uMsg==WM_COMMAND
      mov eax,wParam
      .if lParam	
         .if ax==ID_BUTTON_PUSH
            shr eax,16
            .if ax==BN_CLICKED
               invoke MessageBox,hWnd,addr StaticText,addr TitleName,MB_OK
            .endif
         .elseif ax==ID_STATIC
            shr eax,16
            .if ax==STN_DBLCLK
               invoke SendMessage,hwndStatic,WM_GETTEXT,sizeof StaticText,addr Buffer
               invoke MessageBox,hWnd,addr Buffer,addr TitleName,MB_OK
            .endif
         .endif 
       .else
      .endif
   .else
      invoke DefWindowProc,hWnd,uMsg,wParam,lParam
      ret
   .endif
   xor    eax,eax
   ret
WndProc endp
end start