role_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'   系统角色处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<!--#include file="inc/md5.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP3_ROLE") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
ENd If

Db.Open()

Dim Work
    Work = Request("Work")

'选择执行操作
Select Case Work
    Case "MdyReco"
        MdyReco()
    Case "AddReco"
        AddReco()
    Case "LockReco"
        LockReco()
    Case "DeleteReco"
        DeleteReco()
End Select


'函数:锁定记录
'说明：
'   owner为1 的角色是系统默认角色，不允许锁定！
Function LockReco()
    Dim IdList, Flag
        IdList = FLib.SafeSql(Request("IdList"))
        Flag = FLib.SafeSql(Request("Flag"))
    If IdList = "" Then
        Exit Function
    End If

    Dim Sql, Rs
    Sql = "UPDATE popedom_role SET disabled=" & Flag & " WHERE owner <> 1 AND id IN(" & IdList & ")"
    Db.ExeCute(Sql)
    Sql = "UPDATE manager_base SET disabled=" & Flag & " WHERE owner <> 1 AND pope_role IN(" & IdList & ")"
    Db.ExeCute(Sql)

    FLib.Alert "执行完毕","Role_List.asp",0
    Response.End

End Function

'函数:删除记录
'说明：
'   owner为1 的角色是系统默认角色，不允许删除！
Function DeleteReco()
    Dim IdList
        IdList = FLib.SafeSql(Request("IdList"))
    If IdList = "" Then
        Exit Function
    End If

    Dim Sql
    Sql = "DELETE FROM popedom_role WHERE owner<>1 AND  id IN(" & IdList & ")"
    Db.ExeCute(Sql)
    Sql = "UPDATE manager_base SET pope_role=-1 WHERE owner<>1 AND pope_role IN(" & IdList & ")"
    Db.ExeCute(Sql)
    FLib.AddLog "删除角色：" & IdList

    FLib.Alert "执行完毕","Role_List.asp",0
    Response.End

End Function

'函数:增加记录
Function AddReco()
    Dim title, remark
    title               = LCase(FLib.SafeSql(Request("title")))
    remark              = FLib.SafeSql(Request("remark"))

    If title = "" Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs
    Sql = "SELECT TOP 1 id FROM popedom_role WHERE title='" & title & "'"
    Set Rs = Db.ExeCute(Sql)
    If Not(Rs.Eof And Rs.Bof) Then
        Rs.Close
        Set Rs = Nothing
        FLib.Alert "角色名称重复","BACK",0
        Response.End
    End If

    Sql = "INSERT INTO popedom_role(title, creator, remark, owner, disabled, addtime)VALUES('" & title & "', '" & Admin.UserName & "', '" & remark & "', 2, 1, GETDATE())"
    Db.ExeCute(Sql)
    FLib.AddLog "增加角色：" & title

    FLib.Alert "执行完毕","Role_List.asp",0
    Response.End

End Function

'函数:修改记录
'说明：
'   owner为1 的角色是系统默认角色，不允许修改！
Function MdyReco()
    Dim rid, title, remark
    rid                 = FLib.SafeSql(Request("rid"))
    title               = LCase(FLib.SafeSql(Request("title")))
    remark              = FLib.SafeSql(Request("remark"))

    If title = "" Or Not IsNumeric(rid) Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs
    Sql = "SELECT TOP 1 id FROM popedom_role WHERE title='" & title & "' AND id <> " & rid
    Set Rs = Db.ExeCute(Sql)
    If Not(Rs.Eof And Rs.Bof) Then
        Rs.Close
        Set Rs = Nothing
        FLib.Alert "角色名称重复","BACK",0
        Response.End
    End If

    Sql = "UPDATE popedom_role SET title='" & title & "', remark='" & remark & "' WHERE owner<>1 AND id=" & rid
    Db.ExeCute(Sql)
    FLib.AddLog "修改角色：" & title

    FLib.Alert "执行完毕","Role_List.asp",0
    Response.End

End Function
%>