panelset.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
  iis or tsset -- set panel variables

  VERSION 1.0.1  31mar2005

*/

VERSION 8.0

INCLUDE _std_medium
INCLUDE header

HELP hlp1, view("help iis")
RESET res1

DIALOG main, label("iis or tsset - Declare dataset to be panel data")	///
		tabtitle("Main")
BEGIN

  TEXT     tx_i		_lft      _top      _cwd1     .,		///
			label("Panel ID variable:")
  VARNAME  vn_i		@         _ss       _vnwd     .,		///
			option("i")					///
			default(char _dta[iis])				///
			nomemory					///
			label("Panel ID variable")

  CHECKBOX ck_t		_lft2     _top      _cwd1     .,		///
			clickon("program time_check")			///
			clickoff("program time_check")			///
			label("Time variable:")
  VARNAME  vn_t		@         _ss       _vnwd     .,		///
			option("t")					///
			default(char _dta[tis])				///
			nomemory					///
			label("Time variable")

  CHECKBOX ck_clear	_lft      _ls       _iwd      .,		///
			nomemory					///
			clickon("program clear_check")			///
			clickoff("program clear_check")			///
			option("clear")					///
			label("Clear all settings")

  GROUPBOX gb_format	_lft      _ls       _iwd      _ht12,		///
			label("Display format for the time variable:")

  RADIO    rb_none	_ilft     _ss       _cwd2     .,		///
			clickon("program format_check")			///
			first						///
			option(NONE)					///
			label("None specified")

  RADIO    rb_day	_lft2     @         _cwd2     .,		///
			clickon("program format_check")			///
			option("daily")					///
			label("Daily")

  RADIO    rb_week	_ilft     _ss       _cwd2     .,		///
			clickon("program format_check")			///
			option("weekly")				///
			label("Weekly")

  RADIO    rb_month	_lft2     @        _cwd2     .,			///
			clickon("program format_check")			///
			option("monthly")				///
			label("Monthly")

  RADIO    rb_quart	_ilft     _ss       _cwd2     .,		///
			clickon("program format_check")			///
			option("quarterly")				///
			label("Quarterly")

  RADIO    rb_half	_lft2     @        _cwd2     .,			///
			clickon("program format_check")			///
			option("halfyearly")				///
			label("Half-yearly")

  RADIO    rb_year	_ilft     _ss       _cwd2     .,		///
			clickon("program format_check")			///
			option("yearly")				///
			label("Yearly")

  RADIO    rb_gen	_lft2     @        _cwd2     .,			///
			clickon("program format_check")			///
			option("generic")				///
			label("Generic")

  RADIO    rb_format	_ilft     _ss       _rbwd     .,		///
			clickon("program format_check")			///
			last						///
			option(NONE)
  EDIT     ed_format	_rbsep    @         _en7wd    .,		///
			option("format")				///
			default("%tw")					///
			nomemory					///
			label("Format")
  BUTTON   bn_format	_en7sep   @         _rben7r2b .,		///
  			onpush(view help tfmt##|_new)			///
			label("Help format...")

END

PROGRAM clear_check
BEGIN
	if main.ck_clear {
		call gaction main.tx_i.disable
		call gaction main.vn_i.disable
		call gaction main.ck_t.disable
	}
	if ! main.ck_clear {
		call gaction main.tx_i.enable
		call gaction main.vn_i.enable
		call gaction main.ck_t.enable
	}
	call program time_check
END

PROGRAM time_check
BEGIN
	if main.ck_t {
		call gaction main.vn_t.enable
	}
	if ! main.ck_t {
		call gaction main.vn_t.disable
	}
	call program format_check
END

PROGRAM format_check
BEGIN
	if main.ck_t & ! main.ck_clear {
		call gaction main.vn_t.enable
		call gaction main.gb_format.enable
		call gaction main.rb_none.enable
		call gaction main.rb_day.enable
		call gaction main.rb_week.enable
		call gaction main.rb_month.enable
		call gaction main.rb_quart.enable
		call gaction main.rb_half.enable
		call gaction main.rb_year.enable
		call gaction main.rb_gen.enable
		call gaction main.rb_format.enable
		if main.rb_format {
			call gaction main.ed_format.enable
			call gaction main.bn_format.enable
		}
	}
	if ! main.ck_t | main.ck_clear {
		call gaction main.vn_t.disable
		call gaction main.gb_format.disable
		call gaction main.rb_none.disable
		call gaction main.rb_day.disable
		call gaction main.rb_week.disable
		call gaction main.rb_month.disable
		call gaction main.rb_quart.disable
		call gaction main.rb_half.disable
		call gaction main.rb_year.disable
		call gaction main.rb_gen.disable
		call gaction main.rb_format.disable
		call gaction main.ed_format.disable
		call gaction main.bn_format.disable
	}
END

PROGRAM command
BEGIN
	if main.ck_clear {
		if main.ck_t {
			put "tsset, clear"
		}
		if !main.ck_t {
			put "iis, clear"
		}
	}
	if !main.ck_clear {
		if !main.ck_t {
			put "iis "
			varlist main.vn_i
		}
		if main.ck_t {
			put "tsset "
			varlist main.vn_i main.vn_t
			beginoptions
				option radio(main ///
rb_none rb_day rb_week rb_month rb_quart rb_half rb_year rb_gen rb_format)
				if main.rb_format {
					require main.ed_format
					optionarg main.ed_format
				}
			endoptions
		}
	}
END