config_process.asp

一个很好的asp cms管理系统

<%
Option Explicit
'----------------------------------------------------------------------------------
'本页:
'	系统配置处理页面
'说明:
'
'----------------------------------------------------------------------------------
%>
<!--#include file="inc/Config.class.asp"-->
<!--#include file="inc/DBControl.class.asp"-->
<!--#include file="inc/FunctionLib.class.asp"-->
<!--#include file="inc/Manager.class.asp"-->
<!--#include file="inc/md5.asp"-->
<%
Dim Cfg, Db, FLib, Admin
Set Cfg = New Config
Set Db = New DBControl
Set FLib = New FunctionLib
Set Admin = New Manager

If Not Admin.Logined Then
    FLib.Alert "对不起，你已经超时或未登录","./",1
    Response.End
End If

If Not Admin.CheckPopedom("TSYS_GROUP3_CONFIG") Then
    FLib.Alert "权限不足", "BACK", 0
    Response.End
ENd If

Dim Work
    Work = Request("Work")

Select Case Work
    Case "MdyFile" :
        MdyFile()
End Select

'函数:保存修改后的配置文件
Function MdyFile()
    Dim Fso, Fl, Cfg_FilePath
    Cfg_FilePath = Server.MapPath("inc/Config.class.asp")
    Set Fso = Server.CreateObject(Cfg.FileSystemObject_Name)

    If Not Fso.FileExists(Cfg_FilePath) Then
        Set Fso = Nothing
        FLib.Alert "文件不存在", "BACK", 0
        Response.End
    End If

    Dim Content
        Content = Request("Content")
    If Content = "" Then
        Set Fso = Nothing
        FLib.Alert "文件内容不能为空", "BACK", 0
        Response.End
    End If

    Set Fl = Fso.OpenTextFile(Cfg_FilePath, 2)
    Fl.Write Content
    Fl.Close

    Db.Open()
    FLib.AddLog "修改系统配置文件，IP:" & Admin.UserIp
    Db.Close()

    Set Fso = Nothing
    FLib.Alert "执行完毕", "BACK", 0
    Response.End

End Function
%>