userspace.asp

公司企业网站管理系统全站源码,用于企业内部对网站的管理

				TempNode.attributes.getNamedItem("title").text=Dvbbs.ChkBadWords(Dvbbs.Replacehtml(TempNode.getAttribute("title")))
			End If
			TempNode.attributes.getNamedItem("dateandtime").text=Formatdatetime(cdate(TempNode.getAttribute("dateandtime")),2)
			TempNode.setAttribute "isbest",1
		Next
		TopicStats_Pic(TopicNodes.documentElement)
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub

'获取用户附件数据
Sub Load_UserFiles(Node)
	Dim Rs,Sql,TopicNodes,TempNode
	'Dv_BookMark
	If Node is Nothing Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Dim HideBoards,Nums
	Nums = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_3"))

	HideBoards = " Not F_BoardID in("&LockBoards()&") "
	Sql = "Select top "&Nums&" F_ID,F_BoardID,F_AnnounceID,F_Filename,F_Readme,F_Type,F_Flag,F_Viewname,F_Username,F_DownNum,F_ViewNum,F_FileType,F_AddTime from [DV_Upfile] where "&HideBoards&" and F_Flag<>4 and  F_UserID ="&MySpace.Sid&"  order by F_ID desc"
	'Response.Write sql
	Set Rs = Dvbbs.Execute(sql)
	If not Rs.Eof Then
		SQL=Rs.GetRows(-1)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","userfile")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing
	If Not TopicNodes Is Nothing Then
		Dim F_AnnounceID
		If Dvbbs.Forum_Setting(76)="" Or Dvbbs.Forum_Setting(76)="0" Then Dvbbs.Forum_Setting(76)="UploadFile/"
		If right(Dvbbs.Forum_Setting(76),1)<>"/" Then Dvbbs.Forum_Setting(76)=Dvbbs.Forum_Setting(76)&"/"
		TopicNodes.documentElement.setAttribute "ishide",Dvbbs.Forum_Setting(75)
		TopicNodes.documentElement.setAttribute "filepath",Dvbbs.Forum_Setting(76)
		TopicNodes.documentElement.setAttribute "defaultfile",Dvbbs.Forum_Info(6)
		For Each TempNode in TopicNodes.documentElement.childNodes
			If Len(TempNode.getAttribute("f_readme"))>25 Then
				TempNode.attributes.getNamedItem("f_readme").text=Dvbbs.ChkBadWords(Left(TempNode.getAttribute("f_readme"),25))&"..."
			Else
				TempNode.attributes.getNamedItem("f_readme").text=Dvbbs.ChkBadWords(TempNode.getAttribute("f_readme"))
			End If
			F_AnnounceID = Split(TempNode.getAttribute("f_announceid"),"|")
			If Ubound(F_AnnounceID)>0 Then
				TempNode.setAttribute "rootid",F_AnnounceID(1)
				TempNode.setAttribute "announceid",F_AnnounceID(0)
			End If
			TempNode.removeAttribute "f_announceid"
			TempNode.attributes.getNamedItem("f_addtime").text=Formatdatetime(cdate(TempNode.getAttribute("f_addtime")),2)
		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub


'获取用户短信数据
Sub Load_UserMsg(Node)
	Dim Rs,Sql,TopicNodes,TempNode,Nums
	'Dv_BookMark
	If Node is Nothing Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Nums = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_8"))
	Sql = "Select top "&Nums&" id,sender,title,flag,sendtime from Dv_Message where incept='"&Dvbbs.Checkstr(MySpace.Space_Info.getAttribute("username"))&"' order by id desc"
	Set Rs = Dvbbs.Execute(sql)
	If not Rs.Eof Then
		SQL=Rs.GetRows(20)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","usermsg")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing
	If Not TopicNodes Is Nothing Then 
		For Each TempNode in TopicNodes.documentElement.childNodes
			If Len(TempNode.getAttribute("title"))>25 Then
				TempNode.attributes.getNamedItem("title").text=Dvbbs.ChkBadWords(Left(Dvbbs.Replacehtml(TempNode.getAttribute("title")),25))&"..."
			Else
				TempNode.attributes.getNamedItem("title").text=Dvbbs.ChkBadWords(Dvbbs.Replacehtml(TempNode.getAttribute("title")))
			End If
			TempNode.attributes.getNamedItem("sendtime").text=Formatdatetime(cdate(TempNode.getAttribute("sendtime")),2)
		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub

