updatehosts.daily

A* sudo sudo/* B* adduser script adduser C* rmuser script rmuser E* tout tout/*

#!/bin/csh
###
# updatehosts - remake and distribute hosts file as necessary.
###

# determines how old a file can be before it is considered unmodified..
set maxthours = 1

# ug+rwx modes for writing files
umask 002

# get the date for figuring out whether to send diffs or the whole thing
set date = `date`

# munged version of date w/o colons on time...
set now     = `date | sed 's/:/ /g'`

# make sure we can execute fun things
set path=(. ~ ~/bin /usr/ucb /usr/bin /usr/new /etc /bin /usr/local/bin \
	/usr/local/etc /usr/hosts /usr/games /usr/local/adm/hosts/tools ) 

# get list of machines to distribute to
set MACHINEINFO = /usr/local/etc/MACHINES

# where the real hosts file lives..
set HOSTFILE    = /etc/hosts

# which mailer to run when bothering people
set mail        = "/usr/ucb/mail" 

# list of people who like to know when host list changes
set names = `cat /usr/local/adm/hosts/mailist`

# someone who wants to be bothered w/errs
set netadmin = coggs

# list of machines to distribute to...
set allhosts = \
( boulder sigi tut orbit extaci euclid sol anchor piper kirk eprince \
	pprince encore tigger )

# find out who trusts us..
#set trusted =  ( `grep -w TRUSTED ${MACHINEINFO} | awk '{print $1}' ` )

# where the action is...
set SRCDIR  = /usr/local/adm/hosts/hostsrc
cd $SRCDIR

##
# check each section, determine if it has been changed since last time.
set sections = \
(`grep "DATASECTIONS =" makefile | sed 's/[A-Z]*[ 	]*=[ 		]*//'`)

##
# max tolerable # of hours a file may be unmodified...
@ maxtseconds = $maxthours * 60 * 60
@ modified = 0
echo ""							> /tmp/updatehosts

foreach section ( $sections )
	echo $section
	set fileage = `cvdate -f $section`
	if ($fileage < $maxtseconds) then
		echo $section 				> touched-sections
		@ modified++
	endif
end
if ( $modified != 0 ) then
	set sections = `cat touched-sections`
	rm /tmp/updatehosts
	cat << EOF					> /tmp/updatehosts.mesg
The following section(s) of the cu/boulder hosts file have been updated.

$sections

A complete copy of the file is available via anonymous ftp from 
boulder.colorado.edu

You may receive the complete updated hosts file by sending mail to
\&'updatehosts@boulder' with a Subject: line consisting of the string
\&'send'. 

You may receive further information on updatehosts by replacing the 
above 'send' with 'help'.

For a complete rationalization, mail '[e-mail]'
EOF
  $mail -s "updatehosts@boulder: hosts file update: $sections" $names $netadmin \
						< /tmp/updatehosts.mesg

	rm /tmp/updatehosts.mesg
endif
##
# make the hosts file...
#
if ( $modified != 0 ) then

	##
	# make new hosts file
	make hosts				>& /tmp/updatehosts.terr
	if ($status != 0) then
		goto reporterr
	endif
	cat /tmp/updatehosts.terr 		>> /tmp/updatehosts.err

	##
	# rcs it.
	ci -l hosts < /dev/null 		>& /tmp/updatehosts.terr
	if ($status != 0) then
		goto reporterr
	endif
	cat /tmp/updatehosts.terr 		>> /tmp/updatehosts.err

	##
	# deposit copy in ~ftp/pub
	cp hosts ~ftp/pub			>& /tmp/updatehosts.err
	if ($status != 0) then
		goto reporterr
	endif
	cat /tmp/updatehosts.terr 		>> /tmp/updatehosts.err

	##
	# stick new copy in host:/etc/hosts
	cp hosts /etc/				>& /tmp/updatehosts.err
	if ($status != 0) then
		goto reporterr
	endif
	cat /tmp/updatehosts.terr 		>> /tmp/updatehosts.err
	#
	mkhosts /etc/hosts			>& /tmp/updatehosts.err	
	if ($status != 0) then
	 	goto reporterr
	endif
	cat /tmp/updatehosts.terr 		>> /tmp/updatehosts.err
	
	rm touched-sections

	##
	# distribute hosts file
	#
	distribhosts	


endif
exit(1)
##
#
reporterr:
	cat /tmp/updatehosts.terr	>> /tmp/updatehosts.err
	(echo "Errors:"; \
	cat   /tmp/updatehosts.err ) | \
	/usr/ucb/mail -s "updatehosts.daily: problems..." $netadmin
	rm /tmp/updatehosts.err
	exit(0)