sqlbasic.sas

SAS是功能強大的統計軟體

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: SQLBASIC                                            */
 /*   TITLE: DEMONSTRATES BASIC SQL SELECT STATEMENTS            */
 /* PRODUCT: BASE                                                */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS: SQL SELECT WHERE LABEL AS                           */
 /*   PROCS: SQL                                                 */
 /*    DATA:                                                     */
 /*                                                              */
 /* SUPPORT: KMS, PMK                    UPDATE:                 */
 /*     REF:                                                     */
 /*    MISC:                                                     */
 /*                                                              */
 /****************************************************************/
  title1 '*** sqlbasic: basic SQL select statements ***';

  /*---------------------------------------------------------------*/
  /*-- The first step is to create the Paper table which will be --*/
  /*-- used in the following queries.                            --*/
  /*---------------------------------------------------------------*/

data paper;
 input author$1-8 section$9-16 title$17-43 @45 time time5.
       duration;
 format time time5.;
 label title='Paper Title';
 cards;
Tom     Testing Automated Product Testing    9:00 35
Jerry   Testing Involving Users              9:50 30
Nick    Testing Plan to test, test to plan  10:30 20
Peter   Info SysArtificial Intelligence      9:30 45
Paul    Info SysQuery Languages             10:30 40
Lewis   Info SysQuery Optimisers            15:30 25
Jonas   Users   Starting a Local User Group 14:30 35
Jim     Users   Keeping power users happy   15:15 20
Janet   Users   Keeping everyone informed   15:45 30
Marti   GraphicsMulti-dimensional graphics  16:30 35
Marge   GraphicsMake your own point!        15:10 35
Mike    GraphicsMaking do without color     15:50 15
Jane    GraphicsPrimary colors, use em!     16:15 25
;


proc sql;


  /*---------------------------------------------------------------*/
  /*-- Let's list all of the information in the Paper table.     --*/
  /*---------------------------------------------------------------*/

  title2 'Papers to be presented';
  select *
    from paper;


  /*---------------------------------------------------------------*/
  /*-- What time will the papers be finished?                    --*/
  /*---------------------------------------------------------------*/

  title2 'How long will it take?';
  select author, title, time, duration,
         time + duration*60 as endtime
    from paper;


  /*---------------------------------------------------------------*/
  /*-- Let's add some labels and formats for some clarity.       --*/
  /*---------------------------------------------------------------*/

  select author, title, time,
         duration label='How Long it Takes',
         time + duration*60 as endtime format=time5.
    from paper;


  /*---------------------------------------------------------------*/
  /*-- Which papers are presented in the morning?                --*/
  /*-- add a where clause to restrict the rows selected.         --*/
  /*---------------------------------------------------------------*/

  title2 'Papers presented in the morning';
  select author, title, time,
         duration label='How Long it Takes',
         time + duration*60 as endtime format=time5.
    from paper
   where time < '12:00't;
quit;