📄 cls_viewresume.asp

📁 一个简历管理系统
💻 ASP
字号:
<%
'程序名称：萍萍多用户简历系统
'程序版本：v1.0
'开发环境：SQL Server 2005 + IIS6.0（SQL Server 2000也能用）
'程序设计：秋忆工作室
'作者网站：http://www.skymean.com
'联系邮箱：mylove21@163.com
%>
<%
Class viewResume
	Private UserID,sql,rs,IsErr,data,Html,i

	Private Sub Class_Initialize()
		Dim ReleaseTime,A
		IsErr = False
		UserID = Trim(Request.QueryString("uid"))
		If sys.ChkEmpty(UserID) Then
			UserID = sys.m_UserID
		End If
		If Not sys.IsNum(UserID) Then
			IsErr = True
			sys.Echo("<div style=""margin:20px 0 20px 0;"">"&sys.WarnningBox("错误：参数不正确，请确保操作无误！<a href=""javascript:window.close();"">「关闭」</a>")&"</div>")
			Exit Sub
		End If
		
		ConnData()
		If DB_State <> 1 Then
			IsErr = True
			Exit Sub
		End If
		sql = "SELECT [ReleaseTime] FROM [User] WHERE [ID]=" & UserID
		Set rs = Conn.Execute(sql)
		If rs.Eof And rs.Bof Then
			IsErr = True
		Else
			ReleaseTime = rs(0)
		End If
		rs.Close
		Set rs = Nothing
		If IsErr Then
			sys.Echo("<div style=""margin:20px 0 20px 0;"">"&sys.WarnningBox("错误：此用户不存在或者已经被删除！<a href=""javascript:window.close();"">「关闭」</a>")&"</div>")
			CloseConn()
		ElseIf sys.ChkEmpty(ReleaseTime) And UserID <> sys.m_UserID Then
			Set A = New Admin
			If A.IsLogin <> "yes" Then
				IsErr = True
				sys.Echo("<div style=""margin:20px 0 20px 0;"">"&sys.WarnningBox("抱歉，此用户没有发布简历，不能查看！<a href=""javascript:window.close();"">「关闭」</a>")&"</div>")
				CloseConn()
			End If
			Set A = Nothing
		End If
	End Sub
	
	Public Function ShowAll()
		If IsErr Then Exit Function
		
		BasicInfo()
		ContactInfo()
		EducateLive()
		CurrentWork()
		WorkLive()
		BringUpLive()
		JobPurpose()
		OtherCert()
		SkillInfo()
	End Function
	
	Public Function BasicInfo()
		If IsErr Then Exit Function
		
		ReDim data(13)
		sql = "SELECT [RealName],[Sex],[Birthday],[Nation],[PolityVisage],[NativePlace],[RegPerRes],[Course],[CourseType],[StudyForm],[AbilityType],[LeaveSchoolType],[GraduateSchool],[Speciality] FROM [BasicInfo] WHERE [UserID]=" & UserID
		Set rs = Conn.Execute(sql)
		If Not (rs.Eof And rs.Bof) Then
			For i=0 To 13
				data(i) = rs(i)
			Next
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title">姓　名</td>
    <td><%=sys.HTML_Encode(data(0))%></td>
    <td class="title">性　别</td>
    <td>
<%
		If Not sys.ChkEmpty(data(1)) Then
			If data(1) = False Then
				sys.Echo("男")
			ElseIf data(1) = True Then
				sys.Echo("女")
			End If
		End If
%>
    </td>
    <td class="title">出生年月</td>
    <td><%=sys.DateToStr(data(2),"Y-m-d")%></td>
