filesys_upload.asp

来自「一个很好的asp cms管理系统」· ASP 代码 · 共 59 行

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'	文件系统列表页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<!--#include file="inc/FileSys.class.asp"-->
<!--#include file="lib/upload/upload_5xsoft.inc"-->
<%
Dim Cfg, Db, FLib, Admin, Tfs
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager
Set Tfs = New TFileSys

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP4_FILESYS") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
ENd If

Dim objUpLoad, Fle, FleExt
Set objUpLoad = New upload_5xsoft

Dim Tfs_Created
Tfs.CurrIndex = objUpLoad.form("CurrIndex")
Tfs.CurrPath = objUpLoad.form("CurrPath")
Tfs_Created = Tfs.Init()

Set Fle = objUpLoad.file("file")
FleExt = Tfs.GetFileEx(Fle.FileName)

If Instr("|" & UCase(Tfs.UpLoadFext) & "|", "|" & Ucase(FleExt) & "|") = 0 Then
    FLib.Alert "此类型的文件不允许上传", "BACK", 0
    Response.End
End If

If objUpLoad.Form("AutoRename") = "1" Then
    Fle.SaveAs Tfs.RealPath & Timer() & "." & FleExt
Else
    Fle.SaveAs Tfs.RealPath & Fle.FileName
End If

Set objUpLoad = Nothing

Response.Redirect "FileSys_List.asp?CurrIndex=" & Tfs.CurrIndex & "&CurrPath=" & Tfs.CurrPath
%>