csvcdl_m.ld

C语言编写的监控中心终端程序。基于GPRS上传收发数据功能

/*
** FILE
** csvcd_m.ld , It's for module compress type 
**
** DESCRIPTION
**
*/
SECTIONS {
    .ramf : {
	_textf = .;
	_etextf = .;
    }	> sdram_cs

    /*
    summer code moving for fs9660 system        
    */

    /*
    ** fs9660 driver on SDRAM
    */
    .fs9660_drv : {
	_fs9660_drv_m_ps = .;
	MIPS/fs9660.o		(.rodata)
	MIPS/fs9660.o		(.text)
    }	> fs9660_drv_m

    /*
    ** jpg_drv driver on SDRAM
    */
    .jpg_drv : {
	_jpg_drv_m_ps = .;
    }	> jpg_drv_m

    /*
    ** mp3_drv driver on SDRAM
    */
    .mp3_drv : {
	_mp3_drv_m_ps = .;
    }	> mp3_drv_m

    /*
    ** setup program on SDRAM
    */
    .setup_drv : {
	_setup_drv_m_ps = .;
	MIPS/setup.o		(.rodata)
	MIPS/setup.o		(.text)
    }	> setup_drv_m

    /*
    ** setup program on SDRAM
    */
    .prev_prog_drv : {
	_prev_prog_drv_m_ps = .;
	MIPS/prog.o		(.rodata)
	MIPS/prog.o		(.text)
    }	> prev_prog_drv_m

    /*
    ** fudu program on SDRAM
    */
    .fudu_drv : {
	_fudu_drv_m_ps = .;
    }	> fudu_drv_m

    /*
    ** Fix program on SDRAM
    */
    .fix_drv : {
	_fix_drv_m_ps = .;
	MIPS/osdutil.o		(.rodata)
	MIPS/osd.o		(.rodata)
/*	MIPS/cdfunc.o		(.rodata)	*/
	MIPS/cd.o		(.rodata)
	MIPS/font.o		(.rodata)
	MIPS/graph.o		(.rodata)

	MIPS/osd.o		(.text)
	MIPS/osdutil.o		(.text)
/*	MIPS/cdfunc.o		(.text)		*/
	MIPS/cd.o		(.text)
	MIPS/font.o		(.text)
	MIPS/graph.o		(.text)
    }	> fix_drv_m

    /*
    ** .rom1: text image (direct mapped)
    */
    .rom1 : {
	MIPS/init0.o		(.text)
	*			(.text)
	MIPS/crt0.o		(.text)
	.	= ALIGN(16);
    }	> rom

    /*
    ** .ram1: DATA section
    */
    .ram1 : {
	_data  = .;		/* beginning of data segment */
	*			(.data)
	_gp    = .;		/* $gp global pointer, _gp for crt0.S to load */
	*			(.sdata)
	_edata = .;		/* end of data area (to be copied from ROM) */
	.	= ALIGN(16);
    }	> dataram

    /*
    ** .rom1_2: padding section for DATA initialization
    */
    .rom1_2 : {
	_data_ps = .;
	.	+= SIZEOF(.ram1);
        _data_pe  = .;
	.	= ALIGN(16);
    }	> rom

    .rom2 : {
	*			(.rdata)
	*			(.rodata)
	.	= ALIGN(16);
    }	> rom

    .ramJ : {
	_sdram_cs_jpeg_ps = .;
	_sdram_cs_jpeg_pe = .;
	.	= ALIGN(16);
    }	> sdram_cs_jpeg

    .ramF : {
	_sdram_cs_ps = .;
/*	MIPS/fs9660.o		(.bss)		*/
	MIPS/osd.o		(.bss)
	MIPS/dsa.o		(.bss)
	MIPS/gsm.o		(.bss)
	MIPS/graph.o		(.bss)
	MIPS/sysmain.o		(.bss)
/*	MIPS/membuf.o		(COMMON)
	MIPS/membufv.o		(COMMON)
	MIPS/osd.o		(COMMON)
	MIPS/genint.o		(COMMON)
	MIPS/setup.o		(COMMON)	*/
	*			(COMMON)
	MIPS/pcm.o		(.scommon)
	MIPS/auctrl.o		(.scommon)
/*	MIPS/setup.o		(.scommon)	*/
/*	MIPS/ir.o		(.scommon)	*/
/*	MIPS/fs9660.o		(.scommon)	*/
	_sdram_cs_pe = .;
	.	= ALIGN(16);
    }	> sdram_cs

    .ramS : {
	sdram_servo_ps = .;
	sdram_servo_pe = .;
	.	= ALIGN(16);
    }	> sdram_servo

    /*
    ** .ram2: un-initialized data
    */
    .ram2 : {
	_bstart = .;
	*			(.sbss)
	*			(.scommon)
	*			(.bss)
	*			(.rel.dyn)
	.			= ALIGN(16);
	_bend			= .;
	_stklimit		= .;
    }	> dataram

    _etext  = ADDR(.rom1) + SIZEOF(.rom1) + SIZEOF(.rom2);	/* end of non-relocating ROM image */
    _stextf = _etext  + SIZEOF(.ram1);
    _etextf = _stextf + SIZEOF(.ramf);

    /*
    ** SDRAM-based stack
    */
/*  _stkbtm = 0x011ff000;	*/
/*  _stkptr = 0x01200000;	*/

    /*
    ** DATARAM-based stack
    */
    _stkbtm = 0xafff3800;
    _stkptr = 0xafff4000;
}

MEMORY
{
    /* ROM space */
    rom			: org = 0x80000000, l = 1024k	/* cached ROM image in ROM	*/
    bootrom		: org = 0xbfc00000, l = 512k	/* Un-cached ROM boot		*/

    /* SDRAM space */
    sdram_cs_jpeg	: org = 0x881b0000, l = 17k	/* for JPEG var buf from 1776	*/
    sdram_servo		: org = 0x881f9e00, l = 464	/* 2036*1024+48 for servo 2035	*/
    sdram_cs		: org = 0x881fa000, l = 24k	/* SDRAM cached 2k-byte 2044	*/

    mp3_drv_m		: org =0x1881d2000, l = 30k	/* mp3 drv          1864	*/
    jpg_drv_m		: org = 0x881d5c00, l = 15k	/* jpeg drv         1865	*/
    fs9660_drv_m	: org = 0x881d9800, l = 12k	/* fs9660 drv       1866	*/
    fudu_drv_m		: org = 0x881e0800, l = 7k	/* fudo drv         1867	*/

    setup_drv_m		: org = 0x881ed400, l = 8k	/* setup drv        1868	*/
    prev_prog_drv_m	: org =0x1881ed400, l = 8k	/* preview/prog drv 1868	*/
    fix_drv_m		: org = 0x881ef400, l = 42k	/* others drv       1876	*/

    /* Data RAM space */
    dataram		: org = 0xafff3800, l = 2k	/* DATARAM			*/
}

ENTRY(__romstart)