owfe.bat

一个工作流设计及定义的系统,可以直接与数据库结合进行系统工作流程的定义及应用.

@echo off

rem
rem starting one OpenWFE component
rem
rem $Id: owfe.bat,v 1.4 2004/09/20 18:55:35 jmettraux Exp $
rem




set APP=%1
set FLAVOUR=%2-%APP%

set ETC=%ETC%\%APP%

rem if "%APP%" == "droflo"  set ETC=%OPENWFE_HOME%\webapps\droflo\WEB-INF\etc
rem obsolete

if "%APP%" == "reactor" set JYTHON=-Dpython.path=%JARS%\jyLib.jar


set CONF=%ETC%\%FLAVOUR%-configuration.xml
if exist "%CONF%" goto confOk
set CONF=%ETC%\%APP%-configuration.xml
set FLAVOUR=%APP%
:confOk

rem jesus, it's been a long time since I haven't used a 'goto'...

set LOGCONF=file:%ETC%\logging.xml
set CLASS=openwfe.org.Application

rem
rem security settings

set POLICY=%ETC%\win-%FLAVOUR%-policy.conf
if exist "%POLICY%" goto policyOk
set POLICY=%ETC%\%FLAVOUR%-policy.conf
if exist "%POLICY%" goto policyOk
set POLICY=%ETC%\win-%APP%-policy.conf
if exist "%POLICY%" goto policyOk
set POLICY=%ETC%\%APP%-policy.conf
if exist "%POLICY%" goto policyOk
set POLICY=
:policyOk

set LOGIN=%ETC%\%FLAVOUR%-login.conf
if exist "%LOGIN%" goto loginOk
set LOGIN=%ETC%\%APP%-login.conf
if exist "%LOGIN%" goto loginOk
set LOGIN=
:loginOk

if "%POLICY%" == "" goto noSecurity
if "%LOGIN%" == "" goto noSecurity
set SECURITY=-Djava.security.manager -Djava.security.policy=%POLICY% -Djava.security.auth.login.config=%LOGIN%
goto securityOk
:noSecurity
set SECURITY=
:securityOk

rem echo sec: %SECURITY%


rem
rem launch component

cd %OPENWFE_HOME%

%JAVA_HOME%\bin\java -Dapp=%APP% %ENCODING% -Dlog4j.configuration=%LOGCONF% %SECURITY% %JYTHON% -cp %CP% %CLASS% %CONF%