📄 other_popetacticscreator.asp

📁 一个很好的asp cms管理系统
💻 ASP
字号:
<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'    系统权限策略创建器
'说明:
'    角色权限策略及管理员个人权限策略应用到它
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP3_ROLE") AND Not Admin.CheckPopedom("TSYS_GROUP3_MANAGER") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
ENd If

Dim Work, PTType, sKey, PTTitle
    Work = Request("Work")
    PTType = Request("PTType")
    sKey = FLib.SafeSql(Request("sKey"))

Select Case PTType
    Case "Role" :
        PTTitle = "[角色]权限策略"
    Case "Manager" :
        PTTitle = "[用户]权限策略"
    Case Else :
        Response.End
End Select

Db.Open()
%>
<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
<html>
<head>
<title>系统权限策略创建器</title>
<meta http-equiv="Content-Type" content="text/html; charset=gb2312">
<link href="inc/style.css" rel="stylesheet" type="text/css">
<SCRIPT LANGUAGE="JavaScript" src="inc/FunctionLib.js"></script>
<SCRIPT LANGUAGE="JavaScript" src="inc/RCPopedomTable.js"></script>
<script language="JavaScript">
<!--
function chkForm_MdyReco(obj)
{
    return true;
}

function my_SCSelector_Open()
{
    var result = SCSelector_Open(2, document.all.special_id_list.value, '', 1);
    if(!result) return false;

    var val = "";
    for(var i=0; i<result.length; i++)
    {
        if(val == "")
        {
            val += result[i].id;
        }else{
            val += "," + result[i].id;
        }
    }
    document.all.special_id_list.value = val;
}

function my_PoPeSelector_Open()
{
    var result = PoPeSelector_Open(2, document.all.pope_id_list.value);
    if(!result) return false;

    var val = "";
    for(var i=0; i<result.length; i++)
    {
        if(val == "")
        {
            val += result[i].id;
        }else{
            val += "," + result[i].id;
        }
    }
    document.all.pope_id_list.value = val;
}

function readFromTemplate()
{
    form1.folder_list.value = form1.FileTemplate.value;
}
//-->
</script>
</head>

<body>
<%
Select Case Work
    Case "MdyReco" :
        MdyReco()
    Case "SaveMdy" :
        SaveMdy()
End Select

Function MdyReco()
    Dim Rs
    Set Rs = getPTData(PTType, sKey)

    Dim Fso, Fle, FileTemplate
    Set Fso = Server.CreateObject(Cfg.FileSystemObject_Name)
    Set Fle = Fso.OpenTextFile(Server.MapPath("inc/file.xml"), 1)
    FileTemplate = Fle.ReadAll()
    Fle.Close()
    Set Fle = Nothing    
%>
<table width="100%" border="0" cellspacing="0" cellpadding="0" class="tabTitleBar">
  <tr> 
    <td>
    <%=PTTitle%>
    </td>
  </tr>
</table>
<form name="form1" method="post" action="Other_PopeTacticsCreator.asp" target="hidden_iframe" onsubmit="return chkForm_MdyReco(this)">
  <table width="800" border="0" align="center" cellpadding="3" cellspacing="0">
    <tr> 
      <td align="right" valign="top">频道分配:</td>
      <td> <script language="JavaScript">
    <!--
    var oRcTable = new RCPopedomTable("oRcTable");
    document.write(oRcTable);

    //初始化
    <%RCPopedom_Table_Init Rs("res_class_list"), "oRcTable"%>
    //-->
    </script> </td>
    </tr>
    <tr> 
      <td width="16%" align="right" valign="top">资源特性分配:</td>
      <td width="84%"> <input name="special_id_list" type="text" class="input_text" id="special_id_list" value="<%=Rs("special_id_list")%>" size="60"> 
        <input name="Button" type="button" class="input_button" onclick="my_SCSelector_Open()" value="..."> 
        <br> <span class="txtNote">请选择将要使用的资源特性节点，无需选择其下子特性。</span></td>
    </tr>
    <tr> 
      <td width="16%" align="right" valign="top">权限分配:</td>
      <td width="84%"> <input name="pope_id_list" type="text" class="input_text" value="<%=Rs("pope_id_list")%>" size="60"> 
        <input name="Button" type="button" class="input_button" onclick="my_PoPeSelector_Open()" value="..."> 
        <br> <span class="txtNote">所有权限请输入“-1”</span></td>
    </tr>
    <tr> 
      <td align="right" valign="top">文件目录:</td>
      <td valign="top"> <textarea name="folder_list" cols="60" rows="8" wrap="OFF" class="input_text"><%If Not IsNull(Rs("folder_list")) Then Response.Write Server.HTMLEncode(Rs("folder_list")) End If%></textarea>
        <textarea name="FileTemplate" id="FileTemplate" style="visibility:hidden"><%=Server.HTMLEncode(FileTemplate)%></textarea> 
        <br>
        [<a href="javascript:readFromTemplate();void(0);">从模板读取</a>] </td>
    </tr>
    <tr> 
      <td width="16%" align="right" valign="top">&nbsp;</td>
      <td width="84%">&nbsp;</td>
    </tr>
    <tr> 
      <td width="16%" align="right" valign="top">&nbsp; </td>
      <td width="84%"> <input name="Submit43" type="submit" class="input_button" value="提  交"> <input name="Submit223" type="reset" class="input_button" value="复位"> 
        <input name="Submit323" type="button" class="input_button" onClick="window.history.back()" value="返回"> 
        <input type="hidden" name="Work" value="SaveMdy">
        <input name="PTType" type="hidden" id="PTType" value="<%=PTType%>">
        <input name="sKey" type="hidden" id="sKey" value="<%=sKey%>"></td>
    </tr>
  </table>
  <iframe name="hidden_iframe" width="0" height="0"></iframe>
</form>
<%
End Function
%>
</body>
</html>
<%
Function SaveMdy()
    Dim Sql, folder_list, pope_id_list, special_id_list, res_class_list
    folder_list = FLib.SafeSql(Request("folder_list"))
    pope_id_list = FLib.SafeSql(Request("pope_id_list"))
    special_id_list = FLib.SafeSql(Request("special_id_list"))
    res_class_list = FLib.SafeSql(FLib.ResClassPopedom_process("oRcTable"))

    Select Case PTType
        Case "Role" :
            Sql = "UPDATE popedom_role SET folder_list='" & folder_list & "', res_class_list='" & res_class_list & "', pope_id_list='" &pope_id_list & "', special_id_list='" & special_id_list & "' WHERE id=" & sKey
        Case "Manager" :
            Sql = "UPDATE manager_info1 SET folder_list='" & folder_list & "', res_class_list='" & res_class_list & "', pope_id_list='" & pope_id_list & "', special_id_list='" & special_id_list & "' WHERE manager_title='" & sKey & "'"
        Case Else :
            Response.End
    End Select

    Db.ExeCute(Sql)

    Response.Write "<script>alert(""保存完毕"");</script>"
    Response.End

End Function

'//初始化权限设置表格
Function RCPopedom_Table_Init(val, objName)
    
    If val = "" OR IsNull(val) Then
        Exit Function
    End If

    Dim arrRCPopedom, I, arrRCPopedomItem, Rs, strHtml
    arrRCPopedom = Split(val, ";")

    For I=0 To UBound(arrRCPopedom)
        arrRCPopedomItem = Split(arrRCPopedom(I), ",", 3)
        Set Rs = getClassListRS(arrRCPopedomItem(0))

        strHtml = "    result = {" & vbCrLf &_
        "       id:""" & arrRCPopedomItem(0) & """," & vbCrLf &_
        "       parent:""" & Rs("parent") & ""","  & vbCrLf &_
        "       title:""" & FLib.HTMLToJS(Rs("title")) & ""","  & vbCrLf &_
        "       creator:""" & FLib.HTMLToJS(Rs("creator")) & ""","  & vbCrLf &_
        "       show:""" & Rs("show") & ""","  & vbCrLf &_
        "       replace_path:""" & FLib.HTMLToJS(Rs("replace_path")) & ""","  & vbCrLf &_
        "       replace_with_url:""" & FLib.HTMLToJS(Rs("replace_with_url")) & ""","  & vbCrLf &_
        "       addtime:""" & Rs("addtime") & """"  & vbCrLf &_
        "   };" & vbCrLf
        strHtml = strHtml & vbCrLf & "        " & objName & ".InsertNewClassPopedom(result, '" & arrRCPopedomItem(1) & "', " & arrRCPopedomItem(2) & ");" & vbCrLf
        Response.Write strHtml
    Next

End Function

'//取得对应频道的Rs记录数据
Function getClassListRS(ClassId)
    Dim Sql, Rs
    Sql = "SELECT Top 1 * FROM res_class_list WHERE id=" & ClassId
    Set Rs = Db.ExeCute(Sql)
    If Rs.Eof And Rs.Bof Then
        Rs.Close
        Set Rs = Nothing
        Set getClassListRS = Nothing
        Exit Function
    End if

    Set getClassListRS = Rs
    Set Rs = Nothing

End Function

Function getPTData(PTType, sKey)
    Dim Sql
    Select Case PTType
        Case "Role" :
            Sql = "SELECT TOP 1 folder_list, res_class_list, pope_id_list, special_id_list FROM popedom_role WHERE id=" & sKey
        Case "Manager" :
            Sql = "SELECT TOP 1 folder_list, res_class_list, pope_id_list, special_id_list FROM manager_info1 WHERE manager_title='" & sKey & "'"
        Case Else :
            Response.End
    End Select

    Set getPTData = Db.ExeCute(Sql)
End Function
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -