truncreg.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  truncreg

*! VERSION 1.1.1  21feb2005

  keyword:  eclass

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE header

HELP hlp1, view("help truncreg")
RESET res1

DIALOG main, label("truncreg - Truncated regression") tabtitle("Model")
BEGIN
  INCLUDE _dviv

  CHECKBOX ck_nocons @         _ms       @         .,			/*
		*/ label("Suppress constant term")			/*
		*/ option("noconstant")					/*
		*/

  GROUPBOX gb_censor _lft      _ls       _iwd      _ht4h,		/*
	*/ label("At least one truncation limit must be specified")	/*
		*/
  TEXT     tx_ll     _indent   _ss       _cwd2     .,			/*
		*/ label("Left truncation limit:")			/*
		*/
  DEFINE y @y
  VARNAME  vn_ll     @         _ss       _vnwd     .,			/*
		*/ label("Left truncation limit")			/*
		*/ option("ll")						/*
		*/
  TEXT     tx_ul     _lft3_2   y         _cwd2     .,			/*
		*/ label("Right truncation limit:")			/*
		*/
  VARNAME  vn_ul     @         _ss       _vnwd     .,			/*
		*/ label("Right truncation limit")			/*
		*/ option("ul")						/*
		*/
END

DIALOG model2, tabtitle("Model 2")
BEGIN
  GROUPBOX gb_option _lft      _top      _iwd      _ht18h,		/*
  		*/ label("Options")
  TEXT     tx_offset _ilft     _ss       _cwd1     .,			/*
		*/ label("Offset variable:")				/*
		*/
  VARNAME  vn_offset @         _ss       _vnwd     .,			/*
		*/ label("Offset variable")				/*
		*/ option("offset")					/*
		*/
  RADIO    rb_default _ilft    _ls       _ibwd     .,			/*
  		*/ label("Do not estimate marginal effects (default)") /*
  		*/ first						/*
  		*/ onclickon(model2.cb_at.disable)
  RADIO    rb_margin _ilft     _ss       _ibwd     .,			/*
		*/ label("Estimate marginal effects around the mean of the independent variables")	/*
		*/ option("marginal")					/*
  		*/ onclickon(model2.cb_at.disable)
  RADIO    rb_at     _ilft     _ss       _ibwd     .,			/*
		*/ label("Estimate marginal effect at:")		/*
  		*/ onclickon(model2.cb_at.enable)			/*
		*/ last
  COMBOBOX cb_at     _indent2  _ss       150       .,			/*
		*/ dropdown						/*
		*/ contents(row)					/*
		*/ label("Estimate marginal effects at")		/*
		*/ option("at")						/*
		*/
  DEFINE _x _ilft
  DEFINE _cx _ibwd
  DEFINE _y _ls
  INCLUDE _constraints
END

INCLUDE byifin
INCLUDE weights_fpa
INCLUDE se

SCRIPT PREINIT
BEGIN
	script se_createAsJknifeBstrapML
END

DIALOG rpt, tabtitle("Reporting")
BEGIN
  DEFINE _x _lft
  DEFINE _cx _spr2b
  DEFINE _y _top
  INCLUDE _sp_level

  GROUPBOX gb_tests  _lft      +35      _iwd       _ht2,		/*
  		*/ label("Additional test statistics")
  CHECKBOX ck_noskip _ilft     _ss      _cwd2      .,			/*
		*/ label("Perform likelihood-ratio test")		/*
		*/ option("noskip")					/*
		*/
END

INCLUDE max_ml

SCRIPT POSTINIT
BEGIN
	script max_setFromNotVisible
END

PROGRAM command
BEGIN
	allowxi
	INCLUDE _by_pr
	put "truncreg "
	varlist main.vn_dv [main.vl_iv]
	INCLUDE _weights_pr
	INCLUDE _ifin_pr
	beginoptions
		if ! (main.vn_ll | main.vn_ul) {
			stopbox stop `"At least one truncation limit"' /*
			*/ `""Left" or "Right" must be specified"'
		}
		optionarg main.vn_ll
		optionarg main.vn_ul
		option main.ck_nocons
		optionarg model2.vn_offset
		option model2.rb_margin
		if model2.rb_at {
			require model2.cb_at
		}
		optionarg model2.cb_at
		optionarg model2.cb_constr
		put " " /program se_output
		optionarg /hidedefault rpt.sp_level
		option rpt.ck_noskip
		put " " /program max_output
	endoptions
END