slice_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'   碎片处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP2_SLICE") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
End If

Db.Open()

Dim Work
    Work = Request("Work")

'选择执行操作
Select Case Work
    Case "MdyReco"
        MdyReco()
    Case "AddReco"
        AddReco()
    Case "DeleteReco"
        DeleteReco()
End Select


'函数:删除记录
Function DeleteReco()
    Dim IdList
        IdList = FLib.SafeSql(Request("IdList"))
    If IdList = "" Then
        Exit Function
    End If

    Dim Sql
    Sql = "DELETE FROM slice_list WHERE id IN(" & IdList & ")"
    Db.ExeCute(Sql)
    FLib.AddLog "删除碎片,Id：" & IdList

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function

'函数:增加记录
Function AddReco()
    Dim title, content, slice_data, class_id, slice_type, start_flag, end_flag, file_path, editor_type
    title = FLib.SafeSql(Request("title"))
    content = FLib.SafeSql(Request("content"))
    slice_type = FLib.SafeSql(Request("slice_type"))
    start_flag = FLib.SafeSql(Request("start_flag"))
    end_flag = FLib.SafeSql(Request("end_flag"))
    file_path = FLib.SafeSql(Request("file_path"))
    slice_data = FLib.SafeSql(Request("slice_data" & slice_type))
    class_id = FLib.SafeSql(Request("class_id"))
    editor_type = FLib.SafeSql(Request("editor_type"))

    If title = "" Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs

    Sql = "INSERT INTO slice_list(title, content, slice_data, creator, class_id, slice_type, start_flag, end_flag, file_path, editor_type, addtime)VALUES('" & title & "', '" & content & "', '" & slice_data & "', '" & Admin.UserName & "', " & class_id & ", " & slice_type & ", '" & start_flag & "', '" & end_flag & "', '" & file_path & "', " & editor_type &", GETDATE())"
    Db.ExeCute(Sql)
    FLib.AddLog "增加碎片：" & title

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function

'函数:修改记录
Function MdyReco()
    Dim rid, title, content, slice_data, class_id, slice_type, start_flag, end_flag, file_path, editor_type
    rid = FLib.SafeSql(Request("rid"))
    title = FLib.SafeSql(Request("title"))
    content = FLib.SafeSql(Request("content"))
    slice_type = FLib.SafeSql(Request("slice_type"))
    start_flag = FLib.SafeSql(Request("start_flag"))
    end_flag = FLib.SafeSql(Request("end_flag"))
    file_path = FLib.SafeSql(Request("file_path"))
    slice_data = FLib.SafeSql(Request("slice_data" & slice_type))
    class_id = FLib.SafeSql(Request("class_id"))
    editor_type = FLib.SafeSql(Request("editor_type"))

    If title = "" Or Not IsNumeric(rid) Then
        FLib.Alert "参数有误","BACK",0
        Response.End
    End If

    Dim Sql, Rs
    Sql = "UPDATE slice_list SET title='" & title & "', content='" & content & "', slice_data='" & slice_data & "', class_id=" & class_id & ", slice_type=" & slice_type & ", start_flag='" & start_flag & "', end_flag='" & end_flag & "', file_path='" & file_path & "', editor_type=" & editor_type & " WHERE id=" & rid
    Db.ExeCute(Sql)
    FLib.AddLog "修改Id为" & rid & "的碎片"

    FLib.Alert "执行完毕","BACK",0
    Response.End

End Function
%>