📄 menu_resclass_tree.asp

📁 一个很好的asp cms管理系统
💻 ASP
字号:
<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'	可查看频道树显示页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","CLOSE",1
    Response.End
End If

Db.Open()
%>
<html>
<head>
<title>频道列表</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="stylesheet" href="inc/style.css" type="text/css">
<link rel="StyleSheet" href="lib/dtree/dtree.css" type="text/css" />
<script type="text/javascript" src="lib/dtree/dtree.js"></script>
<SCRIPT LANGUAGE="JavaScript" src="inc/FunctionLib.js"></script>
</head>

<body bgcolor="#FFFFFF" text="#000000" leftmargin="0" topmargin="0">
<table width="100%" border="0" cellspacing="0" cellpadding="2">
  <tr> 
    <td> 
	<%InitResClassScript()%>
    </td>
  </tr>
</table>
</body>
</html>
<%
Function InitResClassScript()
	Response.Write "        <script type=""text/javascript"">" & vbCrLf
	Response.Write "        <!--" & vbCrLf
	Response.Write "        d = new dTree('d');" & vbCrLf
	Response.Write "        d.config.inputType = 0;" & vbCrLf
	Response.Write "        d.config.useIcons = true;" & vbCrLf
	InitTree_A()
	Response.Write "        document.write(d);" & vbCrLf
	Response.Write "        //-->" & vbCrLf
	Response.Write "        </script>" & vbCrLf
End Function

Function InitTree_A()
	Dim Rs, Sql
	Dim I, RootNodeList, arrRootNodeList, ChildNodeList, LinkUrl
		RootNodeList = Admin.RootNodeList
		LinkUrl = Request("LinkUrl")
		If Instr(LinkUrl, "?") = 0 Then
			LinkUrl = LinkUrl & "?tmp=1"
		End If

	If RootNodeList = "" Then
		Response.Write "        d.add(0,-1,'无可浏览的频道',null,null,null,null);" & vbCrLf
		Exit Function
	End If

	arrRootNodeList = Split(RootNodeList, ",")
	For I=0 To UBound(arrRootNodeList)

		'创建根节点'
		Sql = "SELECT id, title, parent FROM res_class_list WHERE id=" & arrRootNodeList(I) & " AND show=1 ORDER BY show_order DESC"
		Set Rs = Db.ExeCute(Sql)
		If Not (Rs.Eof And Rs.Bof) Then
			Response.Write "        d.add(" & Rs("id") & ",-1,'" & Rs("title") & "','" & LinkUrl & "&Parent=" & Rs("id") & "&ClassTitle=" & Server.UrlEncode(Server.HtmlEncode(Rs("title"))) & "', null, 'MainFrame',null);" & vbCrLf
			Rs.Close()

			'创建子节点'
			ChildNodeList = FLib.ChildenList(arrRootNodeList(I))
			If ChildNodeList<>"" Then
				Sql = "SELECT id, title, parent FROM res_class_list WHERE id IN (" & ChildNodeList & ")"
				Set Rs = Db.ExeCute(Sql)
				While Not Rs.Eof
					Response.Write "        d.add(" & Rs("id") & "," & Rs("parent") & ",'" & Rs("title") & "','" & LinkUrl & "&Parent=" & Rs("id") & "&ClassTitle=" & Server.UrlEncode(Server.HtmlEncode(Rs("title"))) & "', null, 'MainFrame',null,null,null,0);" & vbCrLf
					Rs.MoveNext
				Wend
				Rs.Close
				Set Rs = Nothing
			End If
		Else
			Rs.Close()
			Set Rs = Nothing
		End If

	Next

End Function
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -