indivgroup.asp

公司企业网站管理系统全站源码,用于企业内部对网站的管理

<!--#include file=../conn.asp-->
<!--#include file="inc/const.asp" -->
<!--#include file="../Dv_plus/IndivGroup/Dv_IndivGroup_Config.asp" -->
<%
Head()
dim admin_flag,info
admin_flag=",8,"
CheckAdmin(admin_flag)
Top_Nav()
Call main()
Footer()

Sub main()
	If Not IsObject(Dv_IndivGroup_Conn) Then Dv_IndivGroup_ConnectionDatabase
	Select Case Lcase(Request("action"))
		Case "grouplist" : GroupInfo()
		Case "save" : savegroup()
		Case "del" : del()
		Case "groupuserlist" : GroupUserList()
		Case "更新用户统计" : upusernum()
		Case "manage" : UserManage()
		Case Else
			GroupInfo()
	End Select
End Sub

Sub Top_Nav()
%>
<script language="JavaScript" src="../inc/Pagination.js"></script>
<table width="100%" border="0" cellspacing="1" cellpadding="3" align="center">
	<tr>
		<th width="100%" style="text-align:center;" colspan=2>论坛圈子管理</th>
	</tr>
	<tr>
		<td height="23" colspan="2" class=td1>请在插件管理的菜单管理中添加一级菜单“个性圈子”。</td>
	</tr>
	<tr>
		<td height="23" colspan="2" class=td1><b>用户圈子管理</b>：您可以添加修改或者删除论坛圈子。</td>
	</tr>
	<tr>
		<td height="23" colspan="2" class=td1>
			<button onclick="window.location='indivGroup.asp?action=addedit&orders=0'" class="button">添加圈子</button>
			<button onclick="window.location='indivGroup.asp'" class="button">圈子管理</button>
			<button onclick="window.location='indivGroup.asp?action=groupuserlist'" class="button">圈子用户管理</button>
		</td>
	</tr>
</table>
<br/>
<%
End Sub

