sys_support.s

免费的OS源代码 符合ITRON4.0规范 http://www.toppers.jp/official_release.html

/*
 *  TOPPERS/JSP Kernel
 *      Toyohashi Open Platform for Embedded Real-Time Systems/
 *      Just Standard Profile Kernel
 * 
 *  Copyright (C) 2000-2003 by Embedded and Real-Time Systems Laboratory
 *                              Toyohashi Univ. of Technology, JAPAN
 * 
 *  Copyright (C) 2005-2007 by Y.D.K.Co.,LTD Technologies company
 *
 *  惧淡螟侯涪荚は·笆布の (1)×(4) の掘凤か·Free Software Foundation 
 *  によって给山されている GNU General Public License の Version 2 に淡
 *  揭されている掘凤を塔たす眷圭に嘎り·塑ソフトウェア∈塑ソフトウェア
 *  を猖恃したものを崔むˉ笆布票じ∷を蝗脱ˇ剩澜ˇ猖恃ˇ浩芹邵∈笆布·
 *  网脱と钙ぶ∷することを痰浸で钓满するˉ
 *  (1) 塑ソフトウェアをソ〖スコ〖ドの妨で网脱する眷圭には·惧淡の螟侯
 *      涪山绩·この网脱掘凤および布淡の痰瘦沮惮年が·そのままの妨でソ〖
 *      スコ〖ド面に崔まれていることˉ
 *  (2) 塑ソフトウェアを·ライブラリ妨及など·戮のソフトウェア倡券に蝗
 *      脱できる妨で浩芹邵する眷圭には·浩芹邵に燃うドキュメント∈网脱
 *      荚マニュアルなど∷に·惧淡の螟侯涪山绩·この网脱掘凤および布淡
 *      の痰瘦沮惮年を非很することˉ
 *  (3) 塑ソフトウェアを·怠达に寥み哈むなど·戮のソフトウェア倡券に蝗
 *      脱できない妨で浩芹邵する眷圭には·肌のいずれかの掘凤を塔たすこ
 *      とˉ
 *    (a) 浩芹邵に燃うドキュメント∈网脱荚マニュアルなど∷に·惧淡の螟
 *        侯涪山绩·この网脱掘凤および布淡の痰瘦沮惮年を非很することˉ
 *    (b) 浩芹邵の妨轮を·侍に年める数恕によって·TOPPERSプロジェクトに
 *        鼠桂することˉ
 *  (4) 塑ソフトウェアの网脱により木儡弄または粗儡弄に栏じるいかなる禄
 *      巢からも·惧淡螟侯涪荚およびTOPPERSプロジェクトを倘勒することˉ
 * 
 *  塑ソフトウェアは·痰瘦沮で捏丁されているものであるˉ惧淡螟侯涪荚お
 *  よびTOPPERSプロジェクトは·塑ソフトウェアに簇して·その努脱材墙拉も
 *  崔めて·いかなる瘦沮も乖わないˉまた·塑ソフトウェアの网脱により木
 *  儡弄または粗儡弄に栏じたいかなる禄巢に簇しても·その勒扦を砷わないˉ
 * 
 *  @(#) $Id: sys_support.S,v 1.2 2007/05/21 01:33:50 honda Exp $
 */

#define _MACRO_ONLY
#include "jsp_kernel.h"
#include <ns9360.h>

/* プロセッサモ〖ド */
Mode_SVC    =   0x13

/* ステ〖タスレジスタ充り哈みbit */
I_Bit       =   0x80
F_Bit       =   0x40

/*  BBUS reset register */
BBUS_RESET_BASE     = 0x90600000


/*
 *  你レベルのタ〖ゲットシステム巴赂の介袋步
 *
 *  スタ〖トアップモジュ〖ルの面で·メモリ介袋步の涟に钙び叫されるˉ          
 */       

        .text
        .align 2
        .global hardware_init_hook
hardware_init_hook: 

/*
 * NS9360巴赂の介袋步
 */
