filesys_list.asp

一个很好的asp cms管理系统

<table width="100%" border="0" cellspacing="0" cellpadding="0">
  <tr>
    <td class="tabTitleBar">目录:<%=ShowCurrentPath()%></td>
  </tr>
</table>
<table width="100%" border="0" cellspacing="0" cellpadding="2">
    <tr> 
      
    <td width="46%">[<a href="javascript:SelectAllCheckBox('ItemList');void(0);">返选</a>][<a href="#UploadFile">上传</a>][<a href="javascript:CreateFolder();void(0);">目录</a>][<a href="javascript:MoveItem(GetCheckBoxList('ItemList'));void(0);">移动</a>][<a href="javascript:DeleteItem(GetCheckBoxList('ItemList'));void(0);">删除</a>]</td>
      <td width="54%" align="right">
      <select name="FolderList" class="select_list" id="FolderList">
          <option value="" selected>    </option>
<%
Dim FItem, SelecteState
If Tfs.HaveFolderItem Then
    For Each FItem In Tfs.FolderItems
        If CInt(FItem.selectSingleNode("./index").Text) = Tfs.CurrIndex Then
            SelecteState = "Selected"
        Else
            SelecteState = ""
        End If
        Response.Write "          <option value=""" & FItem.selectSingleNode("./index").Text & """ " & SelecteState & ">" & FItem.selectSingleNode("./title").Text & "</option>" & vbCrLf
    Next
End If
%>
        </select>
      <input name="Submit" type="button" class="input_button" onClick="ChangeRoot(document.all.FolderList)" value="转到">
    </td>
  <tr> 
    <td colspan="2"></tr>
  <tr>
    <td colspan="2"></tr>
</table>
<table width="100%" border="0" cellspacing="1" cellpadding="2">
  <tr> 
    <td align="center" class="tabHead">&nbsp;</td>
    <td align="center" class="tabHead">&nbsp;</td>
    <td colspan="2" align="center" class="tabHead">名称</td>
    <td width="17%" align="center" class="tabHead">大小</td>
    <td width="18%" colspan="2" align="center" class="tabHead">创建/修改时间</td>
  </tr>
<%
If Tfs_CreateResult Then
    ShowList()
End If

Function ShowList()
%>
  <tr class="tabRow1"> 
    <td width="2%" align="center"><input name="ItemList" type="checkbox" class="input_checkbox" value="" disalbed></td>
    <td width="3%" align="center"><img src="img/fl/folder_root.gif" width="16" height="16"></td>
    <td colspan="2"><a href="javascript:OpenFolder('');void(0);" title="回到根目录">/</a></td>
    <td align="center">-&nbsp;</td>
    <td colspan="2" align="center">-</td>
  </tr>
  <tr class="tabRow2"> 
    <td width="2%" align="center"><input name="ItemList" type="checkbox" class="input_checkbox" value="" disalbed></td>
    <td width="3%" align="center"><img src="img/fl/folder_parent.gif" width="16" height="16"></td>
    <td colspan="2"><a href="javascript:OpenFolder(ParentPath);void(0);" title="上级目录">...</a></td>
    <td align="center">-&nbsp;</td>
    <td colspan="2" align="center">-</td>
  </tr>
<%  
    Dim SubItems, I
    I = 0
    '//目录清单'
    Set SubItems = Tfs.SubItems("folder")
    For Each FItem In SubItems
        I = I + 1
%>
  <tr class="<%If I Mod 2 = 0 Then Response.Write "tabRow2" Else Response.Write "tabRow1" End If%>">
    <td width="2%" align="center"><input name="ItemList" type="checkbox" class="input_checkbox" value="<%=Server.HtmlEncode(FItem.Name)%>"></td>
    <td width="3%" align="center"><img src="img/fl/folder.gif" width="16" height="16"></td>
    <td colspan="2"><a href="javascript:OpenFolder('<%=Tfs.CurrPath & "/" & Server.HtmlEncode(FItem.Name)%>');void(0);" oncontextmenu="contextForFolder('<%=Server.HtmlEncode(FItem.Name)%>')"><%=FItem.Name%></a></td>
    <td align="center">-&nbsp;</td>
    <td colspan="2" align="center"><span title="<%=FItem.DateCreated%>">
      <%If DateDiff("d", Now(), FItem.DateCreated) = 0 Then Response.Write "<font color=""#3300FF"">" & FormatDateTime(FItem.DateCreated,2) & "</font>" Else Response.Write FormatDateTime(FItem.DateCreated,2) End If%>
      </span></td>
  </tr>
  <%
    Next


    '//文件清单'
    Set SubItems = Tfs.SubItems("file")
    For Each FItem In Tfs.SubItems("file")
        I = I + 1
%>
  <tr class="<%If I Mod 2 = 0 Then Response.Write "tabRow2" Else Response.Write "tabRow1" End If%>">
    <td width="2%" align="center"><input name="ItemList" type="checkbox" class="input_checkbox" value="<%=Server.HtmlEncode(FItem.Name)%>"></td>
    <td width="3%" align="center"><img src="<%="img/fl/" & Tfs.FileIco(FItem.Name)%>" width="16" height="16"></td>
    <td colspan="2"><a href="javascript:ViewFile('<%=FItem.Name%>');void(0);" oncontextmenu="contextForFile('<%=Server.HtmlEncode(FItem.Name)%>')"><%=FItem.Name%></a></td>
    <td align="center"><%=FormatNumber(FItem.Size/1024,2,-1)%>K&nbsp;</td>
    <td colspan="2" align="center">
    <span title="<%=FItem.DateCreated%>"><%If DateDiff("d", Now(), FItem.DateCreated) = 0 Then Response.Write "<font color=""#3300FF"">" & FormatDateTime(FItem.DateCreated,2) & "</font>" Else Response.Write FormatDateTime(FItem.DateCreated,2) End If%></span>
    </td>
  </tr>
<%
    Next
End Function
%>
</table>
<table width="100%" border="0" cellspacing="0" cellpadding="2">
  <tr> 
    <td>[<a href="javascript:SelectAllCheckBox('ItemList');void(0);">返选</a>][<a href="#UploadFile">上传</a>][<a href="javascript:CreateFolder();void(0);">目录</a>][<a href="javascript:MoveItem(GetCheckBoxList('ItemList'));void(0);">移动</a>][<a href="javascript:DeleteItem(GetCheckBoxList('ItemList'));void(0);">删除</a>]</td>
    <td>&nbsp;</td>
  </tr>
</table>
<table width="100%" border="0" cellspacing="0" cellpadding="2">
  <tr> 
    <td align="right">
    <form name="form1" enctype="multipart/form-data" method="post" action="FileSYS_Upload.asp" onSubmit="if(this.file.value == '') return false;" <%If Not Tfs.EnableUpload Then Response.Write "Disabled" End If%>>
        <a name="UploadFile"></a>上传文件: 
        <input name="CurrIndex" type="hidden" id="CurrIndex" value="<%=Tfs.CurrIndex%>">
        <input name="CurrPath" type="hidden" id="CurrPath" value="<%=Tfs.CurrPath%>">
        <input name="file" type="file" class="input_text">
        <input name="Submit2" type="submit" class="input_button" value="上传" <%If Not Tfs.EnableUpload Then Response.Write "Disabled" End If%>>
        <br>
        <input name="AutoRename" type="checkbox" id="AutoRename" value="1">
        <label for="AutoRename">上传后自动重命名</label>
      </form></td>
  </tr>
</table>
</body>
</html>
<%
Function MoveItem()

    If Not Tfs.EnableMove Then
        FLib.Alert "当前目录没有移动权限", "BACK", 0
        Response.End
    End If

    Dim arrItemList, I, TargetPath
    arrItemList = Split(Request("ItemList"), ",")
    TargetPath = Request("TargetPath")

    For I =0 To Ubound(arrItemList)
        Tfs.MoveItem arrItemList(I), TargetPath
    Next
End Function

Function DeleteItem()

    If Not Tfs.EnableDelete Then
        FLib.Alert "当前目录没有删除权限", "BACK", 0
        Response.End
    End If

    Dim arrItemList, I
    arrItemList = Split(Request("ItemList"), ",")

    For I =0 To Ubound(arrItemList)
        Tfs.DeleteItem arrItemList(I)
    Next
End Function

Function CreateFolder()

    If Not Tfs.EnableCreate Then
        FLib.Alert "当前目录没有创建权限", "BACK", 0
        Response.End
    End If

    If Tfs.CreateFolder(Request("FolderName")) Then
    End If
End Function

'函数:显示当前路径'
'返回:路径串'
Function ShowCurrentPath()

    If Not Tfs_CreateResult Then
        ShowCurrentPath = ""
        Exit Function
    End If

    ShowCurrentPath = "<a href=""javascript:OpenFolder('');void(0);"" onmouseover=""PathLabelColor=this.style.color;this.style.color='#808080'"" onmouseout=""this.style.color=PathLabelColor"">" & Tfs.CurrUrl & "</a>"

    If Tfs.IsRoot Then
        Exit Function
    End If

    Dim arrPath, parentPath, I, parentPathName
    arrPath = Split(Tfs.CurrPath, "/")
    parentPath = ""

    For I=0 To Ubound(arrPath)

        parentPath = parentPath & arrPath(I)
        parentPathName = arrPath(I)
        ShowCurrentPath = ShowCurrentPath & "<a href=""javascript:OpenFolder('" & Server.HtmlEncode(parentPath) & "');void(0);"" onmouseover=""PathLabelColor=this.style.color;this.style.color='#808080'"" onmouseout=""this.style.color=PathLabelColor"">" &Server.HtmlEncode(parentPathName) & "</a>"
        If I <> Ubound(arrPath) Then
            parentPath = parentPath & "/"
            ShowCurrentPath = ShowCurrentPath & "/"
        End If
    Next
End Function
%>