print.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 1.0.5  08feb2005
program define print
	version 7.0
	
	gettoken filename 0 : 0, parse(", ")
	gettoken start rest : filename, parse(".")
	while ("`rest'" != "") {
		gettoken next rest : rest, parse(".")
		if ("`rest'" != "") {
			local ext "`rest'"
		}
	}
	
	syntax [, like(string) name(passthru) printer(string) * ]
			
	if substr("`filename'", 1, 1) == "@" {
		if "`like'" != "" {
			dis in error "like() invalid"
			exit 198
		}
		local first = substr("`filename'", 2, .)
		local translator "`first'2prn"
	}
	else if "`like'" != "" {
		local translator "`like'2prn"
	}
	else {
		qui transmap q `ext'
		local ext "`r(suffix)'"
		local translator "`ext'2prn"
	}

	if "$S_OS" == "Unix" {
		if "`printer'" != ""  {
			if substr("`filename'", 1, 1) == "@" {
				local translator "`first'2`printer'"
			}
			else if "`like'" != ""  {
				local translator "`like'2`printer'"
			}
			else 	local translator "`ext'2`printer'"
		}
	}
	else {
		if "`printer'" != "" {
			dis in err "printer() invalid" 
			exit 198
		}
	}
	qui translate "`filename'" __PRINT, /*
			*/ translator(`translator') `name' `options'
end