treatreg.hlp

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

{smcl}
{* 18mar2005}{...}
{cmd:help treatreg}{...}
{right:dialogs:  {bf:{dialog treatreg_ml:ml}}  {bf:{dialog treatreg_2step:two-step}} {space 10}}
{right:also see:  {help treatreg postestimation}}
{hline}

{title:Title}

{p2colset 5 21 23 2}{...}
{p2col:{hi:[R] treatreg} {hline 2}}Treatment-effects model{p_end}
{p2colreset}{...}


{title:Syntax}

{phang}
Basic syntax

{p 8 17 2}
{cmd:treatreg}
{depvar}
[{indepvars}]{cmd:,}
{cmdab:tr:eat:(}{it:depvar_t} {cmd:=} {it:indepvars_t}{cmd:)}
[{opt two:step}]

{phang}
Full syntax for maximum likelihood estimates only

{p 8 17 2}
{cmd:treatreg}
{depvar}
[{indepvars}]
{ifin}
{weight}{cmd:,}
{cmdab:tr:eat:(}{it:depvar_t} {cmd:=} {it:indepvars_t} [{cmd:,}
{opt noc:onstant}]{cmd:)}
[{it:{help treatreg##treatreg_ml_options:treatreg_ml_options}}]

{phang}
Full syntax for two-step consistent estimates only

{p 8 17 2}
{cmd:treatreg}
{depvar}
[{indepvars}]
{ifin}{cmd:,}
{cmdab:tr:eat:(}{it:depvar_t} {cmd:=} {it:indepvars_t} [{cmd:,}
{opt noc:onstant}]{cmd:)}
{opt two:step}
[{it:{help treatreg##treatreg_ts_options:treatreg_ts_options}}]


{marker treatreg_ml_options}{...}
{synoptset 26 tabbed}{...}
{synopthdr:treatreg_ml_options}
{synoptline}
{syntab:Model}
{synopt:{opt noc:onstant}}suppress (treatment) constant term{p_end}
{synopt:{cmdab:const:raints(}{it:{help estimation options##constraints():constraints}}{cmd:)}}apply specified linear constraints{p_end}

{syntab:SE/Robust}
{synopt:{opth vce(vcetype)}}{it:vcetype} may be {opt oim}, {opt r:obust},
	{opt opg}, {opt boot:strap} or {opt jack:knife}{p_end}
{synopt:{opt r:obust}}synonym for {cmd:vce(robust)}{p_end}
{synopt:{opth cl:uster(varname)}}adjust standard errors for intragroup
	correlation{p_end}

{syntab:Reporting}
{synopt:{opt l:evel(#)}}set confidence level; default is
	{cmd:level(95)}{p_end}
{synopt:{opt fir:st}}report first-step probit estimates{p_end}
{synopt:{opt noskip}}perform likelihood-ratio test{p_end}
{synopt:{opth ha:zard(newvar)}}create {it:newvar} containing hazard from
	treatment equation{p_end}

{syntab:Max options}
{synopt:{it:{help treatreg##maximize_options:maximize_options}}}control
	maximization process; seldom used{p_end}
{synoptline}

{marker treatreg_ts_options}{...}
{synopthdr:treatreg_ts_options}
{synoptline}
{syntab:Model}
{synopt:{opt noc:onstant}}suppress (treatment) constant term{p_end}

{syntab:SE/Robust}
{synopt:{opth vce(vcetype)}}{it:vcetype} may be 
	{opt boot:strap} or {opt jack:knife}{p_end}

{syntab:Reporting}
{synopt:{opt l:evel(#)}}set confidence level; default is
	{cmd:level(95)}{p_end}
{synopt:{opt fir:st}}report first-step probit estimates{p_end}
{synopt:{opth ha:zard(newvar)}}create {it:newvar} containing hazard from
	treatment equation{p_end}
{synoptline}
{p2colreset}{...}
{p 4 6 2}
{it:depvar}, {it:indepvars}, {it:depvar_t}, and {it:indepvars_t} may contain
time-series operators; see {help tsvarlist}.
	{p_end}
{p 4 6 2}
{opt bootstrap}, {opt by}, {opt jackknife}, {opt rolling}, {opt statsby}, and
{opt xi} are allowed; see {help prefix}.
	{p_end}
{p 4 6 2}
{opt pweight}s, {opt aweight}s, {opt fweight}s, and {opt iweight}s are
allowed with maximum likelihood estimation; see {help weight}.  No weights are
allowed if {opt twostep} is specified.
	{p_end}
{p 4 6 2}
See {help treatreg postestimation} for features available after estimation.
	{p_end}


{title:Description}

{pstd}
{opt treatreg} fits a treatment-effects model using either a
two-step consistent estimator or full maximum likelihood.  The
treatment-effects model considers the effect of an endogenously chosen binary
treatment on another endogenous continuous variable, conditional on two sets
of independent variables.


{title:Options}

{dlgtab:Model}

{phang}
{cmd:treat(}{it:depvar_t}{cmd:=}{it:indepvars_t}[{cmd:,} {opt noc:onstant}]{cmd:)}
   specifies the variables and options for the
   treatment equation.  It is an integral part of specifying a treatment-effects
   model and is required.

{phang}
{opt twostep} specifies that two-step consistent
   estimates of the parameters, standard errors, and covariance matrix of the
   model be produced, instead of the default maximum likelihood estimates.

{phang}
{opt noconstant}, {opt constraints(constraints)}; see
     {help estimation options##noconstant:estimation options}.

{dlgtab:SE/Robust}

{phang}
{opth vce(vcetype)}; see {it:{help vce_option}}.

{phang}
{opt robust}, {opth cluster(varname)}; see
    {help estimation options##robust:estimation options}.

{dlgtab:Reporting}

{phang}
{opt level(#)}; see {help estimation options##level():estimation options}.

{phang}
{opt first} specifies that the first-step probit estimates of the treatment
   equation be displayed before estimation.

{phang}
{opt noskip} specifies that a full maximum likelihood model with only a
   constant for the regression equation be fitted.  This model is not
   displayed, but is used as the base model to compute a likelihood-ratio test
   for the model test statistic displayed in the estimation header.  By
   default, the overall model test statistic is an asymptotically equivalent
   Wald test that all the parameters in the regression equation are zero
   (except the constant).  For many models, this option can substantially
   increase estimation time.

{phang}
{opth hazard(newvar)} will create a new variable containing the
   hazard from the treatment equation.  The hazard is computed from the
   estimated parameters of the treatment equation.

{marker maximize_options}{...}
{dlgtab:Max options}

{phang}
{it:maximize_options}:
{opt diff:icult},
{opt tech:nique(algorithm_spec)},
{opt iter:ate(#)},
[{cmdab:no:}]{opt lo:g},
{opt tr:ace},
{opt grad:ient},
{opt showstep},
{opt hess:ian},
{opt shownr:tolerance},
{opt tol:erance(#)},
{opt ltol:erance(#)},
{opt gtol:erance(#)},
{opt nrtol:erance(#)},
{opt nonrtol:erance(#)},
{opt from(init_specs)};
see {help maximize}.  These options are seldom used.


{title:Examples}

{p 4 4 2}To obtain full ML estimates:

{p 8 12 2}{cmd:. treatreg ww wa cit, treat(wc=wmed wfed)}

{p 4 4 2}To obtain Heckman's two-step consistent estimates:

{p 8 12 2}{cmd:. treatreg ww wa cit, treat(wc=wmed wfed) twostep}

{p 4 4 2}To define and use each equation separately:

{p 8 12 2}{cmd:. global wage_eqn ww wa cit}{p_end}
{p 8 12 2}{cmd:. global trteqn wc=wmed wfed}{p_end}
{p 8 12 2}{cmd:. treatreg $wage_eqn, treat($trteqn)}


{title:Also see}

{psee}
Manual:  {bf:[R] treatreg}

{psee}
Online:  
{help treatreg postestimation},{break}
{helpb constraint},
{helpb heckman},
{helpb probit}
{p_end}