compilelabs

Vxworks的培训教程,大家分享下啊,

#!/bin/csh -f

# This script compiles VxWorks and Unix C programs in the student lab
# directories for the appropriate architecture. Not all .c files will
# be compiled - we need to leave some work for the students!
# 
# The environment variables WIND_BASE and WIND_HOST_TYPE should be set
# before this script is run. Run this script from the 'student'
# directory before copying its contents to the student team home directories.

#set verbose

echo " "
if (! $?WIND_BASE || ! $?WIND_HOST_TYPE ) then
	echo " "
	echo Tornado environment variables WIND_BASE and WIND_HOST_TYPE
	echo must be defined. Quitting.
	exit 1
endif

if ( ! -d $WIND_BASE/host/$WIND_HOST_TYPE/bin ) then
	echo " "
	echo Tornado executable directory 
	echo \"$WIND_BASE/host/$WIND_HOST_TYPE/bin\"
	echo does not exist. Quitting.
	exit 1
endif

if (! -e lab4 || ! -e lab13) then
	echo " "
	echo Run script within \'student\' directory containing labs.
	exit 1
endif

set labdir = `pwd`

# Set default values
set arch = simso
set CPU = SIMSPARCSOLARIS
set answers = "$labdir/../answers"
set FLAGS = ""
set NETOPTS = '-traditional -lnsl -lsocket'

@ i = 1 
while ($i <= $#argv)
	set arg = "$argv[$i]"
	switch ("$arg")
	case CPU=*:
		set CPU = `echo -n $arg | cut -c 5- -`
		breaksw
	case arch=*:
		set arch = `echo -n $arg | cut -c 6- -`
		breaksw
	case answers=*:
		set answers=`echo -n $arg | cut -c 9- -`
		breaksw
	case FLAGS=*:
		set FLAGS=`echo -n $arg | cut -c 7- -`
		breaksw
	case ccUNIX=*:
		set ccUNIX=`echo -n $arg | cut -c 8- -`
		breaksw
	case NETOPTS=*:
		set NETOPTS=`echo -n $arg | cut -c 9- -`
		breaksw
	default:
		echo Strange argument $arg ... quitting.
		exit 1
		breaksw
	endsw
	@ i++
end

echo CPU=$CPU
echo arch=$arch

if (-d $answers) then
    echo answers=$answers
else
    echo " "
    echo The answers directory \'$answers\' does not exist.
    echo 'var.o' in lab3 will not be compiled. Notify the instructor.
endif

echo FLAGS=$FLAGS

if (! $?ccUNIX) then
	if (X$arch == Xsimso || X$arch == Xhppa || X$arch == Xsparc) then
		set ccUNIX="$WIND_BASE/host/$WIND_HOST_TYPE/bin/cc$arch"
	else
		set ccUNIX="gcc"
	endif
endif

#if (! -x $ccUNIX) then
#	echo " "
#	echo Unix compiler \"$ccUNIX\" does not exist or is not executable.
#	echo Unix network lab programs will not be compiled.
#else
	echo Unix compilation will use \"$ccUNIX $NETOPTS\".
#endif

echo " "

#Solaris Native compiler
#alias ccUNIX cc
#set NETOPTS = '-Xs -lnsl -lsocket'

alias ccx  "$WIND_BASE/host/$WIND_HOST_TYPE/bin/cc$arch -c -DCPU=$CPU -I$WIND_BASE/target/h -fno-builtin -nostdinc -Wall $FLAGS"

cd $labdir/lab3
# ccx demo.c
ccx loop.c
if (-f $answers/lab3/var.c) then
    echo "Note: a 'var2 defined but not used' message is expected below ..."
    echo " "
    ccx $answers/lab3/var.c
else
    rm -f var.o
endif

# cd $labdir/lab4
# ccx -g -O0 rdbLab.c

cd $labdir/lab5
ccx recur.c
ccx recur2.c
# demo.c not used in this lab?
ccx demo.c

cd $labdir/lab6
ccx semB.c
ccx semC.c
ccx semM.c
ccx mutex.c

cd $labdir/lab7
ccx copyMsg.c

cd $labdir/lab9
ccx wdTask.c

cd $labdir/lab10
ccx select.c

#cd $labdir/lab11

cd $labdir/lab12
ccx copyMsg.c

cd $labdir/lab13/udp
ccx sockHelp.c
$ccUNIX $NETOPTS -o unixServer unixServer.c

cd $labdir/lab13/tcp
ccx sockHelp.c
$ccUNIX $NETOPTS -o testServer testServer.c
$ccUNIX $NETOPTS -o conClient conClient.c

ccx seqServer.c

#cd $labdir/lab14

cd $labdir/unsupported/rpc
$ccUNIX -o unixDate unixDate.c

echo " "
echo Done!