copyheaders.bat

WM9713 audio codec driver for WinCE 5.0

@echo off
@REM --------------------------------------------------------------------------
@REM Copyright (c) Wolfson Microelectronics plc.  All rights reserved.
@REM
@REM This software as well as any related documentation may only be used or
@REM copied in accordance with the terms of the Wolfson Microelectronic plc's
@REM non-disclosure agreement (NDA). The information in this file is furnished
@REM for informational use only, is subject to change without notice, and
@REM should not be construed as a commitment by Wolfson Microelectronics plc.
@REM Wolfson Microelectronics plc assumes no responsibility or liability for
@REM any errors or inaccuracies that may appear in this document or any software
@REM that may be provided in association with this document.
@REM 
@REM Except as permitted by the NDA, no part of this document may be reproduced,
@REM stored in a retrieval system, or transmitted in any form or by any means
@REM without the express written consent of Wolfson Microelectronics plc.
@REM
@REM $Id: CopyHeaders.bat 2890 2006-04-11 09:33:58Z fb $
@REM
@REM This file copies the various header files to the public include folders.
@REM
@REM Warning:
@REM  This driver is specifically written for Wolfson devices.  It is
@REM  not a general device driver.
@REM
@REM  This platform file is specifically designed to work Windows CE.  There
@REM  is no guarantee of correct operation with other platforms/controllers.
@REM
@REM --------------------------------------------------------------------------

setlocal

@REM Move to the Wolfson directory (the drive and path of the script name)
pushd %~dp0

if "%_WINCEOSVER%Check"=="Check" (
    echo error: Please run CopyHeaders.bat in a build window.
    goto END
)
    
if %_WINCEOSVER% GEQ 500 (
    if "%WM_BSP%"=="INTEL_DBPXA27X" (
    	echo == MAINSTONEII WM5 Intel BSP ==
        set INCDIR=%_TARGETPLATROOT%\platform\mainstoneii\src\inc
    ) else if "%WM_BSP%"=="TAHITI" (
        echo == i.MX21 WinCE 5.0 ==
        set INCDIR=%_TARGETPLATROOT%\inc
    ) else if "%WM_BSP%"=="MAINSTONEII" (
    	echo == MAINSTONEII WinCE 5.0 BSP ==
        set INCDIR=%_TARGETPLATROOT%\src\inc
    ) else if "%WM_BSP%"=="MAINSTONEIII" (
    	echo == MAINSTONEIII WM5 MS BSP ==
        set INCDIR=%_TARGETPLATROOT%\src\inc
    ) else (
    	echo == Unknown WinCE 5.0 BSP ==
        set INCDIR=%_TARGETPLATROOT%\src\inc
    )
) else (
    echo == Pre WinCE 5.0 BSP ==
    set INCDIR=%_TARGETPLATROOT%\inc
)
	
set HEADERDIRS=inc inc\Compatibility inc\RegisterDefs

@REM
@REM The following files are needed for interrupt handling.
@REM
set PLATFORMFILES=WMPlatformDefs.h WMInterrupts_Raw.h WMPlatform_Raw.h
set PLATFORMFILES=%PLATFORMFILES% WMPlatformDeviceContext.h WMPlatformConfig.h

@REM
@REM The following file is required for OS specific types e.g. Mutex_t.
@REM
set OSFILES=WMPlatform_OS.h

@REM
@REM Files which go in the platform root directory.
@REM
set ROOTFILES=WMCommonDefines OS\WMCE.bat

echo Copying public header files from the Wolfson library to %INCDIR%
set COPY_CMD=xcopy

@REM
@REM Now do the work
@REM
:DO_WORK

@REM
@REM First delete the existing files (but don't care if they're not there)
@REM
del /f /q %INCDIR%\WM*.h 2>NUL

@REM
@REM Now link or copy the new files
@REM
for %%d in (%HEADERDIRS%) 		do %COPY_CMD% %%d\*.h		%INCDIR%\
for %%f in (%PLATFORMFILES%) 	do %COPY_CMD% Platform\%%f  %INCDIR%\
for %%f in (%OSFILES%)          do %COPY_CMD% OS\%%f        %INCDIR%\

@REM
@REM Copy our internal build environment variable bat file to %_TARGETPLATROOT%
@REM
for %%f in (%ROOTFILES%) 		do if exist %%f %COPY_CMD% %%f %_TARGETPLATROOT%\

:END
endlocal

@REM
@REM Now run the bat file so that are settings are picked up in the
@REM current environment.
@REM
if exist %_TARGETPLATROOT%\WMCE.bat call %_TARGETPLATROOT%\WMCE.bat

popd
echo on