find_jmail.asp

机票预定系统 各个模块的设计-ticket reservation systems detailed design system modules of the design

<%
From=tmp(10)
FromName=tmp(1)
MailServerUserName=tmp(11)
MailServerPassword=tmp(12)
SMTP=tmp(13)
Website=tmp(2)
Otheinfo=tmp(21)

Subject = "您在"&FromName&"的找回密码信息！"
AddRecipient = ""&mem_email&""
HTMLBody = "用户名："&mem_loginname&"<br>密码："&Mem_LoginPasd&"<br>请妥善保管好您的密码！"

'response.Write From&"<br>"&FromName&"<br>"&Subject&"<br>"&MailServerUserName&"<br>"&MailServerPassword&"<br>"&AddRecipient&"<br>"&HTMLBody&"<br>"&SMTP
emailtype=1
if emailtype=1 then
Jmailsend From,FromName,Subject,MailServerUserName,MailServerPassword,AddRecipient,HTMLBody,SMTP
else
SendMail From,AddRecipient,Subject,HTMLBody
end if


'Jmail邮件发送组件  1
Function Jmailsend(From,FromName,Subject,MailServerUserName,MailServerPassword,AddRecipient,HTMLBody,SMTP)
'Jmailsend(发送者地址,发送者姓名,邮件主题,身份验证的用户名,身份验证的密码,收件人地址,邮件主体,SMTP)
	On error resume next
	Dim JMail, contentId
	Set JMail = Server.CreateObject("JMail.Message") 
	JMail.Charset = "gb2312" ' 邮件字符集，默认为'US-ASCII'
	' JMa il.ISOEncodeHeaders = False ' 是否进行ISO编码，默认为True
	
	' 发送者信息（可用变量方式赋值）
	JMail.From = From ' 发送者地址
	JMail.FromName = FromName ' 发送者姓名
	JMail.Subject = Subject ' 邮件主题
	
	' 身份验证
	JMail.MailServerUserName = MailServerUserName ' 身份验证的用户名
	JMail.MailServerPassword = MailServerPassword ' 身份验证的密码
	
	' 设置优先级，范围从1到5，越大的优先级越高，3为普通
	JMail.Priority = 3
	
	JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")
	
	' 加入一个收件人【变量email：收件人地址】可以同一语句重复加入多个
	JMail.AddRecipient("[e-mail]")
	
	If Instr(AddRecipient,";") Then
		AddR=Split(AddRecipient,";")
		For i=0 to Ubound(AddR)
		if i>Ubound(AddR) then exit for
		JMail.AddRecipient (AddR(i))
		Next
		else
		JMail.AddRecipient (AddRecipient)
	End if
	' 加入附件【变量filename：附件文件的绝对地址，确保用户IUSR_机器名有访问的权限】
	' 【参数设置是(True)否(False)为Inline方式】
	'contentId = JMail.AddAttachment (Server.MapPath("jmail.asp"), True)
	' 邮件主体（HTML(注意信件内链接附件的方式)）
	
	JMail.HTMLBody = HTMLBody
	
	' 邮件主体（文本部分）
	JMail.Body = "我们的邮件采用了HTML格式，但是您的邮件查看软件可能不支持。。。"
	
	' 发送【调用格式：objJMail.Send([username:password@]SMTPServerAddress[:Port])】
	JMail.Send(SMTP)
	
	' 关闭并清除对象
	JMail.Close()
	Set JMail = Nothing
	
	If err.number<>0 then
		err.Clear
		SendMail From,AddRecipient,Subject,HTMLBody
		'Response.Write "<center>很遗憾，服务器暂不支持邮件发送！</center>"
		else
		session("Mailinfo")="<center>您的注册信息已经成功发送到您的邮箱，请及时查收,感谢您对我们的支持！</center>"
	End if
End Function

'windows2003自带发送邮件 2
Function SendMail (mailFrom,mailTo,Subject,HtmlBody)
	On error resume next 
	Dim cm
	Set cm=Server.CreateObject("CDO.Message")
	'创建对象
	with cm
	 .From=mailFrom
	'发信人的邮箱
	 .To="[e-mail];"&mailTo
	'收信人的邮箱
	 .Subject=Subject
	'邮件的主题
	
	 .HtmlBody=HtmlBody
	
	'cm.AddAttachment Server.MapPath("test.zip")
	'如果有需要发送附件的话就用上面的方法把文件附加进去。 
	
	 .Send
	end with
	Set cm=Nothing

    if err then 
      SendMail=False 
      err.Clear 
	  session("Mailinfo")="<center>很遗憾，由于您的服务器不支持邮件发送，您的意见暂时未提交成功！<br>请直接联系我们的客服，或者去帮助中心寻求帮助，感谢您对我们的支持！</center>"
    else 
      SendMail=True
	  session("Mailinfo")="<center>您的注册信息已经成功发送到您的邮箱，请及时查收！感谢您对我们的支持！</center>"
    end if
	'response.End()
End Function
%>