'获取用户收藏数据
Sub Load_UserFav(Node)
	Dim Rs,Sql,TopicNodes,TempNode,Nums
	'Dv_BookMark
	If Node is Nothing Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Nums = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_9"))
	Sql = "Select top "&Nums&" url,topic,addtime from Dv_BookMark where username='"&Dvbbs.Checkstr(MySpace.Space_Info.getAttribute("username"))&"' order by id desc"
	Set Rs = Dvbbs.Execute(sql)
	If not Rs.Eof Then
		SQL=Rs.GetRows(-1)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","userfav")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing
	If Not TopicNodes Is Nothing Then 
		For Each TempNode in TopicNodes.documentElement.childNodes
			If Len(TempNode.getAttribute("topic"))>25 Then
				TempNode.attributes.getNamedItem("topic").text=Dvbbs.ChkBadWords(Left(Dvbbs.Replacehtml(TempNode.getAttribute("topic")),25))&"..."
			Else
				TempNode.attributes.getNamedItem("topic").text=Dvbbs.ChkBadWords(Dvbbs.Replacehtml(TempNode.getAttribute("topic")))
			End If
			TempNode.attributes.getNamedItem("addtime").text=Formatdatetime(cdate(TempNode.getAttribute("addtime")),2)

		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub


'获取用户好友数据
'F_Mod 用户关系标识。 陌生人=0， 我的好友=1，黑名单=2 
Sub Load_UserFriend(Node)
	If Node is Nothing Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Dim Rs,Sql,TopicNodes,TempNode,Nums
	Nums = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_10"))
	Sql = "Select top "&Nums&" F_Friend,F_addtime,F_Mod From Dv_Friend where F_UserID="&MySpace.Sid&" order by F_mod,F_id desc"
	Set Rs = Dvbbs.Execute(sql)
	If not Rs.Eof Then
		SQL=Rs.GetRows(-1)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","userfriend")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing
	If Not TopicNodes Is Nothing Then 
		For Each TempNode in TopicNodes.documentElement.childNodes
			TempNode.attributes.getNamedItem("f_friend").text=Dvbbs.ChkBadWords(TempNode.getAttribute("f_friend"))
			TempNode.attributes.getNamedItem("f_addtime").text=Formatdatetime(cdate(TempNode.getAttribute("f_addtime")),2)
		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub


