dfuller.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  dfuller.dlg

*! VERSION 1.2.1  02mar2005

*/

VERSION 9.0

INCLUDE _std_medium
INCLUDE _ht230
INCLUDE header
HELP hlp1, view("help dfuller")
RESET res1

DIALOG main, label("dfuller - Augmented Dickey-Fuller unit-roots test") /*
		*/ tabtitle("Main")
BEGIN
  DEFINE _x _xsetbu
  DEFINE _y _top
  INCLUDE _bu_tsset

  TEXT	 	tx_var		_lft	_top	 _cwd2  .,      	/*
              		*/   label("Variable:")

  VARNAME 	vn_var		@	_ss	 _vnwd	.,      	/*
              		*/   label("Variable")				/*
			*/   allowts

  GROUPBOX 	gb_opts 	@       _ls      _iwd	_ht13,		/*
		        */   label("Options")

  CHECKBOX	ck_noconstant   _indent _ss      _inwd  .,      	/*
                        */ label("Suppress constant term in regression")/*
			*/ option(noconstant)				/*
			*/ onclickon(script noconstant_on)		/*
			*/ onclickoff(script noconstant_off)

  CHECKBOX	ck_trend        @       _ms      @      .,      	/*
                        */ label("Include trend term in regression")	/*
			*/ option(trend)				/*
			*/ onclickon(script trend_on)			/*
			*/ onclickoff(script trend_off)

  CHECKBOX      ck_drift        @       _ms      @      .,		/*
  			*/ label("Include drift term in regression")	/*
  			*/ option(drift)				/*
  			*/ onclickon(script drift_on)			/*
  			*/ onclickoff(script drift_off)

  CHECKBOX	ck_regress      @       _ms      @      .,    	        /*
                        */ label("Display regression table")		/*
			*/ option(regress)

  SPINNER   	sp_lags   	@	_ls	 _spwd	.,	        /*
  		        */   min(0) max(1000)	                        /*
  		        */   label("Lagged differences")		/*
  		        */   default(0)					/*
			*/   option(lags)

  TEXT      	tx_lags 	_spsep  @        _sprb  .,	        /*
       	                */   label("Lagged differences")
END

SCRIPT noconstant_on
BEGIN
	main.ck_drift.disable
	main.ck_trend.disable
END

SCRIPT noconstant_off
BEGIN
	main.ck_drift.enable
	main.ck_trend.enable
END

SCRIPT drift_on
BEGIN
	main.ck_noconstant.disable
	main.ck_trend.disable
END

SCRIPT drift_off
BEGIN
	main.ck_noconstant.enable
	main.ck_trend.enable
END

SCRIPT trend_on
BEGIN
	main.ck_noconstant.disable
	main.ck_drift.disable
END

SCRIPT trend_off
BEGIN
	main.ck_noconstant.enable
	main.ck_drift.enable
END

INCLUDE ifin

PROGRAM command
BEGIN
	put "dfuller "
	varlist main.vn_var
	INCLUDE _ifin_pr
	beginoptions
		option main.ck_noconstant
		option main.ck_trend
		option main.ck_drift
		option main.ck_regress
		optionarg main.sp_lags
	endoptions
END