<%
		If LCase(Trim(Request.QueryString("mode"))) <> "nopicture" Then
			sys.Echo("    <td rowspan=""5"" style=""width:133px;""><img align=""absmiddle"" src=""viewResume.asp?mode=photo&uid="&UserID&""" onload=""resizepic(this,133,160);"" /></td>")
		End If
%>
  </tr>
  <tr>
    <td class="title">民　族</td>
    <td><%=sys.HTML_Encode(data(3))%></td>
    <td class="title" nowrap>政治面貌</td>
    <td><%=sys.HTML_Encode(data(4))%></td>
    <td class="title">籍　贯</td>
    <td><%=sys.HTML_Encode(data(5))%></td>
    </tr>
  <tr>
    <td class="title" nowrap>户口所在地</td>
    <td><%=sys.HTML_Encode(data(6))%></td>
    <td class="title">学　历</td>
    <td><%=sys.HTML_Encode(data(7))%></td>
    <td class="title">学历类型</td>
    <td><%=sys.HTML_Encode(data(8))%></td>
    </tr>
  <tr>
    <td class="title">学习形式</td>
    <td><%=sys.HTML_Encode(data(9))%></td>
    <td class="title">人才类别</td>
    <td><%=sys.HTML_Encode(data(10))%></td>
    <td class="title" nowrap>毕业/结业</td>
    <td><%=sys.HTML_Encode(data(11))%></td>
    </tr>
  <tr>
    <td class="title">毕业院校</td>
    <td colspan="2"><%=sys.HTML_Encode(data(12))%></td>
    <td class="title">专　业</td>
    <td colspan="2"><%=sys.HTML_Encode(data(13))%></td>
    </tr>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function

	Public Function ContactInfo()
		If IsErr Then Exit Function
		
		ReDim data(5)
		sql = "SELECT [MobilePhone],[LineatePhone],[Postalcode],[Address],[Email],[WebSite] FROM [ContactInfo] WHERE [UserID]=" & UserID
		Set rs = Conn.Execute(sql)
		If Not (rs.Eof And rs.Bof) Then
			For i=0 To 5
				data(i) = rs(i)
			Next
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap>手机号码</td>
    <td><%=sys.HTML_Encode(data(0))%></td>
    <td class="title" nowrap>固定电话</td>
    <td><%=sys.HTML_Encode(data(1))%></td>
  </tr>
  <tr>
    <td class="title">邮　编</td>
    <td><%=sys.HTML_Encode(data(2))%></td>
    <td class="title">联系地址</td>
    <td><%=sys.HTML_Encode(data(3))%></td>
  </tr>
  <tr>
    <td class="title">电子邮件</td>
    <td><%=sys.HTML_Encode(data(4))%></td>
    <td class="title">个人主页</td>
    <td><%=sys.HTML_Encode(data(5))%></td>
  </tr>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function

	Public Function EducateLive()
		If IsErr Then Exit Function
		
		ReDim data(0)
		Html = ""
		data(0) = 2
		sql = "SELECT [CurrentCalling],[From],[To],[Speciality],[Course] FROM [EducateLive] WHERE [UserID]=" & UserID & "ORDER BY [From]"
		Set rs = Server.CreateObject("ADODB.RecordSet")
		rs.Open sql,Conn,1,1
		If Not (rs.Eof And rs.Bof) Then
			data(0) = rs.RecordCount + 1
			While Not rs.Eof
				Html = Html & "  <tr>" & vbcrlf
				For i=0 To 4
					If i = 1 Or i = 2 Then
						Html = Html & "    <td>"&sys.DateToStr(rs(i),"Y-m-d")&"</td>" & vbcrlf
					Else
						Html = Html & "    <td>"&sys.HTML_Encode(rs(i))&"</td>" & vbcrlf
					End If
				Next
				Html = Html & "  </tr>" & vbcrlf
				rs.MoveNext
			Wend
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="<%=data(0)%>" nowrap>教育经历</td>
    <td class="title2">现从事行业</td>
    <td class="title2">从</td>
    <td class="title2">至</td>
    <td class="title2">所属专业</td>
    <td class="title2">学　历</td>
  </tr>
<%
		If Not sys.ChkEmpty(Html) Then
			sys.Echo(Html)
		Else
%>
  <tr>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
  </tr>
<%
		End If
%>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function CurrentWork()
		If IsErr Then Exit Function
		
		ReDim data(3)
		sql = "SELECT [SchoolName],[CurrentProfession],[ProfessionalLevel],[CurrentPay] FROM [CurrentWork] WHERE [UserID]=" & UserID
		Set rs = Conn.Execute(sql)
		If Not (rs.Eof And rs.Bof) Then
			For i=0 To 3
				data(i) = rs(i)
			Next
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="2" nowrap>现职业概况</td>
    <td class="title2">学校名称</td>
    <td class="title2">现从事职业</td>
    <td class="title2">现职位级别</td>
    <td class="title2">目前薪水</td>
  </tr>
  <tr>
    <td><%=sys.HTML_Encode(data(0))%></td>
    <td><%=sys.HTML_Encode(data(1))%></td>
    <td><%=sys.HTML_Encode(data(2))%></td>
    <td><%=sys.HTML_Encode(data(3))%></td>
  </tr>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function WorkLive()
		If IsErr Then Exit Function
		
		ReDim data(0)
		Html = ""
		data(0) = 3
		sql = "SELECT [UnitsName],[From],[To],[DeptJob],[Responsibility] FROM [WorkLive] WHERE [UserID]=" & UserID & "ORDER BY [From]"
		Set rs = Server.CreateObject("ADODB.RecordSet")
		rs.Open sql,Conn,1,1
		If Not (rs.Eof And rs.Bof) Then
			data(0) = rs.RecordCount*2+1
			While Not rs.Eof
				Html = Html & "  <tr>" & vbcrlf
				For i=0 To 3
					If i = 1 Or i = 2 Then
						Html = Html & "    <td>"&sys.DateToStr(rs(i),"Y-m-d")&"</td>" & vbcrlf
					Else
						Html = Html & "    <td>"&sys.HTML_Encode(rs(i))&"</td>" & vbcrlf
					End If
				Next
				Html = Html & "  </tr>" & vbcrlf
				Html = Html & "  <tr>" & vbcrlf
				Html = Html & "    <td class=""title2"">工作职责</td>" & vbcrlf
				Html = Html & "    <td colspan=""3"" align=""left""><div style=""margin:4px"">"&sys.HTML_Encode(rs(i))&"</div></td>" & vbcrlf
				Html = Html & "  </tr>" & vbcrlf
				rs.MoveNext
			Wend
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="<%=data(0)%>" nowrap>工作经历</td>
    <td class="title2">单位名称</td>
    <td class="title2">从</td>
    <td class="title2">至</td>
    <td class="title2">所属部门及所任职位</td>
  </tr>
<%
		If Not sys.ChkEmpty(Html) Then
			sys.Echo(Html)
		Else
%>
  <tr>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
  </tr>
  <tr>
    <td class="title2">工作职责</td>
    <td colspan="3"></td>
  </tr>
<%
		End If
%>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function BringUpLive()
		If IsErr Then Exit Function
		
		ReDim data(0)
		Html = ""
		data(0) = 2
		sql = "SELECT [CoursesName],[From],[To],[Certificate],[Organization] FROM [BringUpLive] WHERE [UserID]=" & UserID & "ORDER BY [From]"
		Set rs = Server.CreateObject("ADODB.RecordSet")
		rs.Open sql,Conn,1,1
		If Not (rs.Eof And rs.Bof) Then
			data(0) = rs.RecordCount + 1
			While Not rs.Eof
				Html = Html & "  <tr>" & vbcrlf
				For i=0 To 4
					If i = 1 Or i = 2 Then
						Html = Html & "    <td>"&sys.DateToStr(rs(i),"Y-m-d")&"</td>" & vbcrlf
					Else
						Html = Html & "    <td>"&sys.HTML_Encode(rs(i))&"</td>" & vbcrlf
					End If
				Next
				Html = Html & "  </tr>" & vbcrlf
				rs.MoveNext
			Wend
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="<%=data(0)%>" nowrap>培训经历</td>
    <td class="title2">课程名称</td>
    <td class="title2">从</td>
    <td class="title2">至</td>
    <td class="title2">获得证书</td>
    <td class="title2">培训机构</td>
  </tr>
<%
		If Not sys.ChkEmpty(Html) Then
			sys.Echo(Html)
		Else
%>
  <tr>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
  </tr>
<%
		End If
%>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function SkillInfo()
		If IsErr Then Exit Function
		
		ReDim data(5)
		sql = "SELECT [OnesStrongSuit],[Language],[ITSkill],[SelfEvaluate],[StateAtSchool],[Remark] FROM [SkillInfo] WHERE [UserID]=" & UserID
		Set rs = Conn.Execute(sql)
		If Not (rs.Eof And rs.Bof) Then
			For i=0 To 5
				data(i) = rs(i)
			Next
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">职业技能与特长</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(0)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">外语及方言</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(1)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">IT技能</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(2)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">在校情况</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(4)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">自我评价</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(3)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" nowrap width="150">特别说明</td>
    <td align="left"><div style="margin:4px"><%=sys.SimUBB(sys.HTML_Encode(data(5)))%></div></td>
  </tr>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function JobPurpose()
		If IsErr Then Exit Function
		
		ReDim data(0)
		Html = ""
		data(0) = 2
		sql = "SELECT [Job],[ExpectPay],[JobProperty],[OnDutyTime] FROM [JobPurpose] WHERE [UserID]=" & UserID & "ORDER BY [ID]"
		Set rs = Server.CreateObject("ADODB.RecordSet")
		rs.Open sql,Conn,1,1
		If Not (rs.Eof And rs.Bof) Then
			data(0) = rs.RecordCount + 1
			While Not rs.Eof
				Html = Html & "  <tr>" & vbcrlf
				For i=0 To 3
					If i = 3 Then
						Html = Html & "    <td>"&sys.DateToStr(rs(i),"H:I")&"</td>" & vbcrlf
					Else
						Html = Html & "    <td>"&sys.HTML_Encode(rs(i))&"</td>" & vbcrlf
					End If
				Next
				Html = Html & "  </tr>" & vbcrlf
				rs.MoveNext
			Wend
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="<%=data(0)%>" nowrap width="150">求职意向</td>
    <td class="title2">应聘职位</td>
    <td class="title2">期望薪水（税前）</td>
    <td class="title2">工作性质</td>
    <td class="title2">到岗时间</td>
  </tr>
<%
		If Not sys.ChkEmpty(Html) Then
			sys.Echo(Html)
		Else
%>
  <tr>
    <td></td>
    <td></td>
    <td></td>
    <td></td>
  </tr>
<%
		End If
%>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
	
	Public Function OtherCert()
		If IsErr Then Exit Function
		
		ReDim data(0)
		Html = ""
		data(0) = 2
		sql = "SELECT [OtherCertificate],[GetTime] FROM [OtherCert] WHERE [UserID]=" & UserID & "ORDER BY [GetTime]"
		Set rs = Server.CreateObject("ADODB.RecordSet")
		rs.Open sql,Conn,1,1
		If Not (rs.Eof And rs.Bof) Then
			data(0) = rs.RecordCount + 1
			While Not rs.Eof
				Html = Html & "  <tr>" & vbcrlf
				For i=0 To 1
					If i = 1 Then
						Html = Html & "    <td>"&sys.DateToStr(rs(i),"Y-m-d")&"</td>" & vbcrlf
					Else
						Html = Html & "    <td>"&sys.HTML_Encode(rs(i))&"</td>" & vbcrlf
					End If
				Next
				Html = Html & "  </tr>" & vbcrlf
				rs.MoveNext
			Wend
		End If
		rs.Close
		Set rs = Nothing
%>
<table class="TableStyle1" cellspacing="1" cellpadding="0">
  <tr>
    <td class="title" rowspan="<%=data(0)%>" nowrap width="150">其他证书</td>
    <td class="title2">证书名称</td>
    <td class="title2">获得时间</td>
  </tr>
<%
		If Not sys.ChkEmpty(Html) Then
			sys.Echo(Html)
		Else
%>
  <tr>
    <td></td>
    <td></td>
  </tr>
<%
		End If
%>
</table>
<div class="br1"></div>
<%
		Erase data
	End Function
End Class
%>
💿 文件大小 117 K
👤 上传用户 xu__tiger
📂 所属分类企业管理
🏷️ 相关标签

#管理系统
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -