twoway__fpfit_serset.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.2  29apr2003
program twoway__fpfit_serset

	// Creates a serset for a fractional polynomial fit view.  Runs from an 
	// immediate log.

	syntax , SERSETNAME(string) X(string) Y(string) TOUSE(string)	///
		 CMD(string) [ PREDOPTS(string) REGOPTS(string)		///
		 MOREVARS(string) WEIGHT(string)			///
		 LEVEL(real `c(level)') STD(string) ]

	tempname esthold
	_estimates hold `esthold' , nullok restore

	preserve
	qui keep if `touse'

	tempvar yhat
	capture fracpoly `cmd' `y' `x' [`weight'] , `regopts'
	sort `x'
	qui keep if `x' != `x'[_n-1]
	if _rc {
		di in green "(note:  fracpoly could not fit model)"
		qui gen `yhat' = . in 1
		local failed 1
	}
	else	qui fracpred `yhat' , `predopts'

	local ylist `yhat'

	if "`std'" != "" {
		tempvar se lcl ucl

		if 0`failed' {
			qui gen `lcl' = . in 1
			qui gen `ucl' = . in 1
		}
		else {
			qui fracpred `se' , `std'
			qui gen `lcl' = `yhat' -			///
				invttail(e(df_r), ((100-`level')/200)) * `se'
			qui gen `ucl' = `yhat' +			///
				invttail(e(df_r), ((100-`level')/200)) * `se'
		}
		label variable `lcl' "`level'% CI"
		label variable `ucl' "`level'% CI"

		local ylist `ylist' `lcl' `ucl'
	}

	.`sersetname' = .serset.new `ylist' `x' `morevars' ,		///
		`.omitmethod' `options' nocount

	if "`std'" != "" {
		.`sersetname'.sers[2].name = "lower_limit"
		.`sersetname'.sers[3].name = "upper_limit"
	}

	.`sersetname'.sort `x'
	.`sersetname'.sers[1].name = "`y'"

end