servertime.asp

一个简历管理系统

<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%
'=======================================================================
'服务器时间程序 v1.2 by 秋忆
'　　　2007年6月24日

'说明：此时间程序需要服务器支持ASP，不同于网上一般的JS显示时间，
'此时间是显示服务器的系统时间，避免了本地时间不准确而显示错误时间。
'上传到网站，使用<script type="text/javascript" src="Server_time.asp?type=123"></script>调用即可显示。
'其中参数type可以是123数字中的任意组合（12、13、23、123）：1显示日期；2显示时间；3显示星期。
'演示地址：http://www.skymean.com

'声明：此信息不影响程序执行，转载程序请保留此信息！谢谢！
'=======================================================================

Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
Response.Expires = 0
Response.CacheControl = "no-cache"
Response.Buffer = True

Dim ShowType
ShowType = Trim(Request.QueryString("type")) & ""
IF Not IsNumeric(ShowType) Or ShowType = "" Then
	ShowType = "123"
End If

Function GetWeek()
	Dim Weekday_Num, Weekday_Name
	Weekday_Num = Weekday(Now()) - 1
	Select Case Weekday_Num
		Case 0
			Weekday_Name = "星期日"
		Case 1
			Weekday_Name = "星期一"
		Case 2
			Weekday_Name = "星期二"
		Case 3
			Weekday_Name = "星期三"
		Case 4
			Weekday_Name = "星期四"
		Case 5
			Weekday_Name = "星期五"
		Case 6
			Weekday_Name = "星期六"
		Case Else
			Weekday_Name = ""
	End Select
	GetWeek = Weekday_Name
End Function
%>
<!--
//服务器时间程序 v1.2 by 秋忆
//     2007年6月24日
//演示地址：http://www.skymean.com
function ShowServerTime()
{
	try
	{
		if(ServerTime3.innerHTML*1<59)
		{
			ServerTime3.innerHTML=ServerTime3.innerHTML*1+1;
		}
		else
		{
			if(ServerTime2.innerHTML*1<59)
			{
				ServerTime2.innerHTML=ServerTime2.innerHTML*1+1;
			}
			else
			{
				if(ServerTime1.innerHTML*1<23)
				{
					ServerTime1.innerHTML=ServerTime1.innerHTML*1+1;
				}
				else
				{
					ServerTime1.innerHTML=0;
				}
				ServerTime2.innerHTML=0;
			}
			if(ServerTime2.innerHTML*1<10) {ServerTime2.innerHTML="0"+ServerTime2.innerHTML;}
			ServerTime3.innerHTML=0;
		}
		if(ServerTime3.innerHTML*1<10) {ServerTime3.innerHTML="0"+ServerTime3.innerHTML;}
		setTimeout("ShowServerTime()",1000);
	}catch(e){}
}

try
{
	var time_ty="position:relative;font:12px Verdana,Times,serif;color:#000000;margin:0;padding:0;border:0;";
	document.write('<span style="'+time_ty+'">');
<%
IF Instr(ShowType, "1") > 0 Then
	Response.Write("document.write('<span id=""ServerDate"">"&Date()&"</span>');" & vbcrlf)
	IF Instr(ShowType, "2") > 0 Or Instr(ShowType, "3") > 0 Then
		Response.Write("document.write(' ');" & vbcrlf)
	End If
End If
IF Instr(ShowType, "2") > 0 Then
	Response.Write("document.write('<span id=""ServerHour"">"&Hour(Now())&"</span>:<span id=""ServerMinute"">"&Minute(Now())&"</span>:<span id=""ServerSecond"">"&Second(Now())&"</span>');" & vbcrlf)
	IF Instr(ShowType, "3") > 0 Then
		Response.Write("document.write(' ');" & vbcrlf)
	End If
	Response.Write("var ServerTime1=document.getElementById('ServerHour');" & vbcrlf)
	Response.Write("var ServerTime2=document.getElementById('ServerMinute');" & vbcrlf)
	Response.Write("var ServerTime3=document.getElementById('ServerSecond');" & vbcrlf)
	Response.Write("ShowServerTime();" & vbcrlf)
End If
IF Instr(ShowType, "3") > 0 Then
	Response.Write("document.write('<span id=""ServerWeek"">"&GetWeek()&"</span>');")
End If
%>
	document.write('</span>');
}catch(e){}
//-->