'获取主题数据
Sub Load_UserTopic(Node)
	'读取用户主题
	If Node is Nothing  or MySpace.Sid=0 Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Dim Rs,Sql,SqlStr,TopicNodes,TempNode
	Dim HideBoards
	Dim Page,MaxRows,Endpage,CountNum,PageSearch,SqlString,i
	PageSearch = ""
	Endpage = 0
	If MySpace.Act="topic" Then
		MaxRows = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_6"))
	Else
		MaxRows = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_0"))
	End If
	CountNum = 0
	Page = Request("Page")
	If IsNumeric(Page) = 0 or Page="" Then Page=1
	Page = Clng(Page)
	HideBoards = " Not Boardid in ("&LockBoards()&") "
	If MySpace.Act="topic" Then
		Sql = "Select "
	Else
		Sql = "Select top "&MaxRows
	End If
	Sql  = Sql & " topicid,boardid,title,postusername,postuserid,dateandtime,child,hits,votetotal,lastpost,lastposttime,istop,isvote,isbest,locktopic,expression,topicmode,mode,getmoney,getmoneytype,usetools,issmstopic,hidename"
	SqlStr = " From dv_Topic Where  "&HideBoards&" and PostUserID="&MySpace.Sid
	Sql = Sql & SqlStr & " Order By TopicID Desc"
	CountNum = Dvbbs.Execute("Select Count(topicid) "&SqlStr)(0)
	Dvbbs.SqlQueryNum = Dvbbs.SqlQueryNum + 1
	If Not IsObject(Conn) Then ConnectionDatabase
	Set Rs = Server.CreateObject ("adodb.recordset")
	Rs.Open Sql,Conn,1,1
	If Not Rs.Eof Then
		'CountNum = Rs.RecordCount
		If CountNum Mod MaxRows=0 Then
			Endpage = CountNum \ MaxRows
		Else
			Endpage = CountNum \ MaxRows+1
		End If
		Rs.MoveFirst
		If Page > Endpage Then Page = Endpage
		If Page < 1 Then Page = 1
		If Page >1 Then 				
			Rs.Move (Page-1) * MaxRows
		End if
		SQL=Rs.GetRows(MaxRows)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","topic")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing

	Dim Lastpost
	If Not TopicNodes Is Nothing Then 
		TopicNodes.documentElement.setAttribute "endpage",Endpage
		TopicNodes.documentElement.setAttribute "maxrows",MaxRows
		TopicNodes.documentElement.setAttribute "countnum",CountNum
		TopicNodes.documentElement.setAttribute "page",Page
		TopicNodes.documentElement.setAttribute "pagesearch",PageSearch
		TopicStats_Pic(TopicNodes.documentElement)
		For Each TempNode in TopicNodes.documentElement.childNodes
			TempNode.attributes.getNamedItem("title").text=Dvbbs.ChkBadWords(Dvbbs.Replacehtml(TempNode.getAttribute("title")))
			TempNode.attributes.getNamedItem("postusername").text=Dvbbs.ChkBadWords(TempNode.getAttribute("postusername"))
			i=0
			For each lastpost in Split(TempNode.getAttribute("lastpost"),"$")
				TempNode.setAttribute "lastpost_"& i,lastpost
				i=i+1
			Next
			TempNode.removeAttribute "lastpost"
		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub

'获取回复帖子数据
Sub Load_UserReply(Node)
	'读取用户回复
	If Node is Nothing or MySpace.Sid=0 Then
		Exit Sub
	Else
		Set Node = CheckNodes(Node,true)
	End If
	Dim Rs,Sql,SqlStr,TopicNodes,HideBoards,TempNode
	Dim Page,MaxRows,Endpage,CountNum,PageSearch,SqlString,i
	PageSearch = ""
	Endpage = 0
	If MySpace.Act="reply" Then
		MaxRows = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_7"))
	Else
		MaxRows = Dvbbs.CheckNumeric(MySpace.Space_Info.getAttribute("set_2"))
	End If
	CountNum = 0
	Page = Request("Page")
	If IsNumeric(Page) = 0 or Page="" Then Page=1
	Page = Clng(Page)
	HideBoards = " Not Boardid in("&LockBoards()&") "
	If MySpace.Act="reply" Then
		Sql = "Select"
	Else
		Sql = "Select top "&MaxRows
	End If
	Sql = Sql + " Announceid,BoardID,rootid,topic,Expression,username,postuserid,dateandtime,IsBest,LockTopic,Body,Length"
	SqlStr = " From "&Dvbbs.NowUseBbs&" Where parentid>0 and "&HideBoards&" and PostUserID="&MySpace.Sid
	Sql = Sql + SqlStr +" Order By Announceid Desc"
	Dvbbs.SqlQueryNum = Dvbbs.SqlQueryNum + 1
	CountNum = Dvbbs.Execute("Select Count(Announceid) "+SqlStr)(0)
	If Not IsObject(Conn) Then ConnectionDatabase
	Set Rs = Server.CreateObject ("adodb.recordset")
	Rs.Open Sql,Conn,1,1
	If Not Rs.Eof Then
		'CountNum = Rs.RecordCount
		If CountNum Mod MaxRows=0 Then
			Endpage = CountNum \ MaxRows
		Else
			Endpage = CountNum \ MaxRows+1
		End If
		Rs.MoveFirst
		If Page > Endpage Then Page = Endpage
		If Page < 1 Then Page = 1
		If Page >1 Then 				
			Rs.Move (Page-1) * MaxRows
		End if
		SQL=Rs.GetRows(MaxRows)
		Set TopicNodes = Dvbbs.ArrayToxml(sql,rs,"row","reply")
	Else
		Set TopicNodes = Nothing
	End If
	Rs.Close
	Set Rs = Nothing
	If Not TopicNodes Is Nothing Then
		TopicNodes.documentElement.setAttribute "endpage",Endpage
		TopicNodes.documentElement.setAttribute "maxrows",MaxRows
		TopicNodes.documentElement.setAttribute "countnum",CountNum
		TopicNodes.documentElement.setAttribute "page",Page
		TopicNodes.documentElement.setAttribute "pagesearch",PageSearch
		TopicStats_Pic(TopicNodes.documentElement)
		For Each TempNode in TopicNodes.documentElement.childNodes
			If TempNode.getAttribute("topic")="" Then
				TempNode.attributes.getNamedItem("topic").text = Left(Dvbbs.Replacehtml(TempNode.getAttribute("body")),30)
			Else
				TempNode.attributes.getNamedItem("topic").text=Dvbbs.ChkBadWords(Dvbbs.Replacehtml(TempNode.getAttribute("topic")))
			End If
			TempNode.removeAttribute "body"
			TempNode.attributes.getNamedItem("username").text=Dvbbs.ChkBadWords(TempNode.getAttribute("username"))
			i=0
		Next
		Node.appendChild(TopicNodes.documentElement)
	End If
