login.asp

这是一套基于WEB的网站管理系统

<!--#include file="config.asp"-->
<!--#include file="../inc/classmenu.asp"-->
<!--#include file="../inc/md5.asp"-->
<%
Dim HtmlContent,ChannelRootDir
ChannelRootDir = Newasp.InstallDir & "user/"
Newasp.LoadTemplates 9999, 5, 0

HtmlContent = Newasp.HtmlContent
HtmlContent = Replace(HtmlContent,"{$InstallDir}", Newasp.InstallDir)
HtmlContent = Replace(HtmlContent, "{$ChannelID}", 0)
'--频道目录
HtmlContent = Replace(HtmlContent,"{$ChannelRootDir}", ChannelRootDir)
HtmlContent = Replace(HtmlContent,"{$PageTitle}","用户登录")
HtmlContent = ReadClassMenu(HtmlContent)
HtmlContent = ReadClassMenubar(HtmlContent)

If Trim(Request.Cookies("newasp_net")) <> "" Then
	Response.Redirect ("./index.asp")
End If

If LCase(Request("action")) = "login" Then
	Call MemberLogin
Else
	HtmlContent = Replace(HtmlContent,"{$UserManageContent}", Newasp.HtmlSetting(7))
	HtmlContent = Replace(HtmlContent,"{$SiteName}", Newasp.SiteName)
	Response.Write HtmlContent
End If
If Founderr = True Then
	Call Returnerr(ErrMsg)
End If
CloseConn
Sub MemberLogin()
	On Error Resume Next
	Dim Rs,SQL,username, password,usercookies,Group_Setting
	If Trim(Request("username")) <> "" And Trim(Request("password")) <> "" Then
		username = Trim(Request("username"))
		password = md5(Request("password"))
	Else
		ErrMsg = ErrMsg + "<li>用户名和密码不能为空！</li>"
		Founderr = True
		Exit Sub
	End If
	If Newasp.IsValidStr(Request("username")) = False Then
		ErrMsg = ErrMsg + "<li>用户名中含有非法字符！</li>"
		Founderr = True
	End If
	If Newasp.IsValidPassword(Request("password")) = False Then
		ErrMsg = ErrMsg + "<li>密码中含有非法字符！</li>"
		Founderr = True
	End If
	usercookies=request("CookieDate")
	If Founderr = True Then Exit Sub
	Set Rs = Server.CreateObject("ADODB.Recordset")
	SQL = "SELECT * FROM [NC_User] WHERE username='" & username & "'"
	Rs.Open SQL, Conn, 1, 3
	If Rs.BOF And Rs.EOF Then
		FoundErr = True
		ErrMsg = ErrMsg + "<li>您输入的用户名和密码不正确，请联系管理员！</li>"
		Exit Sub
	Else
		If password <> Rs("password") Then
			FoundErr = True
			ErrMsg = ErrMsg + "<br><li>用户名或密码错误！！！</li>"
			Exit Sub
		End If
		If Rs("UserLock") <> 0 Then
			Founderr = True
			ErrMsg = Newasp.HtmlSetting(8)
			Exit Sub
		End If
		Response.Cookies("newasp_net")("LastTimeDate") = Rs("LastTime")
		Response.Cookies("newasp_net")("LastTimeIP") = Rs("userlastip")
		Response.Cookies("newasp_net")("LastTime") = Rs("LastTime")
		Group_Setting=Split(Newasp.UserGroupSetting(Rs("UserGrade")), "|||")
		If Rs("userpoint") < 0 Then
			Rs("userpoint") = CLng(Group_Setting(25))
		Else
			Rs("userpoint") = Rs("userpoint") + CLng(Group_Setting(25))
		End If
		If Rs("experience") < 0 Then
			Rs("experience") = CLng(Group_Setting(32))
		Else
			Rs("experience") = Rs("experience") + CLng(Group_Setting(32))
		End If
		If Rs("charm") < 0 Then
			Rs("charm") = CLng(Group_Setting(33))
		Else
			Rs("charm") = Rs("charm") + CLng(Group_Setting(33))
		End If
		Rs("LastTime") = Now()
		Rs("userlastip") = Newasp.GetUserip
		Rs("UserLogin") = Rs("UserLogin") + 1
		Rs.Update
		If isnull(usercookies) Or usercookies="" Then usercookies="0"
		Select Case usercookies
		Case "0"
			Response.Cookies("newasp_net")("usercookies") = usercookies
		Case 1
			Response.Cookies("newasp_net").Expires=Date+1
			Response.Cookies("newasp_net")("usercookies") = usercookies
		Case 2
			Response.Cookies("newasp_net").Expires=Date+31
			Response.Cookies("newasp_net")("usercookies") = usercookies
		Case 3
			Response.Cookies("newasp_net").Expires=Date+365
			Response.Cookies("newasp_net")("usercookies") = usercookies
		End Select
		Response.Cookies("newasp_net")("userid") = Rs("userid")
		Response.Cookies("newasp_net")("username") = Rs("username")
		Response.Cookies("newasp_net")("password") = Rs("password")
		Response.Cookies("newasp_net")("nickname") = Rs("nickname")
		Response.Cookies("newasp_net")("UserGrade") = Rs("UserGrade")
		Response.Cookies("newasp_net")("UserGroup") = Rs("UserGroup")
		Response.Cookies("newasp_net")("UserClass") = Rs("UserClass")
		Response.Cookies("newasp_net")("UserToday") = Rs("UserToday")
	End If
	Rs.Close
	Set Rs = Nothing
	'Response.Redirect("index.asp")
	Dim comeurlname,comeurl,Returnstr
	comeurl = Request.ServerVariables("HTTP_REFERER")
	If instr(lcase(comeurl),"reg.asp")>0 Or instr(lcase(comeurl),"login.asp")>0 Or Trim(comeurl)="" Or (Not Newasp.CheckPost) Then
		comeurlname=""
		comeurl="index.asp"
		Returnstr = "<span id=jump>3</span> 秒钟后系统将自动返回控制中心"
	Else
		comeurl=comeurl
		comeurlname="<li><a href="&comeurl&">"&comeurl&"</a></li>"
		Returnstr = "<span id=jump>3</span> 秒钟后系统将自动返回"
	End If
	HtmlContent = Replace(HtmlContent,"{$UserManageContent}", Newasp.HtmlSetting(9))
	HtmlContent = Replace(HtmlContent,"{$SiteName}", Newasp.SiteName)
	HtmlContent = Replace(HtmlContent,"{$UserName}", Request("username"))
	HtmlContent = Replace(HtmlContent,"{$ComeUrl}", comeurl)
	HtmlContent = Replace(HtmlContent,"{$ComeUrlName}", comeurlname)
	HtmlContent = Replace(HtmlContent,"{$ReturnStr}", Returnstr)
	Response.Write HtmlContent
End Sub
%>