manova_postestimation.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 30apr2005}{...}
{cmd:help manova postestimation}{...}
{right:dialogs:  {bf:{dialog manovatest}}  {bf:{dialog manova_p:predict}}  {bf:{dialog testmanova:test}}}
{right:also see:  {helpb manova}{space 19}}
{hline}

{title:Title}

{p 4 36 2}
{hi:[MV] manova postestimation} {hline 2} Postestimation tools for manova


{title:Description}

{pstd}
The following postestimation command is of special interest after {cmd:manova}:

{synoptset 14 tabbed}{...}
{p2coldent:command}description{p_end}
{synoptline}
{synopt:{helpb manova postestimation##manovatest:manovatest}}multivariate
	tests after {cmd:manova}{p_end}
{synopt:{helpb screeplot}}plot eigenvalues{p_end}
{synoptline}

{pstd}
In addition, the following standard postestimation commands are available:

{p2coldent:command}description{p_end}
{synoptline}
{synopt:{helpb adjust}}adjusted predictions of xb{p_end}
{p2coldent:* {helpb estat}}VCE and estimation sample summary{p_end}
INCLUDE help post_estimates
INCLUDE help post_lincom
{synopt:{helpb manova postestimation##predict:predict}}predictions, residuals,
	and standard errors{p_end}
{synopt:{helpb manova postestimation##test:test}}Wald tests for simple and
	composite linear hypotheses{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
* {cmd:estat ic} is not available after {cmd:manova}.
{p_end}


{title:Special-interest postestimation commands}

{pstd}
{cmd:manovatest} provides multivariate tests involving {it:term}s
or linear combinations of the underlying design matrix
from the most recently fitted {cmd:manova}.  The four multivariate test
statistics are Wilks' lambda, Pillai's trace, Lawley-Hotelling trace, and
Roy's largest root.  The format of the output is similar to that shown by
{helpb manova}.

{pstd}
{cmd:test} has specialized syntax for use after {cmd:manova}; see below.
{cmd:test} performs Wald tests of expressions involving the coefficients of
the underlying regression model.  Simple and composite linear hypotheses are
possible.


{marker predict}{...}
{title:Syntax for predict}

{p 8 16 2}{cmd:predict} {dtype} {newvar:name} {ifin}
[{cmd:,} {opt eq:uation(eqno[, eqno])}
{it:statistic}]

{synoptset 14 tabbed}{...}
{synopthdr:statistic}
{synoptline}
{syntab:Main}
{synopt:{opt xb}}xb fitted values; the default{p_end}
{synopt:{opt stdp}}standard error of the prediction{p_end}
{synopt:{opt r:esiduals}}residuals{p_end}
{synopt:{opt d:ifference}}difference between the linear predictions of two
	equations{p_end}
{synopt:{opt stdd:p}}standard error of the difference in linear
	predictions{p_end}
{synoptline}
{p2colreset}{...}
INCLUDE help esample


{title:Options for predict}

{dlgtab:Main}

{phang}
{opt equation(eqno [, eqno])} specifies the equation to which you are
referring.

{pmore}
{opt equation()} is filled in with one {it:eqno} for options
    {cmd:xb}, {cmd:stdp}, and {cmd:residuals}.  {cmd:equation(#1)} would mean
    the calculation is to be made for the first equation, {cmd:equation(#2)}
    would mean the second, and so on.  Alternatively, you could refer to the
    equations by their names.  {cmd:equation(income)} would refer to the
    equation named income and {cmd:equation(hours)} to the equation named
    hours.

{pmore}
If you do not specify {cmd:equation()}, results are the same as if you
    specified {cmd:equation(#1)}.

{pmore}
{opt difference} and {opt stddp} refer to between-equation
    concepts.  To use these options, you must specify two equations, e.g.,
    {cmd:equation(#1,#2)} or {cmd:equation(income,hours)}.  When two equations
    must be specified, {cmd:equation()} is required.  With
    {cmd:equation(#1,#2)}, {opt difference} computes the prediction of
    {cmd:equation(#1)} minus the prediction of {cmd:equation(#2)}.

{phang}
{cmd:xb}, the default, calculates the fitted values--the prediction of xb for
the specified equation.

{phang}
{cmd:stdp} calculates the standard error of the prediction for the specified
equation (the standard error of the estimated expected value or mean for the
observation's covariate pattern).  This is also referred to as the standard
error of the fitted values.

{phang}
{cmd:residuals} calculates the residuals.

{phang}
{cmd:difference} calculates the difference between the linear
predictions of two equations in the system.

{phang}
{cmd:stddp} calculates the standard error of the difference in linear
predictions between two equations.

{pstd}
For more information on using {cmd:predict} after multiple-equation commands,
see {helpb predict}.


{marker manovatest}{...}
{title:Syntax for manovatest}

{p 8 19 2}
{cmd:manovatest} {it:term} [{it:term ...}] [{cmd:/} {it:term} [{it:term ...}]]
[{cmd:,} {opt ytr:ansform(matname)}]

{p 8 19 2}
{cmd:manovatest} {cmd:,} {opt test(matname)}
[{opt ytr:ansform(matname)}]

{p 8 19 2}
{cmd:manovatest} {cmd:,} {opt showord:er}

{pstd}
where {it:term} is of the form
{it:varname}[{c -(}{cmd:*}|{cmd:|}{c )-}{it:varname}[{it:...}]]


{title:Options for manovatest}

{phang}
{cmd:ytransform(}{it:matname}{cmd:)} specifies a matrix for transforming the y
variables (the {it:depvarlist} from {helpb manova}) as part of the test.  The
multivariate tests are based on inv(A*E*A')*(A*H*A').  By default, A is the
identity matrix.  {cmd:ytransform()} is how you specify an A matrix to be used
in the multivariate tests.  Specifying {cmd:ytransform()} provides the same
results as first transforming the Y variables with Y*A', where Y is the matrix
formed by binding the y variables by column, and A is the matrix stored in
{it:matname}; performing the {cmd:manova} on the transformed ys; and then
running {cmd:manovatest} without {cmd:ytransform()}.

{pmore}
The number of columns of {it:matname} must equal the number of variables in
the {it:depvarlist} from {cmd:manova}.  The number of rows must be less than
or equal to the number of variables in the {it:depvarlist} from {cmd:manova}.
{it:matname} should have columns in the same order as the {it:depvarlist} from
{cmd:manova}.  The column and row names of {it:matname} are ignored.

{pmore}
When {cmd:ytransform()} is specified, a listing of the transformations is
presented before the table containing the multivariate tests.  You should
examine this table to verify that you have applied the transformation you
desired.

{phang}
{cmd:test(}{it:matname}{cmd:)} is required with the second syntax of
{cmd:manovatest}.  The rows of {it:matname} specify linear combinations of the
underlying design matrix of the MANOVA that are to be jointly tested.  The
columns correspond to the underlying design matrix (including the constant if
it has not been suppressed).  The column and row names of {it:matname} are
ignored.

{pmore}
A listing of the constraints imposed by the {cmd:test()} option is presented
before the table containing the multivariate tests.  You should examine this
table to verify that you have applied the linear combinations you desired.
Typing {cmd:manovatest , showorder} allows you to examine the ordering of the
columns for the design matrix from the MANOVA.

{phang}
{cmd:showorder} causes {cmd:manovatest} to list the definition of each column
in the design matrix.  {cmd:showorder} is not allowed with any other option
or when {it:term}s are specified.


{marker test}{...}
{title:Syntax for test following manova}

{p 8 13 2}
{cmdab:te:st}
{cmd:,}
{opt test(matname)}
[{cmdab:m:test}[{cmd:(}{it:opt}{cmd:)}]
{opt matvlc(matname2)}]

{p 8 13 2}
{cmdab:te:st} [{it:exp} {cmd:=} {it:exp}]
[{cmd:,} {opt a:ccumulate}
{opt not:est}
{opt matvlc(matname2)}]

{p 8 13 2}
{cmdab:te:st} {cmd:,} {opt showord:er}

{p 4 6 2}
where {it:exp} must have references to coefficients enclosed in
{cmd:[}{it:eqno}{cmd:]_coef[]} (or synonym {cmd:[}{it:eqno}{cmd:]_b[]}).
{it:eqno} is either {cmd:#}{it:#} or {it:name}.  Omitting
{cmd:[}{it:eqno}{cmd:]} is equivalent to specifying {cmd:[#1]}.


{title:Options for test after manova}

{p 4 8 2}
{cmd:test(}{it:matname}{cmd:)} is required with the first syntax of
{cmd:test}.  The rows of {it:matname} specify linear combinations of the
underlying design matrix of the MANOVA that are to be jointly tested.  The
columns correspond to the underlying design matrix (including the constant if
it has not been suppressed).  The column and row names of {it:matname} are
ignored.

{p 8 8 2}
A listing of the constraints imposed by the {cmd:test()} option is presented
before the table containing the tests.  You should examine this
table to verify that you have applied the linear combinations you desired.
Typing {cmd:test , showorder} allows you to examine the ordering of the
columns for the design matrix from the MANOVA.

{p 8 8 2}
{it:matname} should have as many columns as the number of dependent variables
times the number of columns in the basic design matrix.  The design matrix is
repeated for each dependent variable.

{p 4 8 2}{cmd:mtest}[{cmd:(}{it:opt}{cmd:)}]
specifies that tests are performed for each condition separately.  {it:opt}
specifies the method for adjusting p-values for multiple testing.  Valid
values for {it:opt} are

{p 12 12 2}{cmdab:b:onferroni}{space 4}Bonferroni's method{p_end}
{p 12 12 2}{cmdab:h:olm}{space      10}Holm's method{p_end}
{p 12 12 2}{cmdab:s:idak}{space      9}Sidak's method{p_end}
{p 12 12 2}{cmdab:noadj:ust}{space   6}no adjustment is to be made{p_end}

{p 8 8 2}
Specifying {cmd:mtest} without an argument, is equivalent to
{cmd:mtest(noadjust)}.

{p 4 8 2}
{cmd:accumulate} allows a hypothesis to be tested jointly with the
previously tested hypotheses.

{p 4 8 2}
{cmd:notest} suppresses the output.  This option is useful when you are
interested only in the joint test with additional hypotheses specified
in a subsequent call of {cmd:test, accumulate}.

{p 4 8 2}
{cmd:matvlc(}{it:matname}{cmd:)}, a programmers option, saves the
variance-covariance matrix of the linear combinations involved in the suite
of tests.  For the test of H0: L*b = c, what is returned in
{it:matname} is L*V*L', where V is the estimated variance-covariance matrix of
b.

{p 4 8 2}
{cmd:showorder} causes {cmd:test} to list the definition of each column
in the design matrix.  {cmd:showorder} is not allowed with any other option.


{title:Examples}

{phang}{cmd:. manova y1 y2 y3 = x1 x2 x1*x2}

{phang}{cmd:. manovatest x1*x2}

{phang}{cmd:. manovatest x1 x1*x2}

{phang}{cmd:. matrix ydif = (1, -1, 0 \ 0, 1, -1)}{p_end}
{phang}{cmd:. manovatest x1*x2 , ytransform(ydif)}


{phang}{cmd:. manova y1 y2 = x1 x2 x3 x1*x2 x1*x3 x2*x3}

{phang}{cmd:. manovatest x1 x1*x2 x1*x3}

{phang}{cmd:. test [y1]_b[x1[1]] = [y1]_b[x1[2]]}

{phang}{cmd:. test [y2]_b[x1[2]*x2[1]] = ([y2]_b[x1[1]*x2[1]] + [y2]_b[x1[3]*x2[1]])/2}


{phang}{cmd:. manova y1 y2 = a / b|a / c|b|a}

{phang}{cmd:. manovatest a / b|a c|b|a}

{phang}{cmd:. matrix y1only = (1, 0)}{p_end}
{phang}{cmd:. manovatest a / b|a c|b|a , ytransform(y1only)}


{phang}{cmd:. manova y1 y2 y3 = a}{space 10}({cmd:a} with 8 levels)

{phang}{cmd:. matrix between = (0,1,1,1,1,-1,-1,-1,-1)}{p_end}
{phang}{cmd:. manovatest , test(between)}

{phang}{cmd:. matrix c1 = (0,1,0,0,-1,0,0,0,0)}{p_end}
{phang}{cmd:. matrix c2 = (0,0,1,0,-1,0,0,0,0)}{p_end}
{phang}{cmd:. matrix c3 = (0,0,0,1,-1,0,0,0,0)}{p_end}
{phang}{cmd:. matrix c = c1 \ c2 \ c3}{p_end}
{phang}{cmd:. manovatest , test(c)}

{phang}{cmd:. matrix d1 = (0,0,0,0,0,1,0,0,-1)}{p_end}
{phang}{cmd:. matrix d2 = (0,0,0,0,0,0,1,0,-1)}{p_end}
{phang}{cmd:. matrix d3 = (0,0,0,0,0,0,0,1,-1)}{p_end}
{phang}{cmd:. matrix d = d1 \ d2 \ d3}{p_end}
{phang}{cmd:. manovatest , test(d)}

{phang}{cmd:. test, showorder}{p_end}
{phang}{cmd:. matrix t1y1 = d1 , J(1,18,0)}{p_end}
{phang}{cmd:. matrix t2y1 = d2 , J(1,18,0)}{p_end}
{phang}{cmd:. matrix t3y1 = d3 , J(1,18,0)}{p_end}
{phang}{cmd:. matrix t1y2 = J(1,9,0), d1 , J(1,9,0)}{p_end}
{phang}{cmd:. matrix t2y2 = J(1,9,0), d2 , J(1,9,0)}{p_end}
{phang}{cmd:. matrix t3y2 = J(1,9,0), d3 , J(1,9,0)}{p_end}
{phang}{cmd:. matrix t1y3 = J(1,18,0), d1}{p_end}
{phang}{cmd:. matrix t2y3 = J(1,18,0), d2}{p_end}
{phang}{cmd:. matrix t3y3 = J(1,18,0), d3}{p_end}
{phang}{cmd:. matrix t = t1y1\t2y1\t3y1\t1y2\t2y2\t3y2\t1y3\t2y3\t3y3}{p_end}
{phang}{cmd:. test , test(t)}

{phang}{cmd:. test , test(t) mtest}

{phang}{cmd:. test , test(t) mtest(bonferroni)}


{title:Also see}

{psee}
Manual:  {bf:[MV] manova postestimation}

{psee}
Online:  {helpb manova},{break}
{helpb adjust},
{helpb estat},
{helpb estimates},
{helpb lincom},
{helpb screeplot}
{p_end}