'圈子列表
Sub GroupInfo()
	Dim Rs,SQL,GroupID
	Dim Page,Orders,ordername,keyword,SQLStr,QueryString
	Dim TotalRec,i,Pcount
	Dim AppUserID,UserGroup,Locked,ViewFlag
	Dim GroupName,GroupInfo,AppUserName,GroupStats,LimitUser

	If LCase(Request("action"))="pass" Then
		GroupID=Dvbbs.CheckNumeric(Request("GroupID"))
		Dv_IndivGroup_Conn.Execute("Update Dv_GroupName Set Stats=1,UserNum=1,PassDate='"&now()&"' Where ID="&GroupID)
		Set Rs=Dv_IndivGroup_Conn.Execute("Select ID,AppUserID,AppUserName From Dv_GroupName Where ID="&GroupID&" Order By ID Desc")
		If Not Rs.Eof Then
			Dv_IndivGroup_Conn.Execute("Insert Into Dv_GroupUser(GroupID,UserID,UserName,IsLock) Values("&Rs(0)&","&Rs(1)&",'"&Rs(2)&"',2)")
			AppUserID = Dvbbs.CheckNumeric(Rs(1))
			Rs.Close
			Set Rs=Dvbbs.Execute("Select UserGroup From Dv_User Where UserID="&AppUserID)
			If Not Rs.Eof Then
				UserGroup=Rs(0)
				If IsNull(UserGroup) Or UserGroup="" Then
					UserGroup = ","&GroupID&","
				Else
					If InStr(UserGroup,","&GroupID&",")<1 Then UserGroup = UserGroup&GroupID&","
				End If
				Dvbbs.Execute("Update Dv_User Set UserGroup='"&UserGroup&"' Where UserID="&AppUserID)
			End If
		End If
		Rs.Close:Set Rs=Nothing
	End If

	If LCase(Request("action"))="batchmodify" Then
		If Request.Form("groupid")="" Then
			Response.write "<script language='javascript'>alert('请选择要修改的项');</script>"
		Else
			For i=1 To Request.Form("groupid").Count
				GroupID = Dvbbs.CheckNumeric(Request.Form("groupid")(i))
				LimitUser = Dvbbs.CheckNumeric(Request.Form("limituser_"&GroupID))
				GroupStats = Dvbbs.CheckNumeric(Request.Form("GroupStats_"&GroupID))
				Set Rs = Dv_IndivGroup_Conn.Execute("Select ID,GroupName,GroupInfo,AppUserID,AppUserName,Stats,LimitUser,Locked,ViewFlag From Dv_GroupName Where ID="&GroupID)
				If Not Rs.Eof Then
					SQL = Rs.GetRows(1)
					Rs.Close
					If SQL(5,0)=0 And SQL(5,0) < GroupStats Then
						Set Rs = Dv_IndivGroup_Conn.Execute("Select * From Dv_GroupUser Where GroupID="&GroupID&" And UserID="&SQL(3,0))
						If Rs.Eof Then Dv_IndivGroup_Conn.Execute("Insert Into Dv_GroupUser(GroupID,UserID,UserName,IsLock) Values("&SQL(0,0)&","&SQL(3,0)&",'"&SQL(4,0)&"',2)")
						Rs.Close

						Set Rs=Dvbbs.Execute("Select UserGroup From Dv_User Where UserID="&SQL(3,0))
						If Not Rs.Eof Then
							UserGroup=Rs(0)
							If IsNull(UserGroup) Or UserGroup="" Then
								UserGroup = ","&GroupID&","
							Else
								If InStr(UserGroup,","&GroupID&",")<1 Then UserGroup = UserGroup&GroupID&","
							End If
							Dvbbs.Execute("Update Dv_User Set UserGroup='"&UserGroup&"' Where UserID="&SQL(3,0))
						End If
					End If
					Dv_IndivGroup_Conn.Execute("Update Dv_GroupName Set LimitUser="&LimitUser&",Stats="&GroupStats&" Where ID="&GroupID)
				End If
			Next
			Response.write "<script language='javascript'>alert('修改成功！');</script>"
		End If
	End If

	TotalRec=0
	Page=Dvbbs.CheckNumeric(Request("page")):If Page=0 Then Page=1
	QueryString = "page="&page
	Orders=Dvbbs.CheckNumeric(Request("orders"))
	QueryString = QueryString & "&orders="&orders
	keyword=Dvbbs.CheckStr(Request("keyword"))
	If keyword<>"" Then	QueryString = QueryString & "&keyword="&keyword

	SQL="id,groupname,groupinfo,appuserid,appusername,usernum,stats,postnum,topicnum,limituser,AppDate,PassDate,Locked,ViewFlag"
	If orders=1 Then
		SQLStr = "Where Stats=0"
	ElseIf orders=0 Then
		SQLStr = ""
	Else
		SQLStr = "Where Stats>0"
	End If
	If keyword<>"" Then
		If SQLStr="" Then
			SQLStr = "Where GroupName like '%"&keyword&"%'"
		Else
			SQLStr = SQLStr&" And GroupName like '%"&keyword&"%'"
		End If
	End if
	Select Case orders
		Case 0
			SQL="Select "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By ID Desc"
		Case 1
			SQL="Select "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By ID Desc"
		Case 2
			SQL="Select "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By ID Desc"
		Case 3
			SQL="Select top 20 "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By PostNum Desc"
		Case 4
			SQL="Select top 20 "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By UserNum Desc"
		Case Else
			SQL="Select "&SQL&" From [Dv_GroupName] "&SQLStr&" Order By ID Desc"
	End Select

	If LCase(Request("action"))="addedit" Then
		GroupID=Dvbbs.CheckNumeric(Request("GroupID"))
		Set Rs=Dv_IndivGroup_Conn.Execute("Select GroupName,GroupInfo,AppUserName,Stats,LimitUser,Locked,ViewFlag From Dv_GroupName Where id="&GroupID)
		If Not Rs.Eof Then
			GroupName = Rs("GroupName")
			GroupInfo = Rs("GroupInfo")
			AppUserName = Rs("AppUserName")
			GroupStats  =Rs("Stats")
			LimitUser = Rs("LimitUser")
			Locked = Rs("Locked")
			ViewFlag = Rs("ViewFlag")
		Else
			GroupName = ""
			GroupInfo = ""
			AppUserName = ""
			GroupStats  = 1
			LimitUser = ""
			Locked = 0
			ViewFlag = 1
		End If
		Rs.Close:Set Rs=Nothing
