📄 popedom_selector.asp
字号:
<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
' 权限选择器页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager
If Not Admin.Logined Then
FLib.Alert "对不起，你已经超时或未登录","CLOSE",1
Response.End
End If
Db.Open()
Dim WinTitle, SelectorType
WinTitle = Request("WinTitle")
SelectorType = Request("Type")
If SelectorType = "" Then
SelectorType = 1
Else
SelectorType = CInt(SelectorType)
End If
If WinTitle = "" Then
WinTitle = "系统权限选择器"
End If
Dim Work
Work = Request("Work")
Select Case Work
Case "ReturnValue"
ReturnValue()
End Select
%>
<html>
<head>
<title><%=WinTitle%></title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link rel="StyleSheet" href="lib/dtree/dtree.css" type="text/css" />
<script type="text/javascript" src="lib/dtree/dtree.js"></script>
<SCRIPT LANGUAGE="JavaScript" src="inc/FunctionLib.js"></script>
<SCRIPT LANGUAGE="JavaScript">
<!--
var SelectorType = <%=SelectorType%>;
function chkForm(obj)
{
if(SelectorType == 1)
{
if(!GetRadioBox("radiod"))
{
return false;
}
}else{
if(!GetCheckBoxList("checkboxd"))
{
return false;
}
}
}
function chkFrom(obj)
{
if(!GetRadioBox("radiod"))
{
return false;
}
return true;
}
//-->
</SCRIPT>
<style type="text/css">
<!--
BODY {
SCROLLBAR-HIGHLIGHT-COLOR: buttonface;
SCROLLBAR-SHADOW-COLOR: buttonface;
SCROLLBAR-3DLIGHT-COLOR: buttonhighlight;
SCROLLBAR-TRACK-COLOR: #eeeeee;
SCROLLBAR-DARKSHADOW-COLOR: buttonshadow;
background-color:buttonface;
font:12px;
margin: 3px;
padding: 0px;
border: none;
}
.input_button {font-size:12px;}
-->
</style>
</head>
<body scroll="no">
<form name="form1" method="post" action="Popedom_Selector.asp" target="hidden_iframe" onsubmit="return chkForm(this)">
<table width="100%" height="100%" border="0" cellpadding="5" cellspacing="0">
<tr>
<td>
<div style="width:100%;height:100%;overflow:auto;background-color:#ffffff;padding:3px;">
<%
Response.Write " <script type=""text/javascript"">" & vbCrLf
Response.Write " <!--" & vbCrLf
Response.Write " d = new dTree('d');" & vbCrLf
If SelectorType = 1 Then
Response.Write " d.config.inputType = 1;" & vbCrLf
Else
Response.Write " d.config.inputType = 2;" & vbCrLf
End If
Response.Write " d.config.useIcons = true;" & vbCrLf
Response.Write " d.add(0,-1,'权限列表',null,null,null,null);" & vbCrLf
Dim IdList
IdList = "," & Request("IdList") & ","
Dim Rs, Sql
Sql = "SELECT id,parent,title FROM popedom_list WHERE show=1 ORDER BY show_order DESC"
Set Rs = Db.ExeCute(Sql)
Dim IsSelected
IsSelected = "false"
While Not Rs.Eof
If Instr(IdList, "," & Rs("id") & ",")>0 Then
IsSelected = "true"
Else
IsSelected = "false"
End If
Response.Write " d.add(" & Rs("id") & "," & Rs("parent") & ",'" & Server.HtmlEncode(Rs("title")) & "',null,null,null,null,null,null,0," & IsSelected & ",'" & Rs("id") & "');" & vbCrLf
Rs.MoveNext
Wend
Rs.Close
Set Rs = Nothing
Response.Write " document.write(d);" & vbCrLf
Response.Write " //-->" & vbCrLf
Response.Write " </script>" & vbCrLf
%>
</div>
</td>
</tr>
<tr>
<td height="22" align="right"> <input name="Button" type="submit" class="input_button" value="确 定"> <input name="Button2" type="button" class="input_button" onclick="window.close();" value="取 消">
<input name="Work" type="hidden" id="Work" value="ReturnValue">
<input name="Type" type="hidden" id="Type" value="<%=SelectorType%>">
</td>
</tr>
</table>
<iframe name="hidden_iframe" width="0" height="0"></iframe>
</form>
</body>
</html>
<%
Function ReturnValue()
Dim SelectorType, IdList
SelectorType = CInt(Request("Type"))
If SelectorType = 1 Then
IdList = FLib.SafeSql(Request("radiod"))
Else
IdList = FLib.SafeSql(Request("checkboxd"))
End If
Dim Sql, Rs
Sql = "SELECT id, parent, title, pope_key, creator, show, addtime FROM popedom_list WHERE id IN (" & IdList & ")"
Set Rs = Db.ExeCute(Sql)
If Rs.Eof And Rs.Bof Then
Rs.Close()
Set Rs = Nothing
Response.Write "<script>alert('记录不存在');window.history.back();</script>"
Response.End
End If
Response.Write "<html><script>" & vbCrLf
Response.Write "var result = Array(" & vbCrLf
While Not Rs.Eof
Response.Write " {" & vbCrLf
Response.Write " id:""" & Rs("id") & """," & vbCrLf
Response.Write " parent:""" & Rs("parent") & """," & vbCrLf
Response.Write " title:""" & FLib.HTMLToJS(Rs("title")) & """," & vbCrLf
Response.Write " pope_key:""" & Rs("pope_key") & """," & vbCrLf
Response.Write " creator:""" & FLib.HTMLToJS(Rs("creator")) & """," & vbCrLf
Response.Write " show:""" & Rs("show") & """," & vbCrLf
Response.Write " addtime:""" & Rs("addtime") & """" & vbCrLf
Rs.MoveNext
If Rs.Eof Then
Response.Write " }" & vbCrLf
Else
Response.Write " }," & vbCrLf
End If
Wend
Response.Write ");" & vbCrLf
Response.Write "window.returnValue = result;window.close();" & vbCrLf
Response.Write "</script></html>" & vbCrLf
response.end
End Function
%>⌨️ 快捷键说明
复制代码
Ctrl + C
搜索代码
Ctrl + F
全屏模式
F11
切换主题
Ctrl + Shift + D
显示快捷键
?
增大字号
Ctrl + =
减小字号
Ctrl + -