vbwk.txt

PC机与智能仪器串口通信(visual basic)

'定义窗体级变量
'在显示、绘图、报警等过程中使用
Dim datatemp(1000) As Single                  '用于存储温度采样值
Dim num As Integer                            '用于存储采样值个数
'串口初始化
'在窗体的Load事件中加入下列代码对串口进行初始化:
Private Sub Form_Load()
  MSComm1.CommPort = 1
  MSComm1.InputMode = 1
  MSComm1.RThreshold = 1
  MSComm1.SThreshold = 1
  MSComm1.Settings = "4800,n,8,2"
  MSComm1.PortOpen = True
  Call tabinit                                 '调用表格初始化子程序
End Sub
'开始采集
Private Sub Cmdstart_Click()
  Timer1.Enabled = True
End Sub
'停止采集
Private Sub Cmdstop_Click()
  Timer1.Enabled = False
End Sub
'每隔1000ms向仪表发送读数据命令串
'每台仪表有一个仪表号，PC机通过仪表号来识别网上的多台仪表
'程序中仪表号（即地址代号）要与仪表设定值一致，否则不能返回数据。
Private Sub Timer1_Timer()
  MSComm1.Output = Chr(&H8282) & Chr(&H52) & Chr(&HC)
End Sub
'获取温度测量值并显示
'每发送一次指令，触发下面事件，返回数据串
Private Sub MSComm1_OnComm()
  Dim Inbyte() As Byte
  Dim buffer As String
  Dim datatemp2a, datatemp2b As String
  Dim datatemp2 As String
  If num > 199 Then Call renew
  '读取仪表返回数据串
  Select Case MSComm1.CommEvent
    Case comEvReceive
      Inbyte = MSComm1.Input
      For i = LBound(Inbyte) To UBound(Inbyte)
        buffer = buffer + Hex(Inbyte(i)) + Chr(32)
      Next i
    Case comEvSend
  End Select
  '获取十进制测量数据
  If Len(Trim(Mid(buffer, 1, 2))) = 1 Then
    datatemp(num) = Val("&H" & Mid(buffer, 3, 2) & Str("0") & Mid(buffer, 1, 2)) * 0.1
  Else
    datatemp(num) = Val("&H" & Mid(buffer, 3, 2) & Mid(buffer, 1, 2)) * 0.1
  End If
  '获取十六进制测量数据
  If Len(Trim(Mid(buffer, 1, 2))) = 1 Then
    datatemp2a = Str("0") & Trim(Mid(buffer, 1, 2))
  Else
    datatemp2a = Mid(buffer, 1, 2)
  End If
  If Len(Trim(Mid(buffer, 3, 2))) = 1 Then
    datatemp2b = Str("0") & Trim(Mid(buffer, 3, 2))
  Else
    datatemp2b = Mid(buffer, 3, 2)
  End If
  datatemp2 = datatemp2a & " " & datatemp2b
   '显示测量温度值
  If datatemp(num) <> 0 Then
    Grid.Col = 1: Grid.Row = num + 1
    Grid.Text = Format$(datatemp(num), "0.0")
    TempText = Format$(datatemp(num), "0.0")      '10进制显示,保留一位小数
    'Text2.Text = datatemp2                       '16进制显示
    num = num + 1
    Call cal                                      '调用计算极值、平均值子程序
    Call draw                                     '调用绘曲线过程
  End If
End Sub
 '计算极值、平均值
Sub cal()
  On Error GoTo hh
  Sum = 0
  Max = datatemp(0): Min = Max
  For i = 0 To num - 1
    If datatemp(i) >= Max Then Max = datatemp(i)
    If datatemp(i) <= Min Then Min = datatemp(i)
    Sum = Sum + datatemp(i)
  Next i
  aver = Sum / num
  MaxText.Text = Format$(Max, "0.0")
  MinText.Text = Format$(Min, "0.0")
  AverText.Text = Format$(aver, "0.0")
hh:  Exit Sub
End Sub
'绘制温度实时变化曲线
Private Sub draw()
  Picture1.Cls
  Picture1.DrawWidth = 1
  Picture1.BackColor = QBColor(15)
  Picture1.Scale (0, 50)-(200, 0)
  For i = 1 To num - 1
    X1 = (i - 1): Y1 = datatemp(i - 1)
    X2 = i: Y2 = datatemp(i)
    Picture1.Line (X1, Y1)-(X2, Y2), QBColor(0)
  Next i
End Sub
'刷新
Private Sub renew()
  If num = 0 Then Exit Sub
  TempText.Text = "": AverText.Text = ""
  MinText.Text = "": MaxText.Text = ""
  Grid.Clear
  Picture1.Cls
  For i = 0 To num - 1
    datatemp(i) = 0
  Next i
  num = 0
  Call tabinit
End Sub
'数据表格初始化
Public Sub tabinit()
  Grid.Cols = 2
  Grid.Rows = 200 + 1
  Grid.ColWidth(0) = 700
  Grid.ColWidth(1) = 950
  Grid.Col = 0
  For i = 1 To 200
    Grid.Row = i
    Grid.Text = "  " + Str$(i)
  Next i
  Grid.Row = 0
  Grid.Col = 0: Grid.Text = " 序号"
  Grid.Col = 1: Grid.Text = " 温度值"
  Grid.TopRow = 1                                 '置在第一页
  Grid.LeftCol = 1
End Sub
'当退出程序时，关闭串行口
Private Sub Cmdquit_Click()
  Unload Me
End Sub
Private Sub Form_QueryUnload(Cancel As Integer, UnloadMode As Integer)
  MSComm1.PortOpen = False           '关闭串口
End Sub