testmanova.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  test after manova

*! VERSION 1.0.2  31mar2005

*/
VERSION 8.0

INCLUDE _std_large
INCLUDE _ht310
INCLUDE header

HELP hlp1, view("help manovatest")
RESET res1

DIALOG main, label("test - Wald test after manova") tabtitle("Main")
BEGIN
  GROUPBOX gb_type        _lft      _top       _iwd     _ht8,		/*
		*/label("Test")
  RADIO    rb_mat         _ilft     _ss        _inwd    .,		/*
  */label("Test expressions involving coef. of underlying regression model (matrix)")/*
		*/first							/*
		*/onclickon(script mat_on)
  RADIO    rb_line        @         _ss        @        .,		/*
*/label("Test expressions involving coef. of underlying regression model (expression)")/*
		*/clickon(program line_on)
  RADIO    rb_showorder   @         _ss        @        .,		/*
  		*/label("Show order of columns in the design matrix")	/*
  		*/onclickon(script showorder_on)
  RADIO    rb_redis       @         _ss        @        .,		/*
		*/label("Redisplay results from previous test")		/*
		*/last							/*
		*/clickon(program line_off)
  BUTTON   bu_linexamp    _lft4_4   _xls       _cwd4_1  .,		/*
		*/label("Examples...")					/*
		*/push("script lin_examp")
DEFINE holdy @y
  TEXT     tx_line        _lft      +5         _comb4_2 .,		/*
		*/label("Linear expression to test:")
  VARLIST  vl_line        _lft      _ss        _iwd     .,		/*
		*/label("Linear expression to test")
  BUTTON   bu_matxamp     _lft4_4   holdy      _cwd4_1  .,		/*
  		*/label("Examples...")					/*
  		*/push("script mat_examp")
  TEXT     tx_mat         _lft      +5         _comb4_2 .,		/*
  		*/label("Matrix to test:")
  COMBOBOX cb_mat         _lft      _ss        _iwd     .,              /*
		*/ label("")                                            /*
		*/ contents(matrix)                                     /*
		*/ dropdown                                             /*
		*/ error("Matrix to test")

  GROUPBOX gb_opt         @         _ls        @        _ht8,		/*
		*/label("Options")
  CHECKBOX ck_acc         _ilft     _ms        _ibwd    .,		/*
		*/option(accumulate)					/*
		*/label("Test jointly with the previously tested hypotheses")
DEFINE opty @y
  CHECKBOX ck_notest      @         _ms        @         .,             /*
		*/label("Suppress the output") option(notest)

  CHECKBOX ck_mtest       @         opty       @        .,		/*
  		*/label("Test each condition separately") 		/*
  		*/onclickon(script mtest_on)				/*
  		*/onclickoff(script mtest_off)				/*
  		*/option(mtest)
  TEXT     tx_mtest       @         _ms        @        .,		/*
  		*/label("P-value adjustment:")
  COMBOBOX cb_mtest       @         _ss        @        .,		/*
  		*/label("P-value adjustment")				/*
  		*/dropdownlist						/*
  		*/contents(mtest_list) values(mtest_list_val)		/*
  		*/default("noadjust") 					/*
  		*/option(mtest)

  /* matvlc option omitted since it is a programmer's option. */
END

LIST mtest_list
BEGIN
	Bonferroni's method
	Holm's method
	Sidak's method
	No adjustment
END

LIST mtest_list_val
BEGIN
	bonferroni
	holm
	sidak
	noadjust
END

SCRIPT mtest_on
BEGIN
	main.tx_mtest.enable
	main.cb_mtest.enable
END

SCRIPT mtest_off
BEGIN
	main.tx_mtest.disable
	main.cb_mtest.disable
END

SCRIPT mat_on
BEGIN
	program line_off
	main.bu_matxamp.show
	main.tx_mat.show
	main.cb_mat.show
	main.gb_opt.show
	main.ck_mtest.show
	main.tx_mtest.show
	main.cb_mtest.show
END

SCRIPT mat_off
BEGIN
	main.bu_matxamp.hide
	main.tx_mat.hide
	main.cb_mat.hide
	main.gb_opt.hide
	main.ck_mtest.hide
	main.tx_mtest.hide
	main.cb_mtest.hide
END

SCRIPT showorder_on
BEGIN
	program line_off
	script mat_off
END

PROGRAM line_off
BEGIN
	call gaction main.ck_notest.hide
	call gaction main.ck_acc.hide
	call gaction main.gb_opt.hide
	call gaction main.tx_line.hide
	call gaction main.vl_line.hide
	call gaction main.bu_linexamp.hide
END

PROGRAM line_on
BEGIN
	call script mat_off
	call gaction main.ck_notest.show
	call gaction main.ck_acc.show
	call gaction main.gb_opt.show
	call gaction main.tx_line.show
	call gaction main.vl_line.show
	call gaction main.bu_linexamp.show
END


SCRIPT lin_examp
BEGIN
	view help lin_manova_example##|_new
END

SCRIPT mat_examp
BEGIN
	view help mat_manova_example##|_new
END

PROGRAM command
BEGIN
	put "test "
	if main.rb_line {
		varlist main.vl_line
	}
	beginoptions
		if main.rb_mat {
			require main.cb_mat
			put "test(" main.cb_mat ") "
		}
		if  main.cb_mtest {
			optionarg main.cb_mtest
		}
		if main.rb_showorder {
			put "showorder "
		}
		if main.rb_line{
			option main.ck_notest
			option main.ck_acc
		}
	endoptions
END