/*
 * bbus_reset
 */
        mov     r0, #0x0
        ldr     r0, =BBUS_RESET_BASE
        mov     r1, #0x0
        str     r1, [r0, #0]

/*
 * CS、GPIO Initial
 */
        stmfd sp!, {r4 - r11,lr}   /* レジスタの瘦赂 */
        bl      cpu_CsGpioInit
        ldmfd sp!,{r4 - r11,lr}

/*----*/
init_done:
        mov     pc, lr


/*
 *
 *  充哈みの叫掐り庚借妄
 *         
 */        
        .text
        .align 4    
        .global IRQ_Handler
IRQ_Handler:

        /* 
         * 充哈みモ〖ド 
         * 
         * cpsrがspsr_irqに牲耽黎がr14_irq(lp)に掐り·
         * spsr_irqとr14_irqとr13(sp)_irqが r14,r13となるˉ
         */

        /* 
         *  タスクの瓢侯箕モ〖ド(ス〖パ〖バイザ〖モ〖ド)へ
         */
        mov     sp,#(CPSR_SVC | CPSR_FIQ_BIT | CPSR_IRQ_BIT) 
        msr     cpsr_all, sp
        stmfd   sp!, {r0-r3,ip,lr,pc} /* pcはダミ〖 */


        /*
         * spsrと提り戎孟を艰评するためにIRQモ〖ドへ
         */
        mov     r0,#(CPSR_IRQ | CPSR_FIQ_BIT | CPSR_IRQ_BIT)
        msr     cpsr,r0
        sub     r0,lr,#4
        mrs     r1,spsr
        

        /*
         *  ス〖パ〖バイザ〖モ〖ドに
         */ 
        and     r2,  r1, #CPSR_FIQ_BIT /* FIQビットの费镜 */
        orr     r2,  r2, #(CPSR_SVC|CPSR_IRQ_BIT)
        msr     cpsr, r2
        str     r0, [sp,#0x18] /* Store pc */
        stmfd   sp!,{r1}       /* spsr */


        /*
         *  驴脚充り哈みか冉年
         */
        ldr     r2, =interrupt_count
        ldr     r3, [r2]
        add     r0,r3,#1
        str     r0, [r2]
        cmp     r3, #0x00

        moveq   r2,sp            /* ネスト充り哈みでない眷圭 */
        ldreq   sp,=STACKTOP     /* スタックの恃构    */
        stmeqfd sp!,{r2}         /* タスクスタックの瘦赂 */

        /*
         *  充り哈み妥傍の冉年ˉ
         *  INT_IDの粕み哈みˉ(ここにある涩妥はないˉ)
         */

        ldr     r3, =ISRADDR_REG
        ldr     r0, [r3]        /* 充り哈みベクタの粕み叫し */

        /*
         *  踏年盗の充哈みかチェック
         */
        cmp     r0, #0x00
        beq     undefined_interrupt
        
        /* 
         * 充り哈み钓材 
         */
        mrs     r2, cpsr
        and     r2,  r2, #~CPSR_IRQ_BIT /* 充哈み钓材 */
        msr     cpsr,r2

        /* 
         * Call Handler  
         */        
        mov     lr,  pc   
        mov     pc,  r0

        /* 
         * 充り哈み敦贿 
         */
        mrs     r2, cpsr
        and     r2,  r2, #CPSR_FIQ_BIT /* FIQビットの费镜 */         
        orr     r2,  r2, #(CPSR_SVC|CPSR_IRQ_BIT)
        msr     cpsr,r2

        /* 
         * 充哈みネスト搀眶(interrupt_count) デクリメント 
         */
        ldr     r2, =interrupt_count
        ldr     r1, [r2]        
        sub     r3, r1, #1                        
        str     r3, [r2]
        cmp     r3, #0x00        
        bne     return_to_task_irq
        
        /*
         * 充哈みネストが痰いので、链てのマスクをクリア
         */
        ldr     r2,  =ISRADDR_REG
        str     r0,  [r2]       /* 充哈みマスククリア */
        /* 
         * タスクスタックの牲耽 
         */
        ldmfd   sp!,{r0}         
        mov     sp, r0        
                
        ldr     r1, =reqflg    /* Check reqflg */
        ldr     r0, [r1]
        cmp     r0, #0
        beq     return_to_task_irq
        mov     r0, #0
        str     r0, [r1]       /* Clear reqflg */
        b       ret_int

return_to_task_irq:
        /*
         *  牲耽借妄
         *  充り哈み钓材となるがタスクコンテキスト惧に瘦赂しているため·
         *  啼玛はない
         */
        ldmfd   sp!,{r1}           /* CPSRの牲耽借妄 */
        mrs     r2, cpsr           /* FIQを费镜            */
        and     r2, r2, #CPSR_FIQ_BIT
        and     r1, r1, #~CPSR_FIQ_BIT
        orr     r1, r1, r2            
        msr     spsr, r1           
        ldmfd   sp!,{r0-r3,ip,lr,pc}^ /*タスク牲耽 + 充哈み钓材 */

        /*
         *  踏年盗の充哈みが掐ったときに钙び叫す
         */    
undefined_interrupt:
         b      undef_interrupt
    

/*
 * キャッシュ扩告簇犯
 * UW       cpuEnableICache( void );
 * UW       cpuEnableDCache( void );
 * UW       cpuEnableMMU( UW tlbaddr );
 * UW       cpuDCache_Line_Invalid( UW mva );
 * UW       cpuDCache_Line_Flush( UW mva );
 * UW       cpuDCache_Line_FlushInalid( UW mva );
 * UW       cpuDCache_DrainWriteBuffer( void );
 */


        .global cpuEnableICache, cpuEnableDCache
        .global cpuEnableMMU
        .global cpuDCache_Line_Invalid, cpuDCache_Line_Flush
        .global cpuDCache_Line_FlushInvalid, cpuDCache_DrainWriteBuffer


#define CP15_ICACHE     0x1000
#define CP15_DCACHE     0x0004
#define CP15_MMU        0x0001


/*
 * CP15-R1のI-cache bit(b12)=1 にする。
 * 苞眶なし
 */
cpuEnableICache:
        mcr     p15, 0, r0, c7, c5, 0       /* ICache invalidate                */
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        nop
        mrc     p15, 0, r0, c1, c0, 0       /* CP15 R1                          */
        orr     r0, r0, #CP15_ICACHE        /* I-Cache enable                   */
        mcr     p15, 0, r0, c1, c0, 0       /* Set CP15 R1 I-cache              */
        mov     pc, lr


/*
 * CP15-R7でDcache invalidate 悸卉稿にCP15-R1のD-cache bit(b2)=1にする。
 * 苞眶なし。
 */
cpuEnableDCache:
        mcr     p15, 0, r0, c7, c6, 0       /* DC all invalidate                */
        mrc     p15, 0, r0, c1, c0, 0       /* CP15 R1                          */
        orr     r0, r0, #CP15_DCACHE        /* D-Cache enable                   */
        mcr     p15, 0, r0, c1, c0, 0       /* Set CP15 R1 D-cache              */
        mov     pc,lr


/*
 * CP15-R1のMMU bit(bit0)=1にする。TLB肋年稿にTBLアドレスを苞眶にコ〖ルする。
 * r0:TLB address
 */
cpuEnableMMU:
        mcr     p15, 0, r0, c2, c0, 0       /* Set CP15 R2 TLB pointer          */
        mov     r0, #0                      /*                                  */
        mvn     r0, r0                      /* all domain is manager            */
        mcr     p15, 0, r0, c3, c0, 0       /* set Domain access (CP15 R3)      */

        mrc     p15, 0, r0, c1, c0, 0       /* CP15 R1                          */
        orr     r0, r0, #CP15_MMU           /* MMU enable                       */
        mcr     p15, 0, r0, c1, c0, 0       /* Set CP15 R1 MMU enable           */
        mov     pc,lr


/*
 * CP15-R7のInvalidate DCache single entry(MVA)を悸乖する。
 * r0:MVA
 */
cpuDCache_Line_Invalid:
        mcr     p15, 0, r0, c7, c6, 1       /* DC invalidate single entry(MVA)  */
        mov     pc,lr


/*
 * CP15-R7のClean DCache single entry(MVA)を悸乖する。
 * r0:MVA
 */
cpuDCache_Line_Flush:
        mcr     p15, 0, r0, c7, c10, 1      /* DC clean single entry(MVA)       */
        mov     pc,lr


/*
 * CP15-R7のClean & Invalidate DCache single entry(MVA)を悸乖する。
 * r0:MVA
 */
cpuDCache_Line_FlushInvalid:
        mcr     p15, 0, r0, c7, c14, 1      /* DC clean single entry(MVA)       */
        mov     pc,lr


/*
 * CP15-R7のDrain write bufferを悸乖する。
 */
cpuDCache_DrainWriteBuffer:
        mcr     p15, 0, r0, c7, c10, 4      /* Drain write buffer               */
        mov     pc,lr