End Sub

Sub BoardList()
	MySpace.XmlDoc.DocumentElement.appendChild Application(Dvbbs.CacheName&"_boardlist").documentElement.cloneNode(True)
End Sub

'限制访问的版块ID列表
Function LockBoards()
	Dim Nodes,ChildNode
	Dim BoardList,i
	If Dvbbs.Master or MySpace.Admin Then
		LockBoards= "444"
		Exit Function
	End If
	Set Nodes = Application(Dvbbs.CacheName&"_boardlist").documentElement.childNodes
	i = 0
	For Each ChildNode in Nodes
		i = i+1
		If ChildNode.getAttribute("checkout")="1" or ChildNode.getAttribute("hidden")=1 or ChildNode.getAttribute("checklock")=1 Then
			BoardList = BoardList & ChildNode.getAttribute("boardid")
			If i<Nodes.length Then BoardList =  BoardList & ","
		End If
	Next
	If BoardList<>"" Then
		BoardList = "444,777,"&BoardList
	Else
		BoardList= "444,777"
	End If
	If Right(BoardList,1)="," Then BoardList = Left(BoardList,Len(BoardList)-1)
	LockBoards = BoardList
End Function

'添加帖子状态图标信息
Sub TopicStats_Pic(Node)
	Node.setAttribute "bestpic",MySpace.Space_Info.getAttribute("skinpath")&"bestpic.gif" 'Dvbbs.mainpic(5)
	Node.setAttribute "votepic",MySpace.Space_Info.getAttribute("skinpath")&"votepic.gif" 'Dvbbs.mainpic(6)
	Node.setAttribute "islockpic",MySpace.Space_Info.getAttribute("skinpath")&"islockpic.gif" 'Dvbbs.mainpic(4)
	Node.setAttribute "hotpic",MySpace.Space_Info.getAttribute("skinpath")&"hotpic.gif" 'Dvbbs.mainpic(3)
	Node.setAttribute "openpic",MySpace.Space_Info.getAttribute("skinpath")&"openpic.gif" 'Dvbbs.mainpic(2)
	Node.setAttribute "ispic",MySpace.Space_Info.getAttribute("skinpath")&"openpic.gif" 'Dvbbs.mainpic(1)
End Sub
%>