sqlcreat.sas

SAS是功能強大的統計軟體

 /****************************************************************/
 /*          S A S   S A M P L E   L I B R A R Y                 */
 /*                                                              */
 /*    NAME: SQLCREAT                                            */
 /*   TITLE: DEMONSTRATES BASIC SQL CREATE STATEMENTS            */
 /* PRODUCT: BASE                                                */
 /*  SYSTEM: ALL                                                 */
 /*    KEYS: SQL CREATE TABLE SELECT WHERE                       */
 /*   PROCS: SQL                                                 */
 /*    DATA:                                                     */
 /*                                                              */
 /* SUPPORT: KMS, PMK                    UPDATE:                 */
 /*     REF:                                                     */
 /*    MISC:                                                     */
 /*                                                              */
 /****************************************************************/
  title1 '*** sqlcreat: basic SQL create statements ***';

  /*---------------------------------------------------------------*/
  /*-- The first step is to create the Paper table which will be --*/
  /*-- used in the following queries.                            --*/
  /*---------------------------------------------------------------*/

data paper;
 input author$1-8 section$9-16 title$17-43 @45 time time5.
       duration;
 format time time5.;
 label title='Paper Title';
 cards;
Tom     Testing Automated Product Testing    9:00 35
Jerry   Testing Involving Users              9:50 30
Nick    Testing Plan to test, test to plan  10:30 20
Peter   Info SysArtificial Intelligence      9:30 45
Paul    Info SysQuery Languages             10:30 40
Lewis   Info SysQuery Optimisers            15:30 25
Jonas   Users   Starting a Local User Group 14:30 35
Jim     Users   Keeping power users happy   15:15 20
Janet   Users   Keeping everyone informed   15:45 30
Marti   GraphicsMulti-dimensional graphics  16:30 35
Marge   GraphicsMake your own point!        15:10 35
Mike    GraphicsMaking do without color     15:50 15
Jane    GraphicsPrimary colors, use em!     16:15 25
;


proc sql;


  /*---------------------------------------------------------------*/
  /*-- SQL can create SAS datasets in three ways.                --*/
  /*--                                                           --*/
  /*-- 1) as an empty copy of some other table                   --*/
  /*-- 2) as the results of any valid SQL select expression      --*/
  /*-- 3) from the traditional SQL DML statements                --*/
  /*--                                                           --*/
  /*---------------------------------------------------------------*/



  /*---------------------------------------------------------------*/
  /*-- This creates table P2, and empty copy of PAPER            --*/
  /*---------------------------------------------------------------*/
  create table p2 like paper;



  /*---------------------------------------------------------------*/
  /*-- In one step, this creates a table, P3, that contains all  --*/
  /*-- of the papers presented after 12:00.                      --*/
  /*---------------------------------------------------------------*/

  create table p3 as
  select * from paper
   where time > '12:00't;


  /*---------------------------------------------------------------*/
  /*-- This creates a table, unlike any existing table.          --*/
  /*---------------------------------------------------------------*/

  create table counts(
                      section char(20),
                      papers  num
                    );
quit;