keyword_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'	预备关键词处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<!--#include file="inc/md5.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP1_OTHER_RES") AND NOT Admin.CheckPopedom("TSYS_GROUP2_OTHER_RES") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
End If

Db.Open()

Dim Work
    Work = Request("Work")

'选择执行操作
Select Case Work
    Case "MdyReco"
        MdyReco()
    Case "AddReco"
        AddReco()
    Case "DeleteReco"
        DeleteReco()
End Select


'函数:删除记录
Function DeleteReco()
    Dim IdList
        IdList = FLib.SafeSql(Request("IdList"))
    If IdList = "" Then
        Exit Function
    End If

    Dim Sql
    Sql = "DELETE FROM keyword_list WHERE id IN(" & IdList & ")"

    If Not Admin.CheckPopedom("TSYS_GROUP2_RES_KEYWORD") Then
        Sql = Sql & " AND creator='" & Admin.UserName & "'"
    End If

    Db.ExeCute(Sql)

    FLib.Alert "执行完毕","KeyWord_List.asp",0
    Response.End

End Function

'函数:增加记录
Function AddReco()
    Dim title, content, show_order
    title           = FLib.SafeSql(Request("title"))
    content         = FLib.SafeSql(Request("content"))
    show_order      = FLib.SafeSql(Request("show_order"))

    If title = "" Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs

    Sql = "INSERT INTO keyword_list(title, content, creator, show_order, addtime)VALUES('" & title & "', '" & content & "', '" & Admin.UserName & "', " & show_order & ", GETDATE())"
    Db.ExeCute(Sql)

    FLib.Alert "执行完毕","KeyWord_List.asp",0
    Response.End

End Function

'函数:修改记录
Function MdyReco()
    Dim rid, title, content, show_order
    rid             = FLib.SafeSql(Request("rid"))
    title           = FLib.SafeSql(Request("title"))
    content         = FLib.SafeSql(Request("content"))
    show_order      = FLib.SafeSql(Request("show_order"))

    If title = "" Or Not IsNumeric(rid) Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs

    Sql = "UPDATE keyword_list SET title='" & title & "', content='" & content & "', show_order=" & show_order & " WHERE id=" & rid

    If Not Admin.CheckPopedom("TSYS_GROUP2_RES_KEYWORD") Then
        Sql = Sql & " AND creator='" & Admin.UserName & "'"
    End If

    Db.ExeCute(Sql)

    FLib.Alert "执行完毕","KeyWord_List.asp",0
    Response.End

End Function
%>