configure.in

pc 透過simens mobile phone 連線,可直接傳訊.

AC_INIT(scmxx,0.6.4)
AC_REVISION($Revision: 1.3 $)
AC_PREREQ(2.53)
AC_CONFIG_HEADER([config.h])


CFLAGS="${CFLAGS} -Wall -Wno-format-y2k"
AC_PROG_CC
AC_PROG_INSTALL

AC_HEADER_STDC
AC_C_BIGENDIAN()
AC_CHECK_SIZEOF(wchar_t)
AC_CHECK_HEADERS(
    wchar.h,
    [],
    [AC_CHECK_HEADER(
	stddef.h,
	[],
	[AC_MSG_ERROR(
	    "Your system does not seem to have any wide character support."
	)]
    )]
)
AH_TEMPLATE(
    [NO_WCSLEN],
    [define this to include own wcslen() (mainly for MacOS X)]
)
AC_SEARCH_LIBS(
    wcslen,
    wcs,
    [],
    [DEP_FILES="dep_wcslen.c ${DEP_FILES}"
     AC_DEFINE(NO_WCSLEN)]
)

AH_TEMPLATE(
    [NO_CFMAKERAW],
    [define this to include own cfmakeraw()]
)
AC_CHECK_FUNC(
    cfmakeraw,
    [],
    [DEP_FILES="dep_cfmakeraw.c ${DEP_FILES}"
     AC_DEFINE(NO_CFMAKERAW)]
)

AC_CHECK_HEADERS(langinfo.h)
AH_TEMPLATE(
    [NO_NL_LANGINFO],
    [define this to include nl_langinfo() replacement]
)
AC_CHECK_FUNC(
    nl_langinfo,
    [],
    [DEP_FILES="dep_langinfo.c ${DEP_FILES}"
     AC_DEFINE(NO_NL_LANGINFO)]
)
AC_CHECK_HEADERS(
    getopt.h,
    [],
    [AC_CHECK_HEADERS(
	gnugetopt/getopt.h,
	[],
        [AC_MSG_ERROR("You need to get libgnugetopt or a newer GNU libc.")]
    )]
)
AC_SEARCH_LIBS(
    getopt_long,
    gnugetopt,
    [],
    [AC_MSG_ERROR("You need to get libgnugetopt or a newer GNU libc.")]
)

AC_CHECK_HEADER(
    iconv.h,
    [],
    [AC_MSG_ERROR("You need to get libiconv or a newer GNU libc.")]
)
AH_TEMPLATE(
    [ICONV_HAS_WCHAR_T],
    [this is defined when iconv is believed to know the charset WCHAR_T]
)
AC_CHECK_FUNC(
    iconv,
    [],
    [AC_CHECK_LIB(
	[iconv],
	[libiconv],
	[],
	[AC_MSG_ERROR("You need to get libiconv or a newer GNU libc.")]
    )
    AC_CHECK_LIB(
	[iconv],
	[wchar_to_loop_convert],
	[AC_DEFINE([ICONV_HAS_WCHAR_T])]
    )]
)

AH_TEMPLATE(
    [TTYPORT],
    [This defines the default device to open parameter --device which overwrites this setting]
)
AC_ARG_WITH(
    [device],
    AC_HELP_STRING([--with-device=DEV],[Use DEV as default [[/dev/ircomm0]]]),
    [device=$withval],
    [device="/dev/ircomm0"]
)
AC_DEFINE_UNQUOTED(TTYPORT,"$device")


AH_TEMPLATE(
    [TTYSPEED],
    [This defines the default serial baudrate, valid values may depend on system]
)
AC_ARG_WITH(
    [baudrate],
    AC_HELP_STRING([--with-baudrate=SPEED],[Set baud rate to SPEED [[19200]]]),
    [baudrate=$withval],
    [baudrate=19200]
)
AC_DEFINE_UNQUOTED(TTYSPEED,"$baudrate")

AC_SUBST(DEP_FILES)
AC_SUBST(LIBS)
AC_SUBST(OBJEXT)
AC_SUBST(EXEEXT)
AC_CONFIG_FILES(Makefile src/Makefile)
AC_OUTPUT