descdata.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  describe.dlg

*! VERSION 1.1.0  17nov2004

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE _ht280
INCLUDE header
HELP hlp1, view("help describe")
RESET res1

DEFINE exin    +70
DEFINE exina   +80
DEFINE exwd     50
DEFINE exwda   195


DIALOG main, label("describe - Describe data in memory") tabtitle("Main")
BEGIN
  TEXT     tx_var        _lft     _top     _iwd        .,	/*
		*/ label("Variables: (leave empty for all variables)")
  VARLIST  vl_var           @      _ss        @        .,	/*
		*/ label("Variables")

  TEXT     tx_examples      @      _ms        @        .,	/*
		*/ label("Examples:")
  TEXT     tx_examp1     exin        @     exwd        ., right	/*
		*/ label("yr*")
  DEFINE   holdx @x
  TEXT     tx_examp1a   exina        @    exwda        .,	/*
		*/ label(`"all variables starting with "yr""')
  TEXT     tx_examp2    holdx      _vss    exwd        ., right	/*
		*/ label("xyz-abc")
  TEXT     tx_examp2a   exina        @    exwda        .,	/*
		*/ label("all variables between xyz and abc")

  GROUPBOX gb_opts       _lft      _ls     _iwd    _ht13,	/*
		*/ label("Options")
  CHECKBOX ck_simple  _indent      _ms    _inwd        .,	/*
  		*/ option(simple)				/*
		*/ onclickon(program simple_on)			/*
		*/ onclickoff(program simple_off)		/*
		*/ label("Display only variable names")
  CHECKBOX ck_short         @      _ms        @        .,	/*
		*/ option(short)				/*
		*/ label("Display only general information")	/*
		*/ onclickon(program short_on)			/*
		*/ onclickoff(program short_off)
  CHECKBOX ck_detail        @      _ms        @        .,	/*
		*/ option(detail)				/*
		*/ label("Display additional details")
  CHECKBOX ck_fullnames     @      _ms        @        .,	/*
		*/ option(fullnames)				/*
		*/ label("Do not abbreviate variable names")	/*
		*/ clickon(gaction main.ck_numbers.disable)	/*
		*/ clickoff(gaction main.ck_numbers.enable)

  CHECKBOX ck_numbers       @      _ms        @        .,	/*
		*/ option(numbers)				/*
		*/ label("Display variable number along with name")/*
		*/ clickon(gaction main.ck_fullnames.disable)	/*
		*/ clickoff(gaction main.ck_fullnames.enable)
END

PROGRAM simple_on
BEGIN
	call main.ck_short.disable
	call main.ck_detail.disable
	call main.ck_fullnames.disable
	call main.ck_numbers.disable
END

PROGRAM simple_off
BEGIN
	call main.ck_short.enable
	call main.ck_detail.enable
	if ! main.ck_short {
		call main.ck_fullnames.enable
		if ! main.ck_fullnames {
			call main.ck_numbers.enable
		}
	}
END

PROGRAM short_on
BEGIN
	call main.ck_fullnames.disable
	call main.ck_numbers.disable
END

PROGRAM short_off
BEGIN
	call main.ck_fullnames.enable
	if ! main.ck_fullnames {
		call main.ck_numbers.enable
	}
END

PROGRAM command
BEGIN
	put "describe "
	varlist [main.vl_var]
	beginoptions
		option main.ck_simple
		option main.ck_short
		option main.ck_detail
		option main.ck_fullnames
		option main.ck_numbers
	endoptions
END