platform.inc

ecos移植到R8H系列的源码。源码包来自http://www.cetoni.de/develop/develop_ecosh8s_en.html

#ifndef CYGONCE_HAL_PLATFORM_INC
#define CYGONCE_HAL_PLATFORM_INC
//=============================================================================
//
//  platform.inc
//
//  EDOSK-2764R "board" assembler header file
//
//=============================================================================
//###ECOSGPLCOPYRIGHTBEGIN####
// -------------------------------------------
// This file is part of eCos, the Embedded Configurable Operating System.
// Copyright (C) 1998, 1999, 2000, 2001, 2002 Red Hat, Inc.
//
// eCos is free software; you can redistribute it and/or modify it under
// the terms of the GNU General Public License as published by the Free
// Software Foundation; either version 2 or (at your option) any later version.
//
// eCos is distributed in the hope that it will be useful, but WITHOUT ANY
// WARRANTY; without even the implied warranty of MERCHANTABILITY or
// FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
// for more details.
//
// You should have received a copy of the GNU General Public License along
// with eCos; if not, write to the Free Software Foundation, Inc.,
// 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
//
// As a special exception, if other files instantiate templates or use macros
// or inline functions from this file, or you compile this file and link it
// with other works to produce a work based on this file, this file does not
// by itself cause the resulting work to be covered by the GNU General Public
// License. However the source code for this file must still be made available
// in accordance with section (3) of the GNU General Public License.
//
// This exception does not invalidate any other reasons why a work based on
// this file might be covered by the GNU General Public License.
//
// Alternative licenses for eCos may be arranged by contacting Red Hat, Inc.
// at http://sources.redhat.com/ecos/ecos-license/
// -------------------------------------------
//###ECOSGPLCOPYRIGHTEND####
//=============================================================================
//#####DESCRIPTIONBEGIN####
//
// Author(s):    yoshinori sato
// Contributors: yoshinori sato, Uwe Kindler
// Date:         2003-12-06
// Purpose:      EDOSK-2674R "board" definitions.
// Description:  This file contains various definitions and macros that are
//               required for writing assembly code for the am31 simulator.
//               Currently there are none
// Usage:
//       #include <cyg/hal/platform.inc>
//       ...
//      
//
//####DESCRIPTIONEND####
//
//=============================================================================


//=============================================================================
//                                   INCLUDES
//=============================================================================
#include <pkgconf/hal.h>

#include <cyg/hal/mod_regs_bsc.h>
#include <cyg/hal/mod_regs_pio.h>
#include <cyg/hal/mod_regs_intc.h>
#include <cyg/hal/mod_regs_sys.h>


//============================================================================
//                      INITIALIZE INTERRUPT CONTROLLER
// DESCRIPTION:
//     Sets up the interrupt control mode selected by user.
//============================================================================
#define CYGPKG_HAL_H8S_INTC_DEFINED
    .macro  hal_intc_init
    #if defined(CYG_HAL_STARTUP_ROM) || defined(CYG_HAL_STARTUP_ROMRAM)  
        //
        // setup interrupt control mode and NMI edge
        //
        mov.b   #(CYGARC_INTCR_ICM2 | CYGARC_INTCR_NMIEG_RIS), r0l
        mov.b   r0l,@CYGARC_INTCR
        //
        // setup interrupt registers for external interrupts
        //
        mov.w #0x0556, r0         // interrupt on falling edge for IRQ5-IRQ0
        mov.w r0, @CYGARC_ISCRL
        mov.w #0xff3f, r0         // select pins (IRQ15-IRQ8 port2, IRQ7,6 port 57, 56, IRQ5-IRQ0 port 8)
        mov.w r0, @CYGARC_ITSR
        mov.w #0x0000, r0         // IRQn requests are not sampled in software standby state
        mov.w r0, @CYGARC_SSIER
    #endif // #if defined(CYG_HAL_STARTUP_ROM) || defined(CYG_HAL_STARTUP_ROMRAM)          
    .endm


//=============================================================================
//                   INITIALIZE MEMORY AND BUS CONTROLLER
// DESCRIPTION:
//     Initializes memory and bus controller of EDOSK board.
//=============================================================================
#define CYGPKG_HAL_H8S_MEMC_DEFINED
    .macro  hal_memc_init
    #if defined(CYG_HAL_STARTUP_ROM) || defined(CYG_HAL_STARTUP_ROMRAM) 
    //
    // we have to initialize memory, port i/o and bus controller only if we
    // are doing ROM startup. If we are doing RAM startup then this should
    // be already done by ROM monitor
    //
      
    //
    // BSC/GPIO setup
    //
    mov.l   #init_regs,er0
    mov.w   #0xff,e2
    //
    // now initialize all registesr in init_regs
    //
regs_init_loop:
    mov.w   @er0+,r2
    beq     regs_init_finished
    mov.w   @er0+,r1
    mov.b   r1l,@er2
    bra     regs_init_loop

    #define INIT_REGS_DATA(REGS,DATA) .word ((REGS) & 0xffff),DATA

//
// All registers to be initialized and their initial values
//
init_regs:
INIT_REGS_DATA(CYGARC_ASTCR,  0xff)
INIT_REGS_DATA(CYGARC_RDNCR,  0x00)
INIT_REGS_DATA(CYGARC_ABWCR,  0x80)
INIT_REGS_DATA(CYGARC_WTCRAH, 0x27)
INIT_REGS_DATA(CYGARC_WTCRAL, 0x77)
INIT_REGS_DATA(CYGARC_WTCRBH, 0x71)
INIT_REGS_DATA(CYGARC_WTCRBL, 0x22)
INIT_REGS_DATA(CYGARC_CSACRH, 0x80)
INIT_REGS_DATA(CYGARC_CSACRL, 0x80)
INIT_REGS_DATA(CYGARC_BROMCRH,0xa0)
INIT_REGS_DATA(CYGARC_BROMCRL,0xa0)
INIT_REGS_DATA(CYGARC_P3DDR,  0x3a)
INIT_REGS_DATA(CYGARC_P3ODR,  0x06)
INIT_REGS_DATA(CYGARC_PADDR,  0xff)
INIT_REGS_DATA(CYGARC_PFDDR,  0xfe)
INIT_REGS_DATA(CYGARC_PGDDR,  0x0f)
INIT_REGS_DATA(CYGARC_PHDDR,  0x0f)
INIT_REGS_DATA(CYGARC_PFCR0,  0xff)
INIT_REGS_DATA(CYGARC_PFCR2,  0x0d)
INIT_REGS_DATA(CYGARC_ITSR,   0x00)
INIT_REGS_DATA(CYGARC_ITSR+1, 0x3f)
INIT_REGS_DATA(CYGARC_MSTPCRL,0xf7)
    .word   0

regs_init_finished:
    //
    // initialize SDRAM_MEMORY - special thanks to Arizona Cooperative Power
    //
    #define SDRAM_SMR 0x400040
    mov.b   #0, r0l
    mov.b   r0l, @CYGARC_DRACCR
    mov.w   #0x188, r0
    mov.w   r0, @CYGARC_REFCR
    mov.w   #0x85b4, r0
    mov.w   r0, @CYGARC_DRAMCR
    mov.b   #0, r1l
    mov.b   r1l,@SDRAM_SMR
    mov.w   #0x84b4, r0
    mov.w   r0, @CYGARC_DRAMCR
     
    #endif // #if defined(CYG_HAL_STARTUP_ROM) || defined(CYG_HAL_STARTUP_ROMRAM)
    .endm


//=------------------------------------------------------------------------------
#endif // ifndef CYGONCE_HAL_PLATFORM_INC
// end of platform.inc