slicepackage_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'   碎片包处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP2_SLICE") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
End If

Db.Open()

Dim Work
    Work = Request("Work")

'选择执行操作
Select Case Work
    Case "MdyReco"
        MdyReco()
    Case "AddReco"
        AddReco()
    Case "DeleteReco"
        DeleteReco()
End Select


'函数:删除记录
Function DeleteReco()
    Dim IdList
        IdList = FLib.SafeSql(Request("IdList"))
    If IdList = "" Then
        Exit Function
    End If

    Dim Sql
    Sql = "DELETE FROM slice_package_list WHERE id IN(" & IdList & ")"
    Db.ExeCute(Sql)
    FLib.AddLog "删除碎片包,Id：" & IdList

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function

'函数:增加记录
Function AddReco()
    Dim title, content, slice_id_list, class_id
    title           = FLib.SafeSql(Request("title"))
    content         = FLib.SafeSql(Request("content"))
    slice_id_list   = FLib.SafeSql(Request("slice_id_list"))
    class_id        = FLib.SafeSql(Request("class_id"))

    If title = "" Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs

    Sql = "INSERT INTO slice_package_list(title, content, slice_id_list, creator, class_id, addtime)VALUES('" & title & "', '" & content & "', '" & slice_id_list & "', '" & Admin.UserName & "', " & class_id & ", GETDATE())"
    Db.ExeCute(Sql)
    FLib.AddLog "增加碎片包：" & title

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function

'函数:修改记录
Function MdyReco()
    Dim rid, title, content, slice_id_list, class_id
    rid             = FLib.SafeSql(Request("rid"))
    title           = FLib.SafeSql(Request("title"))
    content         = FLib.SafeSql(Request("content"))
    slice_id_list   = FLib.SafeSql(Request("slice_id_list"))
    class_id        = FLib.SafeSql(Request("class_id"))

    If title = "" Or Not IsNumeric(rid) Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs
    Sql = "UPDATE slice_package_list SET title='" & title & "', content='" & content & "', slice_id_list='" & slice_id_list & "', class_id=" & class_id & " WHERE id=" & rid
    Db.ExeCute(Sql)
    FLib.AddLog "修改Id为" & rid & "的碎片包"

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function
%>