clsinifile.cls

来自「智能邮件管理信息系统」· CLS 代码 · 共 103 行

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsIniFile"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'******************************************************************************
' -概要定义-
'  系统名称
'                   Copyright(C) 2004
'  程序名称         IniFile.cls
'  功能概要         应用初始化文件对象
'  日期             2004.05.18
'  作成者
'  备注
'******************************************************************************
'修改简历
'******************************************************************************

'******************************************************************************
'DLL 函数声明
'******************************************************************************
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long


Private sIniFileName As String                '初始化文件名称

Private Sub Class_Initialize()
    sIniFileName = vbNullString
End Sub

Public Sub SetIniFileName(FilePathName)
    sIniFileName = Trim(FilePathName)
End Sub

Private Function NoIniFile() As Boolean

    NoIniFile = True
    If sIniFileName = vbNullString Then
        Exit Function
    End If
    NoIniFile = False
    
End Function

'******************************************************************************
'函数名称   |设置字符型参数函数
'------------------------------------------------------------------------------
'函数参数   |1|  IN|String:段名
'           |2|  IN|String:KEY
'           |3|  IN|String:参数值
'------------------------------------------------------------------------------
'函数返回值 |Boolean:True-设置成功;False-设置失败
'******************************************************************************
Public Function SetStringParameter(Section As String, Key As String, value As String) As Boolean

    SetStringParameter = False
    If NoIniFile() Then
        Exit Function
    End If
    If WritePrivateProfileString(Section, Key, value, sIniFileName) = 0 Then
        Exit Function
    End If
    SetStringParameter = True
    
End Function

'******************************************************************************
'函数名称   |取字符型参数函数
'------------------------------------------------------------------------------
'函数参数   |1|  IN|String:段名
'           |2|  IN|String:KEY
'           |3|  IN|Long:长度
'------------------------------------------------------------------------------
'函数返回值 |String:参数值
'******************************************************************************
Public Function GetStringParameter(Section As String, Key As String, Size As Long) As String
    Dim sRet As String
    Dim lRet As Long
    
    GetStringParameter = vbNullString
    If NoIniFile() Then
        Exit Function
    End If
    sRet = Space(Size)
    lRet = GetPrivateProfileString(Section, Key, vbNullString, sRet, Size, sIniFileName)
    GetStringParameter = left(sRet, lRet)
    
End Function