class_usercommand.asp

电子备课系统

<%@ LANGUAGE = VBScript CodePage = 936%>
<!--#include file="../conn.asp"-->
<!--#include  file="class_sys.asp"-->
<!--#include  file="Inc_Calendar.asp"-->
<!--#include  file="Inc_ubb.asp"-->
<%
Dim oBlog
Set oBlog = New class_sys
oBlog.start

'用户全功能类模块
'本模块目前尽可能与其他模块独立
Class Class_UserCommand
	Public Action
	Public ID,FileID
	Public rst
	Public Title
	Public ErrMsg
	Public mUserSkinLog,mYear,mMonth,mDay
	Private mUserName,mUserId,mUserPath,mUserNickName,mUserFolder,mBlogName,mUserPhotoRow,mUsersublist,mUserCmdpath,mUserLogPath,mUserIndexlist,mUserIcon1
	Private strLogN,strUrl,ShowDigg
	Private Sql,SqlStart,SqlPart,SqlEnd,rstSubject,strErrMsg,strPlayerUrl

	Private Sub Class_Initialize()
		userid=Request("uid")
		strPlayerUrl= blogurl & "PhotoPlayer.asp?userid="&muserid
		'G_P_PerMax=5
	End Sub

	Private Sub Class_Terminate()

	End Sub

	Public Property Let userid(ByVal Values)
		Dim rstmp, strSql
		mUserid = CLng(Values)
		'SqlStart = "select  * From oblog_log Where userid="& mUserId & " "
		SqlStart = "select  * From oblog_log Where 1=1 "
		'SqlEnd="  And ishide=0 and passcheck=1 and isdraft=0 and blog_password=0 Order by istop,addtime Desc"
		SqlEnd=" and passcheck=1 and isdraft=0 and isdel=0  And (userid="& mUserId & " Or authorid=" & mUserId & ") Order by istop,addtime Desc"
		Action=LCase(Request("do"))
		Id=OB_IIF(Request("Id"),0)
		Call GetUserInfo()
		G_P_FileName=mUserCmdpath&"cmd."&f_ext&"?uid="&mUserid&"&do="

		Dim rsUser
		Set rsUser = oblog.Execute ("SELECT isdigg FROM oblog_user WHERE userid = "&OB_IIF(mUserid,0))
		If Not rsUser.Eof Then
			If OB_IIF (rsUser(0),1) = 1 Then
				ShowDigg = vbcrlf & "<div class=""digg_list"" style=""float: left; display:inline; margin: 0 10px 5px 0; width: 45px; height: 55px; background: url("&blogurl&"Images/digg.gif) no-repeat left top; text-align: center; "">" & vbcrlf
				ShowDigg = ShowDigg & "	<div class=""digg_number"" style=""width:45px;padding: 10px 0 11px 0;font-size:18px;font-weight:600;color:#333;font-family:tahoma,Arial,Helvetica,sans-serif;line-height:1.0;"">$diggnum$</div>" & vbcrlf
				ShowDigg = ShowDigg & "	<div class=""digg_submit"" style="" padding: 3px 0 0 6px;line-height:1.0;letter-spacing: 6px; ""><a href=""javascript:void(null)"" onclick=""diggit($logid$);"" style=""font-size:12px;line-height:1.0;"">$showmsg$</a></div>" & vbcrlf
				ShowDigg = ShowDigg & "</div>" & vbcrlf
			End if
		Else
			ShowDigg = ""
		End if
	End Property

	Public Function Process()
		Dim strReturn,strMonth,strDay
		Id=CheckInt(Id)
		strMonth=Request("month")
		strDay=Request("day")
		'Response.Write "动作2：" & Action & "<BR/>" & vbCrlf
		'Response.Write "编号2：" & Id & "<BR/>" & vbCrlf
		select Case Action
			Case "index"
				SqlPart=" "
				Sql=SqlStart &	SqlEnd
				G_P_FileName = G_P_FileName & "index"
				strReturn = ShowList(Sql,"篇日志","0")
			Case "blogs"
				If Id="" OR Id=0 Then
					SqlPart=" And logType=0"
					G_P_FileName = G_P_FileName & "blogs"
				Else
					SqlPart=" And logType=0 And Subjectid=" & Id
					G_P_FileName = G_P_FileName & "blogs&id=" & Id
				End If
				SqlPart = SqlPart &" AND (isspecial = 0  OR isspecial IS NULL )"
				Sql=SqlStart & SqlPart & SqlEnd
				strReturn = ShowList(Sql,"篇日志","0")
			Case "month"
				Dim LastDay
				G_P_FileName = G_P_FileName & "month&month=" & strMonth
				strDay=Left(strMonth,4) & "-" & Right(strMonth,2) & "-01"
				mYear=Left(strMonth,4)
				mMonth=Right(strMonth,2)
				If InStr ("01,03,05,07,08,10,12",mMonth)> 0 Then
					LastDay = "31"
				Else
					If mMonth <> "02" Then
						LastDay = "30"
					Else
						If mYear Mod 4 = 0 Then
							LastDay = "29"
						Else
							LastDay = "28"
						End if
					End if
				End if
				If Not IsDate(strDay) Then
					ErrMsg = "<center>错误的日期数据，应为YYYYMMDD格式，如：20050801</center>"
					Exit Function
				End If
				If Is_Sqldata = 0 Then
					SqlPart = " And Datediff("&G_Sql_m&",Addtime,'" & strDay &"')=0"
				Else
					SqlPart = " And Addtime >='"&strMonth&"01' AND Addtime < '"&strMonth&LastDay&"' "
				End if
				Sql=SqlStart & SqlPart & SqlEnd
				strReturn = ShowList(Sql,"篇日志","0")
			Case "day"
				G_P_FileName = G_P_FileName & "day&day=" & strDay
				mYear=Year(strDay)
				mMonth=Month(strDay)
				If Not IsDate(strDay) Then
					strReturn = "<center>错误的日期格式，应为YYYYMMDD格式，如：20050801</center>"
					Exit Function
				End If
				If Is_Sqldata = 0 Then
					SqlPart = "And Datediff("&G_Sql_d&",Addtime,'" & strDay &"')=0"
				Else
					SqlPart = "AND Addtime >= '"&GetDateCode(strDay,0)&"' AND Addtime <'"&GetDateCode(CDate(strDay)+1,0)&"' "
				End if
				Sql=SqlStart & SqlPart & SqlEnd
				strReturn = ShowList(Sql,"篇日志","0")
			Case "message"
				Sql="select * from oblog_message where userid=" & mUserId & " order by messageid desc"
				G_P_FileName = G_P_FileName & "message"
				strReturn = ShowList(Sql,"个留言","1")
			Case "comment"
			Case "tag_blogs" '此处将日志与相册合并显示
				G_P_FileName = G_P_FileName & "tag_blogs&id=" & Id
				Sql="select a.userid,b.* From "
				Sql=Sql & " (select logid,userid From oblog_usertags Where userid=" & mUserId  & " and tagid=" & id &") a ,"
				'Sql=Sql & " (select * From oblog_log where userid=" & mUserId & " And logType=0) b Where a.logid=b.logid "
				Sql=Sql & " (select * From oblog_log where userid=" & mUserId & ") b Where a.logid=b.logid "
				Sql=Sql & " order By b.addtime Desc"
				strReturn = ShowList(Sql,"篇日志","0")
			Case "tag_photos"
				G_P_FileName = G_P_FileName & "tag_photos&id=" & Id
				Sql="select a.userid,b.* From "
				Sql=Sql & " (select logid,userid From oblog_usertags Where userid=" & mUserId  & " and tagid=" & id &") a ,"
				Sql=Sql & " (select * From oblog_log where userid=" & mUserId & " And logType=1) b Where a.logid=b.logid "
				Sql=Sql & " order By b.addtime Desc"
				strReturn = ShowList(Sql,"篇日志","0")
			Case "tags"
				strReturn = GetUserTags()
			Case "show"
				strReturn = ShowOneBlog(Id,0)
			Case "album"
				If oblog.CacheConfig(76) = "0" Then
					strReturn = ("此功能已被系统关闭！")
					strReturn=oblog.htm2js_div(filtskinpath(strReturn),"oblog_usercontent")
					Response.Write strReturn
					Response.End
				End if
				G_P_FileName = G_P_FileName & "album&id=" &Id
				if id>0 then
					Sql = "select photo_path,fileID,photo_Title,photo_name from oblog_album where TeamID=0 and (ishide=0 OR ishide IS NULL) and userid="&mUserId&" and userClassId="&id&"  order by photoID desc"
				Else
					If id = -1 Then
					'显示所有非隐藏的相片
						Sql = "select photo_path,fileID,photo_Title,photo_name from oblog_album where TeamID=0 and (ishide=0 OR ishide IS NULL) and userid="&mUserId&" and userClassId=0  order by photoID desc"
					Else
					'显示所有非隐藏的相册
						Sql = "SELECT c.photo_path,c.subjectid,c.subjectlognum FROM "
						Sql = Sql &" oblog_subject AS c "
						Sql = Sql &" WHERE c.subjecttype = 1 AND ( c.ishide = 0  OR c.ishide IS NULL) AND c.userid="&mUserId
						Sql = Sql &" ORDER BY c.subjectid DESC"
					End if
				end if
				strReturn = ShowList(sql,"个相片","2")
			Case "flash"
				If oblog.CacheConfig(76) = "0" Then
					strReturn = ("此功能已被系统关闭！")
					strReturn=oblog.htm2js_div(filtskinpath(strReturn),"oblog_usercontent")
					Response.Write strReturn
					Response.End
				End if
				'by 叶开
	'			strReturn="　<a href=""#"" onclick=""window.open('"&strPlayerUrl&"','_photo','height=500, width=480, top=100, left=400, toolbar=no, menubar=no, scrollbars=no, resizable=yes,status=no')"">启用自动播放</a>" & VBCRLF
				strReturn=strReturn&"  <a href='"&mUserCmdpath&"cmd."&f_ext&"?uid="&mUserid&"&do=album'>相册方式浏览</a>"
				strReturn = strReturn &"<div style=""margin:0;width:500px;text-align:center;""><object classid='clsid:D27CDB6E-AE6D-11cf-96B8-444553540000' codebase='http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=7,0,19,0' width='100%' height='500' align='middle'><param name=""wmode"" value=""transparent"" /><param name='movie' value='"&blogurl&"photo.swf?blogurl="&blogurl&"&userid="&mUserId&"&f_ext="&f_ext&"' /><param name='quality' value='high' /><embed src='"&blogurl&"photo.swf?blogurl="&blogurl&"&userid="&mUserId&"&f_ext="&f_ext&"' quality='high' pluginspage='http://www.macromedia.com/go/getflashplayer' type='application/x-shockwave-flash' width='100%' height='500'></embed></object></div>"
				'strReturn = strReturn &"<br/>	<div id=""PlayerContainer"" style=""position:absolute;background-color:#fff;z-index:1000;width:600px;height:480px;padding:0px;"" align=""center""><object classid=""clsid:d27cdb6e-ae6d-11cf-96b8-444553540000"" codebase=""http://fpdownload.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=8,0,0,0"" width=""100%"" height=""100%"" id=""photoview"" align=""middle""><param name=""allowScriptAccess"" value=""always"" />	<param name=""movie"" value=""http://5.4sk.cn/PhotoViewer.swf?blogurl=http://5.4sk.cn/&userid=1"" /><param name=""quality"" value=""high"" />	<param name=""wmode"" value=""transparent"" />	<param name=""bgcolor"" value=""#ffffff"" />	<embed src=""http://5.4sk.cn/PhotoViewer.swf?blogurl=http://5.4sk.cn/&userid=1"" quality=""high"" wmode=""transparent"" bgcolor=""#ffffff"" width=""100%"" height=""100%"" name=""photoview"" align=""middle"" allowScriptAccess=""always"" type=""application/x-shockwave-flash"" pluginspage=""http://www.macromedia.com/go/getflashplayer"" /></object>	</div>" & vbCrlf
			Case "info"
				strReturn=showinfo()
			'获取相册评论列表
			Case "photocomment"
				If oblog.CacheConfig(76) = "0" Then
					strReturn = ("此功能已被系统关闭！")
					strReturn=oblog.htm2js_div(filtskinpath(strReturn),"oblog_usercontent")
					Response.Write strReturn
					Response.End
				End if
				G_P_FileName = G_P_FileName & "photocomment&fileid=" & FileID
				Sql ="select comment_user,homepage,commenttopic,comment,commentid,a.addtime,isguest "
				Sql = Sql & "FROM oblog_albumcomment a,oblog_album b "
				Sql = Sql & "WHERE a.mainid = b.fileid AND iState=1 AND mainid="&FileID
				Sql = Sql & " ORDER By A.addtime DESC"
				strReturn = strReturn & ShowList(Sql,"篇评论","3")
			Case Else
				SqlPart=" "
				Sql=SqlStart &	SqlEnd
				strReturn = ShowList(Sql,"篇日志","0")
		End select
		strReturn=oblog.htm2js_div(filtskinpath(strReturn),"oblog_usercontent")
		Process=strReturn
		'Process="document.write('" & strReturn & "');"
	End Function

	Public Function CreateCalendar()
		Dim strReturn
		If mYear="" Then
			mYear=Year(Date)
			mMonth=Month(Date)
		End If
		strReturn=oblog.htm2js_div(Calendar(mYear,mMonth,mUserId),"calendar")
		CreateCalendar=strReturn
	End Function

	Private Function ShowUserBlogs(rst)
		Dim strBlogs
		Do While Not rst.Eof
			strBlogs= strBlogs & GetOneBlogInfo(rst,"")	& "<BR/>"
			rst.Movenext
		Loop
		'进行统一处理，不必每篇处理
		strLogMore=Replace(strLogMore,"$show_blogtag$","")
		strLogMore=Replace(strLogMore,"$show_blogzhai$","")
		strLogMore=Replace(strLogMore,"$show_blogtag","")
		strLogMore=filt_inc(strLogMore)
		strLogMore=strLogMore & "<script src="""&BlogDir&"count.asp?action=logs&id="&strLogN&"""></script>"
		'strLogMore=Replace(user_skin_main,"$show_log$",strLogMore)
		ShowUserBlogs= strLogMore