testanova.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  testanova

*! VERSION 1.0.2  31mar2005

*/
VERSION 8.0

INCLUDE _std_large
INCLUDE _ht350
INCLUDE header

HELP hlp1, view("help testanova")
RESET res1

DIALOG main, label("testanova - Test linear hypotheses after anova") /*
		*/ tabtitle("Main")
BEGIN
  /*--+----1----+----2----+----3----+----4----+----5----+----6----+----7----+*/
  GROUPBOX gb_type        _lft      _top       _iwd     _ht12,		/*
  		*/label("Test type:")
  RADIO    rb_mat         _ilft     _ss        _inwd    .,		/*
  */label("Test expressions involving coef. of underlying regression model (matrix)")/*
  		*/first							/*
  		*/onclickon(script mat_on)
  RADIO    rb_line        _ilft     _ss        @        .,		/*
 */label("Test expressions involving coef. of underlying regression model (expression)")/*
 		*/clickon(program line_on)
  RADIO    rb_eff         @         _ss        @        .,		/*
  		*/label("Test effects")					/*
		*/clickon(program effects_on)
  RADIO    rb_symb        @         _ss        @        .,		/*
  		*/label("Show symbolic forms")				/*
  		*/clickon(program symb_on)
  RADIO    rb_showorder   @         _ss        @        .,		/*
  		*/label("Show order of columns in the design matrix")	/*
  		*/onclickon(script showorder_on)
  RADIO    rb_redis       @         _ss        @        .,		/*
  		*/label("Redisplay results from previous test")		/*
  		*/last 							/*
		*/clickon(program all_off)
  BUTTON   bu_effexamp    _lft4_4   _xls       _cwd4_1  .,		/*
		*/ push("script examples")                              /*
 		*/ label("Examples...")
  DEFINE  holdy @y
  TEXT     tx_eff         _lft      +5         _comb4_1 .,		/*
  		*/label("Effects to test:")
  VARLIST  vl_eff         @         _ss        _iwd     .,		/*
  		*/label("Effects to test")
  BUTTON   bu_linexamp    _lft4_4   holdy      _cwd4_1  .,		/*
  		*/label("Examples...")					/*
  		*/push("script lin_examp")
  TEXT     tx_line        _lft      +5         _comb4_2 .,		/*
  		*/label("Linear expressions to test:")
  VARLIST  vl_line        _lft      _ss        _iwd     .,		/*
  		*/label("Linear expressions to test")

  BUTTON   bu_matxamp     _lft4_4   holdy      _cwd4_1  .,		/*
  		*/label("Examples...")					/*
  		*/push("script mat_examp")
  TEXT     tx_mat         _lft      +5         _comb4_2 .,		/*
  		*/label("Matrix to test:")
  COMBOBOX cb_mat         _lft      _ss        _iwd     .,              /*
		*/ label("")                                            /*
		*/ contents(matrix)                                     /*
		*/ dropdown                                             /*
		*/ error("Matrix to test")

  GROUPBOX gb_opt         @         _ls        @        _ht8,		/*
  		*/label("Options")
  CHECKBOX ck_acc         _ilft     _ms        _ibwd    .,		/*
  	*/label("Test jointly with the previously tested hypotheses")   /*
  		*/option(accumulate)
DEFINE opty @y
  CHECKBOX ck_notest      @         _ms        @         .,		/*
  		*/label("Suppress the output") option(notest)

  CHECKBOX ck_mtest       @         opty       @        .,		/*
  		*/label("Test each condition separately") 		/*
  		*/onclickon(script mtest_on)				/*
  		*/onclickoff(script mtest_off)				/*
  		*/option(mtest)
  TEXT     tx_mtest       @         _ms        @        .,		/*
  		*/label("P-value adjustment:")
  COMBOBOX cb_mtest       @         _ss        @        .,		/*
  		*/label("P-value adjustment")				/*
  		*/dropdownlist						/*
  		*/contents(mtest_list) values(mtest_list_val)		/*
  		*/default("noadjust") 					/*
  		*/option(mtest)

  /* matvlc option omitted since it is a programmer's option. */
END

LIST mtest_list
BEGIN
	Bonferroni's method
	Holm's method
	Sidak's method
	No adjustment
END

LIST mtest_list_val
BEGIN
	bonferroni
	holm
	sidak
	noadjust
END

SCRIPT mtest_on
BEGIN
	main.tx_mtest.enable
	main.cb_mtest.enable
END

SCRIPT mtest_off
BEGIN
	main.tx_mtest.disable
	main.cb_mtest.disable
END

PROGRAM all_off
BEGIN
	call gaction main.ck_notest.hide
	call gaction main.ck_acc.hide
	call gaction main.gb_opt.hide
	call gaction main.tx_line.hide
	call gaction main.vl_line.hide
	call gaction main.bu_linexamp.hide
	call gaction main.vl_eff.hide
	call gaction main.tx_eff.hide
	call gaction main.bu_effexamp.hide
	call gaction main.bu_matxamp.hide
	call gaction main.tx_mat.hide
	call gaction main.cb_mat.hide
	call gaction main.ck_mtest.hide
	call gaction main.cb_mtest.hide
	call gaction main.tx_mtest.hide
END

SCRIPT mat_on
BEGIN
	program all_off
	main.bu_matxamp.show
	main.tx_mat.show
	main.cb_mat.show
	main.gb_opt.show
	main.ck_mtest.show
	main.cb_mtest.show
	main.tx_mtest.show
END

PROGRAM line_on
BEGIN
        call program all_off
	call gaction main.ck_notest.show
	call gaction main.ck_acc.show
	call gaction main.gb_opt.show
	call gaction main.tx_line.show
	call gaction main.vl_line.show
	call gaction main.bu_linexamp.show
END

PROGRAM symb_on
BEGIN
	call program all_off
	call gaction main.bu_effexamp.show
	call gaction main.tx_eff.setlabel "Effects: (leave empty for symbolic form of estimable functions)"
	call gaction main.vl_eff.setlabel "Effects"
	call gaction main.tx_eff.show
	call gaction main.vl_eff.show
END

SCRIPT showorder_on
BEGIN
	program all_off
END

PROGRAM effects_on
BEGIN
	call program all_off
	call gaction main.bu_effexamp.show
	call gaction main.tx_eff.setlabel "Effects to test:"
	call gaction main.vl_eff.setlabel "Effects to test"
	call gaction main.tx_eff.show
	call gaction main.vl_eff.show
END

SCRIPT lin_examp
BEGIN
	view help lin_anova_example##|_new
END

SCRIPT mat_examp
BEGIN
	view help mat_anova_example##|_new
END

SCRIPT examples
BEGIN
	view help anova_example##|_new
END


PROGRAM command
BEGIN
	put "test "
	if main.rb_eff {
		varlist main.vl_eff
	}
	if main.rb_symb{
		varlist [main.vl_eff]
	}
	if main.rb_line {
		varlist main.vl_line
	}
	beginoptions
		if main.rb_mat {
			require main.cb_mat
			put "test(" main.cb_mat ") "
		}
		if  main.cb_mtest {
			optionarg main.cb_mtest
		}
		if main.rb_symb {
			put "symbolic "
		}
		if main.rb_showorder {
			put "showorder "
		}
		if main.rb_line{
			option main.ck_notest
			option main.ck_acc
		}
	endoptions
END