linkdsk5402.cmd

基于ti 5402dsk的flashburn程序。

/*******************************************************************************
 * Copyright 2004-2005 - Software Design Solutions, Inc.  All rights reserved.
 *
 * Portions of this work have been provided under license with Texas 
 * Instruments Inc.
 * 
 * $RCSfile: LinkDSK5402.cmd,v $
 * $Revision: 1.4 $
 * 
 * Linker control file for the FBTC
 * 
 ******************************************************************************/

-c
-stack 0x0256
-heap  0x0256

MEMORY  
{
/* Note: Assume PMST = 0xffe0
        PMST    Bit     Name   Value
                15-7    IPTR    0xff80
                6       MP/!MC  1
                5       OVLY    1
                3       DROM    0
*/
        PAGE 0: /* Program Space */
        RSV1 (R)        : o=00000h l=00080h     /* Reserved */
        DARAM   (RWIX)  : o=00080h l=03f80h     /* On-Chip Dual-Access RAM */
        EXT0    (R)     : o=04000h l=0bf80h     /* External Page 0 */
        VECS    (RWIX)  : o=0ff80h l=00080h     /* Interrupt Vector Table */
        EAP0    (RW)    : o=018000h l=8000h     /* Extended addr. page 0 */
                
        PAGE 1: /* Data Space */
        MMRS    (RW)    : o=00000h l=00060h     /* Memory-Mapped Registers */
        SPAD    (RW)    : o=00060h l=00020h     /* Scratch-Pad RAM */
        DARAM   (RWIX)  : o=00080h l=03f80h     /* On-Chip Dual-Access RAM */
        EXT0    (R)     : o=04000h l=0c000h     /* External Page 0 */
}

SECTIONS
{
    GROUP : > DARAM /* group sections in overlay for contiguous addresses */
    {       
        .text           /* User code */
        .cinit          /* initialization tables */
        .pinit          /* initialization functions */
        .switch         /* for C-switch tables */

        .cio            /* C-IO Buffer */
        .bss            /* global & static vars */
        .const          /* C constant tables */

        .sysmem         : fill = 0xDEADh        /* dynamic heap */
        .stack          : fill = 0xBEEFh        /* system stack */
    }

        .intvecs        : > VECS  PAGE 0        /* interrupt vector table */
        .data           : > SPAD  PAGE 1        /* asm data area */
}