xtlogit.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  xtlogit

*!  VERSION 1.1.7  23jun2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_glm
INCLUDE _ht320
INCLUDE header

HELP hlp1, view("help xtlogit")
RESET res1

DIALOG main, tabtitle("Model") 	///
	label("xtlogit - Fixed-effects, random-effects, and population-averaged logit models")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_panelset
  INCLUDE _dviv_ts4set

  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_model  _lft      _ls       _iwd      _ht2,		/*
	*/ label("Model type (affects which options are available)")	/*
		*/
  RADIO    rb_re     _ilft     _ss       _cwd3_2   .,			/*
		*/ label("Random-effects (RE)")				/*
		*/ clickon("script re_opts")				/*
		*/ first						/*
		*/ option("re")						/*
		*/
  RADIO    rb_fe     _ilft3_2  @         @         .,			/*
		*/ label("Fixed-effects (FE)")				/*
		*/ clickon("script fe_opts")				/*
		*/ option("fe")						/*
		*/
  RADIO    rb_pa     _ilft3_3  @         @         .,			/*
		*/ label("Population-averaged (PA)")			/*
		*/ clickon("script pa_opts")				/*
		*/ last							/*
		*/ option("pa")						/*
		*/

  GROUPBOX gb_opts   _lft      _xls      _iwd      _ht9h,		/*
		*/ label("Options")					/*
		*/

  TEXT     tx_offset _ilft     _ss       _cwd2     .,			/*
		*/ label("Offset variable:")				/*
		*/
  DEFINE y @y
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/

  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints

END

INCLUDE intopts_re

SCRIPT re_opts
BEGIN
	script intopts_re_enable
	script max_ml_on
	script rpt_lrtest_enable
	main.ck_nocons.enable

	program check_se_status
	program disable_xtgee_common
	script weights_setLayout_i
	main.tx_constr.enable
	main.cb_constr.enable
END

SCRIPT fe_opts
BEGIN
	script intopts_re_disable
	script rpt_lrtest_enable
	main.ck_nocons.disable

	program check_se_status
	program disable_xtgee_common
	script max_ml_on
	main.tx_constr.enable
	main.cb_constr.enable
	script weights_setLayout_i
END

SCRIPT pa_opts
BEGIN
	script intopts_re_disable
	script rpt_lrtest_disable
	main.ck_nocons.enable
	main.tx_constr.disable
	main.cb_constr.disable
	program check_se_status
	program enable_xtgee_common
	script max_pa_on
	script weights_setLayout_fpi
END

INCLUDE xtgee_common
INCLUDE byifin
INCLUDE weights
INCLUDE se
INCLUDE rpt_xt_or
INCLUDE max_ml

SCRIPT PREINIT
BEGIN
	script se_createAsGEE
END

PROGRAM check_se_status
BEGIN
	if main.rb_pa {
		call script se_setGEE_on
	}
	if !main.rb_pa {
		call script se_setGEE_off
	}
END

SCRIPT POSTINIT
BEGIN
	program check_se_status
	script max_int_on
	script corr_setTabTitlePA
	script corr_setForceVisible
	script weights_setLayout_i
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "xtlogit "
	varlist main.vn_dv [main.vl_iv]
	if !main.vl_iv & main.ck_nocons & !D(main.ck_nocons) {
	  stopbox stop `""Suppress constant term" is selected without independent variables."'
	}
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_nocons
		option radio(main rb_re rb_fe rb_pa)
		optionarg main.vn_offset
		put " " /program intopts_re_output
		INCLUDE _constraints_main_pr

		put " " /program xtgee_common_output
		put " " /program se_output
		put " " /program rpt_output
		put " " /program max_output
	endoptions
END