fig08_16.pl

PERL语言资料 可以用于PERL程序设计

#!/usr/bin/perl
# Fig 8.16: fig08_16.pl
# Form processing CGI program.

use strict;
use warnings;
use CGI ':standard';

my $firstName = param( "firstName" );
my $lastName = param( "lastName" );
my $phone = param( "phone" );
my $date = param( "date" );
my $time = param( "time" );

print header();
print start_html( -title => "form page" );

if ( $firstName =~ /^\w+$/ ) {
   print "<p>Hello there \L\u$firstName.</p>";
}

if ( $lastName =~ /^\w+$/ ) {
   print "<p>Hello there Mr./Ms. \L\u$lastName.</p>";
}

if ( $phone =~ /^  # beginning of line
      (?:1-?)?     # optional 1-
      (?:          # start alternate
         \(        # left paren
         (\d{3})   # capture three digits
         \)        # right paren
      |            # or
         (\d{3})   # capture three digits
      )            # end alternate
      -?           # optional dash
      (\d{3})      # capture three more digits
      -?           # optional dash
      (\d{4})      # capture the final four digits
      $/x )        # end of line, with x modifier
{
   print "<p>Your phone number is ", $1 || $2 , " - $3 - $4.</p>";
}

if ( $date =~ m#^(1[012]|0?[1-9])/([012]?\d|3[01])/(\d\d)$# ) {
   print "<p>The date is $1 / $2 / $3.</p>";
}

if ( $time =~ m#^(1[012]|[1-9]):([0-5]\d):([0-5]\d)$# ) {
   print "<p>The time is $1 : $2 : $3.</p>";
}

print end_html();


###########################################################################
#  (C) Copyright 2001 by Deitel & Associates, Inc. and Prentice Hall.     #
#  All Rights Reserved.                                                   #
#                                                                         #
#  DISCLAIMER: The authors and publisher of this book have used their     #
#  best efforts in preparing the book. These efforts include the          #
#  development, research, and testing of the theories and programs        #
#  to determine their effectiveness. The authors and publisher make       #
#  no warranty of any kind, expressed or implied, with regard to these    #
#  programs or to the documentation contained in these books. The authors #
#  and publisher shall not be liable in any event for incidental or       #
#  consequential damages in connection with, or arising out of, the       #
#  furnishing, performance, or use of these programs.                     #
###########################################################################