pca_p.dlg

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

/*
	predict (after pca)

*!  VERSION 1.0.1  28mar2005

*/

VERSION 9.0

INCLUDE _std_large
INCLUDE _ht330
INCLUDE header

HELP hlp1, view("help pca postestimation")
RESET res1

DIALOG main, label("predict - Prediction after estimation") tabtitle("Main")
BEGIN
INCLUDE  _p_gentype

  GROUPBOX gb_produce		_lft	_ls	_iwd	_ht8,		///
	label("Produce:")
  RADIO    rb_score		_indent	_ss	_ibwd	.,	first	///
	option(score) label("Scores based on the components (default)")	///
	onclickon(script _p_gentype_multiple)
  RADIO    rb_fit		@	_ss	@	.,		///
	option(fit) 							///
	label("Fitted values using the retained components")		///
	onclickon(script _p_gentype_multiple)
  RADIO    rb_residual		@	_ss	@	.,		///
  	onclickon(script _p_gentype_multiple)				///
	option(residual) label("Raw residuals from the fit using the retained components")
  RADIO    rb_q			@	_ss	@	.,	last	///
	option(q) label("Residual sum of squares")			///
	onclickon(script _p_gentype_single)

  GROUPBOX gb_opts		_lft	_xls	_iwd	_ht10h,		///
	label("Options")
  CHECKBOX ck_norotated		_ilft	_ss	_ibwd	.,		///
	option(norotated) label("Use unrotated results, even when rotated results are available")
  CHECKBOX ck_center		@	_ms	@	.,		///
	option(center) label("Base scores on centered variables")
  CHECKBOX ck_notable		@	_ms	@	.,		///
	option(notable) label("Suppress table of scoring coefficients")
  EDIT     en_format		@	_ls	_en7wd	.,		///
  	label("Format") option(format) default("%8.4f")
  TEXT     tx_format		_spsep	@	_cksprb	.,		///
	label("Format for displaying the scoring coefficients")
END

INCLUDE _p_gentype_sc
INCLUDE ifin
INCLUDE _type_list_fd

SCRIPT POSTINIT
BEGIN
	script _p_gentype_setHasStubFalse
END

PROGRAM command
BEGIN
	put "predict "
	put " " /program _p_gentype_output
	INCLUDE _ifin_pr
	beginoptions
		option main.rb_score
		option main.rb_fit
		option main.rb_residual
		option main.rb_q
		option main.ck_norotated
		option main.ck_center
		option main.ck_notable
		optionarg /hidedefault main.en_format
	endoptions
END