tobit.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  tobit

*!  VERSION 1.1.1  30mar2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help tobit")
RESET res1

DIALOG main, label("tobit - Tobit regression")				/*
		*/ tabtitle("Model")
BEGIN
  INCLUDE _dviv

  GROUPBOX gb_censor _lft      _xls      _iwd      _ht8h,		/*
		*/ label("Specify at least one censoring limit")	/*
		*/
  RADIO    rb_noll   _indent   _ss       _cwd2     .,			/*
	  	*/ first						/*
	  	*/ label("No left-censoring limit")			/*
		*/ onclickon("gaction main.en_ll.disable")
  DEFINE y @y
  RADIO    rb_ll     @         _ss       @         .,			/*
		*/ label("Left-censoring at minimum")			/*
		*/ clickon("gaction main.en_ll.disable")		/*
		*/ option("ll")	default(1)				/*
		*/
  RADIO    rb_llarg  @         _ss       @         .,			/*
		*/ last							/*
		*/ label("Specified left-censoring limit:")		/*
		*/ clickon("gaction main.en_ll.enable")			/*
		*/
  EDIT     en_ll     _indent2  _ss       _en14wd   .,			/*
		*/ label("Left-censoring limit")			/*
		*/ numonly						/*
		*/ option("ll")						/*
		*/
  RADIO    rb_noul   _lft2     y         _cwd2     .,			/*
		*/ first						/*
		*/ onclickon("gaction main.en_ul.disable")		/*
		*/ label("No right-censoring limit")
  RADIO    rb_ul     @         _ss       @         .,			/*
		*/ label("Right-censoring at maximum")			/*
		*/ clickon("gaction main.en_ul.disable")		/*
		*/ option("ul")						/*
		*/
  RADIO    rb_ularg  @         _ss       @         .,			/*
		*/ last							/*
		*/ label("Specified right-censoring limit:")		/*
		*/ clickon("gaction main.en_ul.enable")			/*
		*/
  EDIT     en_ul     _indent2  _ss       _en14wd   .,			/*
		*/ label("Right-censoring limit")			/*
		*/ numonly						/*
		*/ option("ul")						/*
		*/


  TEXT     tx_offset _lft      _xxls     _ibwd     .,			/*
		*/ label("Offset variable: (optional)")			/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/
END

INCLUDE byifin
INCLUDE weights_fa
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrap
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y 20
  INCLUDE _sp_level
END

INCLUDE max_internal

SCRIPT POSTINIT
BEGIN
	script max_setDefaultNoLog
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "tobit "
	varlist main.vn_dv [main.vl_iv]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if main.rb_noll & main.rb_noul {
			stopbox stop				/*
			*/ `"On the "Model" tab,"'		/*
			*/ `"at least one censoring limit must be specified"'
		}
		if main.rb_llarg {
			require main.en_ll
			optionarg main.en_ll
		}
		if main.rb_ularg {
			require main.en_ul
			optionarg main.en_ul
		}
		option main.rb_ll
		option main.rb_ul
		optionarg main.vn_offset
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		put " " /program max_output
	endoptions
END