login_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'	登录处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<!--#include file="inc/md5.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

Dim Work
Work = Request("Work")

'选择执行操作'
Select Case Work
    Case "LoginCheck"
        LoginCheck()
    Case "LoginOff"
        LoginOff()
End Select

'函数:用户登录认证'
Function LoginCheck()

    Dim UserName, UserPwd, UserIp
        UserName = FLib.SafeSql(Trim(Request.Form("UserName")))
        UserPwd = FLib.SafeSql(Trim(Request.Form("UserPwd")))
        UserIp = Request.ServerVariables("REMOTE_ADDR")
    If UserName = "" Or UserPwd = "" Or UserIp = "" Then
        FLib.Alert "对不起，登录失败","BACK",0
        Response.End
    End If

    Db.Open()
    Admin.Logoff()
    Dim LoginResult
        LoginResult = Admin.Login(UserName, UserPwd, UserIp)

    Select Case LoginResult
        Case 0
            FLib.AddLog "IP:" & UserIp & "尝试用[" & UserName & "]用户登录,结果失败"
            FLib.Alert "对不起，用户不存在","BACK",0
        Case 1
            Response.Redirect "main.asp"
        Case 2
            FLib.AddLog "[" & UserName & "]用户尝试登录，但此账号已被禁止登录，IP:" & UserIp
            FLib.Alert "对不起，[" & UserName & "]用户被禁止登录","BACK",0
        Case 3
            FLib.AddLog "[" & UserName & "]登录失败，IP:" & UserIp
            FLib.Alert "对不起，登录密码不正确！","BACK",0
        Case Else
            FLib.AddLog "[" & UserName & "]登录失败，IP:" & UserIp
            FLib.Alert "对不起，登录失败","BACK",0
    End Select
    Db.Close()
End Function

'函数:用户登出处理'
Function LoginOff()
    Db.Open()
    FLib.AddLog "[" & Admin.UserName & "]退出系统，IP:" & Admin.UserIp
    Admin.Logoff()
    FLib.Alert "你已经成功退出","./",1
    Db.Close()
End Function
%>