%>
<table width="100%" border="0" cellspacing="1" cellpadding="3" align="center">
	<form method="POST" action="indivGroup.asp?action=save&<%=QueryString%>" name="groupform">
	<input type="hidden" name="groupid" value="<%=GroupID%>">
	<tr> 
		<th width="100%" style="text-align:center;" colspan=2><b>添加/修改圈子</b></th>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>圈子名称</b></td>
		<td width="80%" class=td1>
		<input type="text" name="Groupname" size="35" value="<%=Groupname%>">
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>管理员名称</b></td>
		<td width="80%" class=td1>
		<input type="text" name="AppUserName" size="35" value="<%=AppUserName%>">
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>圈子说明</b></td>
		<td width="80%" class=td1>
		<textarea rows="4" cols="35" name="GroupInfo"><%=GroupInfo%></textarea>
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>成员人数上限</b></td>
		<td width="80%" class=td1>
		<input type="text" name="LimitUser" size="35" value="<%=LimitUser%>">
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>圈子状态</b></td>
		<td width="80%" class=td1>
		<%If GroupStats=0 Then Response.write "<input type=""radio"" class=""radio"" name=""GroupStats"" value=""0""/>审核"%>
		<input type="radio" class="radio" name="GroupStats" value="1"/>正常
		<input type="radio" class="radio" name="GroupStats" value="2"/>锁定
		<input type="radio" class="radio" name="GroupStats" value="3"/>关闭
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>成员加入</b></td>
		<td width="80%" class=td1>
		<input type="radio" class="radio" name="locked" value="0"/>自由加入
		<input type="radio" class="radio" name="locked" value="1"/>需要审核
		</td>
	</tr>
	<tr> 
		<td width="20%" class=td1><b>浏览设置</b></td>
		<td width="80%" class=td1>
		<input type="radio" class="radio" name="viewflag" value="0"/>公开
		<input type="radio" class="radio" name="viewflag" value="1"/>不公开
		</td>
	</tr>
	<tr><td colspan="2">（公开：任何人都可以浏览；不公开：只有成员能浏览）</td></tr>
	<tr><td height="23" colspan="2" class=td1><input type="submit" class="button" name="Submit" value="提 交"></tr>
	</form>
	<script language="JavaScript">
	<!--
	chkradio(document.groupform.GroupStats,'<%=GroupStats%>')
	chkradio(document.groupform.islock,'<%=Locked%>')
	chkradio(document.groupform.viewflag,'<%=viewflag%>')
	//-->
	</script>
</table>
<br />
<%
	End If
%>
<table width="100%" border="0" cellspacing="1" cellpadding="3" align="center">
	<form method="post" action="indivGroup.asp" name="searchform">
	<tr>
		<td colspan="10">
		&nbsp;个性圈子搜索：<input name="keyword" type="text" value="<%=keyword%>" size="15" /> <input name="Submit" type="submit" class="button" value="搜索" />
		<select name="orders" onchange='javascript:submit()'>
			<option value="0" selected>所有圈子</option>
			<option value="1">待审核圈子</option>
			<option value="2">最新圈子</option>
			<option value="3">发贴总数Top20</option>
			<option value="4">成员总数Top20</option>
		</select>
		<script language="javascript">
		function setorders(ordernum){
			document.searchform.orders.options(ordernum).selected=1;
		}
		setorders(<%=orders%>);
		</script>

		</td>
	</tr>
	</form>
	<form method="post" action="indivGroup.asp?action=batchmodify&<%=QueryString%>" name="batchform">
	<tr>
		<th style="text-align:center;">&nbsp;</th>
		<th style="text-align:center;">圈子名称</th>
		<th style="text-align:center;">圈子申请人名称</th>
		<th style="text-align:center;">用户总数</th>
		<th style="text-align:center;">帖子总数</th>
		<th style="text-align:center;">主题总数</th>
		<th style="text-align:center;">成员人数上限</th>
		<th style="text-align:center;">申请时间</th>
		<th style="text-align:center;">状态</th>
		<th style="text-align:center;">操作</th>
	</tr>
