_tsheadr.ado

是一个经济学管理应用软件 很难找的 但是经济学学生又必须用到

*! version 6.1.0  10sep2004
program define _tsheadr
	version 6.0

	local crtype = upper(substr(`"`e(crittype)'"',1,1)) + /*
		*/ substr(`"`e(crittype)'"',2,.)

	if e(N_gaps) > 0 { local gaptitl ", but with gaps" }

	di _n in gr "`e(title)'"
	if `"`e(title2)'"' != "" { di in gr "`e(title2)'" }
	
	local smpl "Sample:  " in ye "`e(tmins)' to `e(tmaxs)'`gaptitl'"

	if length(`"`smpl'"') < 45 {
		local osmpl "`smpl'"
		di
	}
	else	di in gr _n "`smpl'"

	di in gr "`osmpl'" 						/*
		*/ _col(49) in gr "Number of obs" in gr _col(68) "="	/*
		*/ in ye _col(70) %9.0g e(N)

	if !missing(e(df_r)) {
		local model _col(49) as txt "F(" ///
			as res %3.0f e(df_m) as txt "," ///
			as res %6.0f e(df_r) as txt ")" _col(68) ///
			"=" _col(70) as res %9.2f e(F)
		local pvalue _col(49) as txt "Prob > F" _col(68) ///
			"=" _col(73) as res %6.4f Ftail(e(df_m),e(df_r),e(F))
	}
	else {
		if "`e(chi2type)'" == "" {
			local chitype Wald
		}
		else	local chitype `e(chi2type)'
		local model _col(49) as txt `"`chitype' chi2("' ///
			as res e(df_m) as txt ")" _col(68) ///
			"=" _col(70) as res %9.2f e(chi2)
		local pvalue _col(49) as txt "Prob > chi2" _col(68) ///
			"=" _col(73) as res %6.4f chiprob(e(df_m),e(chi2))
	}

	di `model'
	if "`e(ll)'" != "" {
		di in gr "`crtype' = " in ye %9.0g e(ll) `pvalue'
	}
	else {
		di `pvalue'
	}
	di

	mat dispCns, r
	if "`r(k)'" != "0" {
		di in gr "Constraints:"
	}
	mat dispCns
end
exit
----+----1----+----2----+----3----+----4----+----5----+----6----+----7----+----8
Main title of time-series model 

Sample: 1940w32 to 1960w45                      Number of obs      =       543
                                                Wald chi2(2)       =      0.61
Log likelihood = -66.372364                     Prob > chi2        =    0.7382