pieview.class

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

//				pieview
//
//  class that redirects a .draw to a pie graphs pie drawing program. 
//  Also provides the interface to legends.

*! version 1.0.0  07dec2002

version 8

class {
	piegraph = ""				// key of the piegraph
	type	 = .pietype_g.new , style(pie)	// for yxkey_g
} , inherit(subview)

program new
	syntax , piegraph(string) [ * ]

	.piegraph = "`.`piegraph'.objkey'"

	.Super.new , `options'
end


// ----------------------------------------------------------------------------
program draw
	.`.piegraph'.drawpie `0'
end

// ----------------------------------------------------------------------------
// Number of legend keys for the pie graph

program numkeys
	.`.piegraph'.sersets[1].set
	class exit = 0`:serset N'
end


// ----------------------------------------------------------------------------
// Return a key for the specified pie wedge.

program newkey
	gettoken i_pie 0 : 0

	if `.numkeys' == 0 {
		class exit ""
	}

	confirm integer number `i_pie'
	syntax  [ , Position(passthru) ]

	class exit .yxkey_g.new , view(`.objkey') 		///
		style(`.`.piegraph'.piestyles[`i_pie'].objkey') `position'
end


// ----------------------------------------------------------------------------
// Return a key label for a specified pie wedge (keynum).

program label

	syntax [ , Nameonly Keynum(integer 1) ]		// nameonly ignored

	.`.piegraph'.sersets[1].set
	local labdex = serset(3 , `keynum')
	class exit `"`.`.piegraph'.sersets[1].sers[3].value_label `labdex''"'
//	class exit `"`.`.piegraph'.sersets[1].sers[3].value_label `keynum''"'
end