<%
	Const EachPageCount=20
	Set Rs=Server.CreateObject("ADODB.RecordSet")
	Rs.Open SQL,Dv_IndivGroup_Conn,1,1
	Dvbbs.SqlQueryNum = Dvbbs.SqlQueryNum + 1
	If Not Rs.Eof Then
		TotalRec=Rs.RecordCount
		If TotalRec Mod EachPageCount=0 Then
			Pcount= TotalRec \ EachPageCount
		Else
			Pcount= TotalRec \ EachPageCount+1
		End If

		If orders=3 Or orders=4 Then
			SQL=Rs.GetRows(-1)
		Else
			RS.MoveFirst
			If Page > Pcount Then Page = Pcount
			If Page < 1 Then Page=1
			RS.Move (Page-1) * EachPageCount
			SQL=Rs.GetRows(EachPageCount)
		End If
		Rs.Close:Set Rs=Nothing
		'id=0,groupname=1,groupinfo=2,appuserid=3,appusername=4,usernum=5,stats=6,postnum=7,topicnum=8,limituser=9,appDate=10,PassDate=11
		For i = 0 To Ubound(SQL,2)
%>
	<tr>
		<td class="td1"><input type="checkbox" name="groupid" value="<%=SQL(0,i)%>"/></td>
		<td class="td1"><a title="<%=SQL(2,i)%>"><%=SQL(1,i)%></a></td>
		<td class="td1"><a href="../dispuser.asp?id=<%=SQL(3,i)%>" target="_blank"><%=SQL(4,i)%></a></td>
		<td class="td1"><%=SQL(5,i)%></td>
		<td class="td1"><%=SQL(7,i)%></td>
		<td class="td1"><%=SQL(8,i)%></td>
		<td class="td1" align="center"><input type="text" name="limituser_<%=SQL(0,i)%>" value="<%=SQL(9,i)%>" size="8"/></td>
		<td class="td1"><%=SQL(10,i)%></td>
		<td class="td1">
		<select size="1" name="GroupStats_<%=SQL(0,i)%>">
			<option value="1">正常</option>
			<option value="2">锁定</option>
			<option value="3">关闭</option>
			<option value="0">审核</option>
		</select>
		<script language="javascript">ChkSelected(document.batchform.GroupStats_<%=SQL(0,i)%>,'<%=SQL(6,i)%>');</script>
		<%=GroupStatsStr(SQL(6,i))%>
		</td>
		<td height="23" class="td2" align="right">
			<%if SQL(6,i)=0 Then Response.write "<a href=""indivGroup.asp?groupid="&SQL(0,i)&"&action=pass&"&QueryString&""">通过</a> | "%>
			<a href="indivGroup.asp?groupid=<%=SQL(0,i)%>&action=addedit&<%=QueryString%>">修改</a> | 
			<a href="indivGroup.asp?groupid=<%=SQL(0,i)%>&action=del&<%=QueryString%>">删除</a> | 
			<a href="indivGroup.asp?action=GroupUserList&groupid=<%=SQL(0,i)%>">查看用户</a>
		</td>
	</tr>
<%
		Next
	Else
		If orders=1 Then
			Response.write "<tr><td class=""td1"" colspan=""10"">没有待审核的圈子</td></tr>"
		Else
			Response.write "<tr><td class=""td1"" colspan=""10"">没找到满足搜索条件的圈子</td></tr>"
		End If
		Rs.Close:Set Rs=Nothing
	End If
%>
	<tr>
		<td colspan="10">
			<div style="margin-left:35px;">
			<input type="submit" name="Submit" value="批量修改" onclick="return clicksubmit(this.form);" class="button"/>
			<input type="checkbox" name="chkall" value="on" onclick="CheckAll(this.form);" class="chkbox" />&nbsp;全选/取消 
			</div>
		</td>
	</tr>
	</form>
</table>
<script language="javascript">
PageList('<%=page%>',10,'<%=EachPageCount%>','<%=TotalRec%>','?action=grouplist',1);
function CheckAll(form){
	for (var i=0;i<form.elements.length;i++){
		var e = form.elements[i];
		if (e.name == 'groupid') e.checked = form.chkall.checked;
	}
}
function clicksubmit(form){
	if(confirm('您确定执行的操作吗?')){
		this.document.batchform.submit();
		return true;
	}else{
		return false;
	}
}
</script>
<%