resource_move_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'   资源移动处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP4_RES_MOVE") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
ENd If

Db.Open()

Dim Work
    Work = Request("Work")

'选择执行操作
Select Case Work
    Case "MoveReco" :
        MoveReco()
    Case Else
End Select

Function MoveReco()
    Dim class_list, CreateByField, sTime, eTime, class_id
    Dim Rs, Sql
    Dim sqlWhere

    class_list = FLib.SafeSql(Request("class_list"))
    CreateByField = FLib.SafeSql(Request("CreateByField"))
    sTime = FLib.SafeSql(Request("sTime"))
    eTime = FLib.SafeSql(Request("eTime"))
    class_id = FLib.SafeSql(Request("class_id"))

    Sql = "UPDATE resource_list SET class_id=" & class_id & " WHERE {sqlWhere}"

    Select Case CreateByField
        Case "1" :
            sqlWhere = " DATEDIFF(second, '" & sTime & "', addtime)>=0 AND DATEDIFF(second, addtime, '" & eTime & "')>=0 "
        Case "2" :
            sqlWhere = " DATEDIFF(second, '" & sTime & "', uptime)>=0 AND DATEDIFF(second, uptime, '" & eTime & "')>=0 "
    End Select

    sqlWhere = sqlWhere & "AND class_id IN (" & class_list & ")"
    Sql = Replace(Sql, "{sqlWhere}", sqlWhere)
    Set Rs = Db.ExeCute(Sql)

    FLib.AddLog "移动[" & class_list & "]资源至[" & class_id & "]频道"

    FLib.Alert "执行完毕", "BACK", 0
    Response.End

End Function
%>