boot.asm

不调用int13号中断

; ==================================================== ;
;                .:  keenjoy95 2007  :.                ;
;          .:  keenjoy95_at_gmail_dot_com  :.          ;
; ---------------------------------------------------- ;
; 代码描述  :  引导扇区演示程序                        ;
; 编译方法  :  nasm  boot.asm -o boot.bin              ;
; ==================================================== ;

        org     07c00h                                 ; ORG伪指令也被称为程序起始地址伪指令 / 定位伪指令
                                                       ; 该伪指令用于指示编译器(链接器)将其后续代码(段)定位于指定地址
                                                       ; 由于本示例是引导扇区演示程序，所以目标定位地址为0000:7c00h
        jmp     MYOS_ENTRY                             ; 无条件跳转到程序的入口点MYOS_ENTRY标号处


BootMessage:
        dw      0x1048                                 ; "H"   (蓝底  黑字)
        dw      0x1465                                 ; "e"   (蓝底  红字)
        dw      0x1f6c                                 ; "l"   (蓝底  白字)
        dw      0x126c                                 ; "l"   (蓝底  绿字)
        dw      0x166f                                 ; "o"   (蓝底  棕字)
        dw      0xfc2c                                 ; ","   (白底浅红字)
        dw      0xf020                                 ; " "   (白底  黑字)
        dw      0x4b4d                                 ; "M"   (红底浅青字)
        dw      0x4179                                 ; "y"   (红底  蓝字)
        dw      0x404f                                 ; "O"   (红底  黑字)
        dw      0x4f53                                 ; "S"   (红底  白字)
        dw      0x4c21                                 ; "!"   (红底浅红字)
        dw      0x0000                                 ; ----- [EOF] ------

VGASEGMENT   equ   0b800h                              ; VGA 显卡缓存首地址                 (16K 缓存大小, 文本模式)

ScrollWindows:
        mov     ax, 0600h                              ; AH 赋值为功能号06h(窗口上滚)       (BIOS INT 10-06h 定义参数)
                                                       ; AL 赋值为0, 窗口信息全部移出(清屏) (BIOS INT 10-06h 定义参数)
        mov     bx, 0700h                              ; BH 底部空白行属性赋值为黑底灰白字  (BIOS INT 10-06h 定义参数)
                                                       ; BL 保留
        mov     cx, 0000h                              ; 窗口左上角的行列、号赋值为00h 00h  (BIOS INT 10-06h 定义参数)
        mov     dx, 184fh                              ; 窗口右下角的行列、号赋值为18h 4fh  (BIOS INT 10-06h 定义参数)
                                                       ;     ---------------------------------------------------
                                                       ;               0(00h)                      79(4fh)
                                                       ;        0(00h)┏━━━━━━━━━━━━━━━━┓
                                                       ;              ┃                                ┃
                                                       ;              ┃                                ┃
                                                       ;              ┃                                ┃
                                                       ;              ┃     显示器  25*80 显示方式     ┃
                                                       ;              ┃                                ┃
                                                       ;              ┃                                ┃
                                                       ;              ┃                                ┃
                                                       ;       24(18h)┗━━━━━━━━━━━━━━━━┛
                                                       ;
        int     10h                                    ; BIOS 10h号中断-06h号功能           (清屏功能调用)
        ret                                            ; 子程序无参数返回

DisplayString:
        xor     si, si                                 ; 清空源地址指针
        xor     di, di                                 ; 清空目的地址指针

        mov     ax, VGASEGMENT                         ; 取VGA显卡缓存首地址
        mov     gs, ax                                 ; GS寄存器指向显卡缓存
        mov     si, BootMessage                        ; 源地址指向待显示字符串
        mov     di, (80 * 2 + 0) * 2                   ; 目的地址指向显卡缓存
        cld                                            ; D标志位置空(增址型操作)
.1
        lodsw                                          ; 串装入指令(按字操作)
        test    ax, ax                                 ; 判断字符串结束符
        jz      .2                                     ; 字符串显示完毕(Z标志位为1)
        mov     [gs:di], ax                            ; 否则就将欢迎信息送显存缓冲区
        add     di, 2                                  ; 将显存缓冲区指向下一个单元(2个字节)
        jmp     .1                                     ; 继续循环
.2
        ret                                            ; 子程序无参数返回

SetCursorShape:
        mov     ah, 01h                                ; AH 赋值为功能号01h(光标形状设置)   (BIOS INT 10-01h 定义参数)
        mov     cx, 0307h                              ; 光标顶部、底部扫描线设置           (BIOS INT 10-01h 定义参数)
        int     10h                                    ; BIOS 10h号中断-01h号功能           (光标形状设置功能调用)
        ret                                            ; 子程序无参数返回

SetCursorPosition:
        mov     ah, 02h                                ; AH 赋值为功能号02h(光标位置设置)   (BIOS INT 10-02h 定义参数)
        mov     bh, 00h                                ; 页号设置                           (BIOS INT 10-02h 定义参数)
        mov     dx, 020ch                              ; 光标行号、列号设置                 (BIOS INT 10-02h 定义参数)
        int     10h                                    ; BIOS 10h号中断-02h号功能           (光标位置设置功能调用)
        ret                                            ; 子程序无参数返回

MYOS_ENTRY:
        mov     ax, cs                                 ; ┓
        mov     ds, ax                                 ; ┣ 段寄存器初始化
        mov     es, ax                                 ; ┛
        call    ScrollWindows                          ; 调用清除屏幕子程序
        call    DisplayString                          ; 调用字符串显示子程序
        call    SetCursorShape                         ; 调用光标形状设置子程序
        call    SetCursorPosition                      ; 调用光标位置设置子程序
        jmp     $                                      ; 主程序进入无限循环

MYOS_PAD:
        times   510-($-$$)   db   0                    ; 循环填充剩余空间，使生成的二进制代码大小恰好为一个扇区(512Byte)
        dw      0xAA55                                 ; 引导扇区结束标志
; ---8<--------------- [Cut Here] --------------->8--- ;
;                .:  keenjoy95 2007  :.                ;
;          .:  keenjoy95_at_gmail_dot_com  :.          ;
;                ! NO rights reserved !                ;
; ---------------------------------------------------- ;